5
$\begingroup$

How can I solve the following inequality:

Log[1/2 + c^2] > (1.4) (30^5) 2^(4.5) 9 (0.6) (2.8) (1 + Log[3]) (1 +Log[ Log[c + 1]])

?

I tried Reduce, but my computer is still computing it (c is a real number).

$\endgroup$
1
  • $\begingroup$ Use for example FindRoot[Log[1/2 + c^2] == 8230118400 Sqrt[2] (1 + Log[3]) (1 + Log[Log[1 + c]]), {c, 1/2}] and plot the function around that value to get a hint ... $\endgroup$ May 19 '13 at 20:33
14
$\begingroup$

If you are looking for exact solutions you should substitute machine precission numbers by exact numbers. Therefore instead of your numerical coefficient I'd rather use this one:

 (7/5) (30^5) 2^(9/2) 9 (3/5) (14/4) (1 + Log[3])
 N[%]
10287648000 Sqrt[2] (1 + Log[3])
3.05326*10^10

This is a huge number so for the sake of simplicity instead of playing with it I'll use a coefficient a much smaller to demonstrate the main issue.

First assume the coefficient is a == 1 and plot these two functions:

Plot[{ Log[1/2 + c^2], (1 + Log[Log[1 + c]])}, {c, 0, 2}, 
       PlotLegends -> "Expressions", PlotStyle -> Thick ]

enter image description here

We can see there are two solutions and Log[1/2 + c^2] tends to infinity faster. To show where the inequality is satisfied we use blue Filling:

Plot[ Log[1/2 + c^2] - (1 + Log[Log[1 + c]]), {c, 0, 2},  PlotLegends -> "Expressions",
      PlotStyle -> Thick,  Filling -> {1 -> {0, {Red, Blue}}}]

enter image description here

Moreover regardless of the coefficient a we have

Limit[a (1 + Log[Log[c + 1]])/Log[1/2 + c^2], c -> Infinity]
 0

and if a gets larger then the upper range of the solution set starts with a larger number. It seems there is a bug in Reduce when we work with inequalities, therefore we can use a simple equality instead. Now the case a == 30:

Reduce[ 30 (1 + Log[Log[c + 1]])/Log[1/2 + c^2] == 1, c, Reals]
c == Root[{1 - 2 E^30 Log[1 + #1]^30 + 2 #1^2 &, 0.43820044934843508362}] || 
c == Root[{1 - 2 E^30 Log[1 + #1]^30 + 2 #1^2 &, 1.35977747245195272715*10^35}]

Thus the inequality for a == 30 is satisfied for

 0 < c < 0.43820044934843508362 || c > 1.35977747245195272715*10^35 

for the original a the lower limit can be calculated as suggested by belisarius in the comment, while the upper one exceeds $MaxNumber.

$\endgroup$
1
  • 1
    $\begingroup$ thank you for your response !!! $\endgroup$
    – MATIRMAK
    May 22 '13 at 20:16

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.