0
$\begingroup$

How can I solve for $\alpha$ in $$4\sin\left(\frac{\alpha}{2}\right)\cos\left(\frac{\alpha}{2}\right)^{3}\left(t-r\right)+\sin\left(\frac{\alpha}{2}\right)=1$$ on the domain $0\leq\alpha\leq\pi$? Clearly, one solution is when $\alpha=\pi$, but through plotting, it seems to only hold true when $t-r$ is less than a value around $0.3$. When $t-r$ is greater than this value, it seems to have different solutions.

NSolve[HoldForm[4*Sin[\[Alpha]/2]*Cos*(\[Alpha]/2)^3*(t - r) + Sin[\[Alpha]/2]] == 1 && 0 <= \[Alpha] <= Pi, \[Alpha], Reals]

I am very new so I don't have much code.

$\endgroup$
4
  • 1
    $\begingroup$ just want to make sure, is this a question about how to solve this problem in the software program Mathematica, or should this question be migrated to the Mathematics stackexchange instead? If it's about mathematica, please post your code so people don't have to type it out again! :) $\endgroup$
    – thorimur
    Aug 28 at 4:00
  • $\begingroup$ Please include in your question the code that you have tried and what you obtained. $\endgroup$
    – bbgodfrey
    Aug 28 at 4:02
  • $\begingroup$ @thorimur I am trying to solve it in Mathematica but I am new so I don't have the tools to solve it. I don't think it's possible to solve it algebraically, which is why I didn't think of posting it on Math stack exchange, but I know there are other solutions. I don't really have much code, but I guess I can post the equation in Mathematica format. $\endgroup$ Aug 28 at 4:04
  • 1
    $\begingroup$ You have syntax errors. Eliminate HoldForm, and use Cos[\[Alpha]/2]^3 instead of Cos*(\[Alpha]/2)^3. Then, use N @ Solve[..] instead of NSolve. $\endgroup$
    – Carl Woll
    Aug 28 at 5:20
1
$\begingroup$
sol = Solve[
     4*Sin[a/2]*Cos[a/2]^3*tr + Sin[a/2] == 1 && 0 <= a <= Pi, {a, tr}, 
      Reals]

(*   {{a -> \[Pi]}, {tr -> 
       ConditionalExpression[1/4 Csc[a/2] Sec[a/2]^3 (1 - Sin[a/2]), 
        0 < a < \[Pi]]}}   *)

Plot[Evaluate[tr /. sol], {a, 0, Pi}, PlotRange -> {0, 20}, 
     GridLines -> Automatic]

{min = Minimize[tr /. sol[[2]], a], min // N}

(*   {{-(1/4) Csc[
2 ArcTan[Root[1 + 2 #1 - 10 #1^2 + 2 #1^3 + #1^4 &, 3]]] Sec[
2 ArcTan[Root[1 + 2 #1 - 10 #1^2 + 2 #1^3 + #1^4 &, 3]]]^3 (-1 + 
 Sin[2 ArcTan[
    Root[1 + 2 #1 - 10 #1^2 + 2 #1^3 + #1^4 &, 3]]]), {a -> 
4 ArcTan[
  Root[1 + 2 #1 - 10 #1^2 + 2 #1^3 + #1^4 &, 
   3]]}}, {0.287482, {a -> 1.75015}}}   *)

Two solutions: 1. for a==Pi, any tr you like 2. For 0 < a < Pi, tr depending on a as shown in the graph.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.