Mesh from Images for three materials

Question

I want to mesh a figure which contains three different materials (organic-based materials and polymers) using Mathematica.

Namely:

Black color: material A

White color: material B

Grey color: material C

in the attachment you will see this figure

I have used ImageMesh[] command in Mathematica, and it does not work.

After the ImageMesh operation we can see such mesh type:

Or looks like this

Answer 1

Combining separate meshes from each image component works well for showing the mesh as a graphics. But the combined meshes don't always match at the boundaries between materials and can have tiny gaps. You can see these problems by zooming into the boundary areas in graphics of the combined meshes. They don't matter for visualization, but can be a problem if you want to use the mesh with NDSolve, e.g., solving for heat transfer through materials with different thermal conductivity.

To avoid gaps, it's best to mesh as a single region with internal boundaries between the different materials, as described in the documentation tutorial FEMDocumentation/tutorial/ElementMeshCreation, in the sections "Element Meshes with Subregions" and "Markers".

One way to get the boundaries is from the clustering components in Rom38's answer, using the "Contours" property of ComponentMeasurements. Then convert these boundaries into the form required by ToBoundaryMesh:

Needs["NDSolve`FEM`"];

img = Import["https://i.sstatic.net/zD7Ar.jpg"];

Module[{components, boundaries, coords, elements, bmesh, 
  pointInEachRegion, reg, parts, markers},

 components = ClusteringComponents[img, 3];
 
 boundaries = 
  Flatten[
   Values@
    ComponentMeasurements[components, "Contours", All, 
     "ComponentAssociation"]];
 
 (* points appearing in the boundaries *)
 coords = Flatten[Cases[boundaries, Line[pts_] :> pts], 1];
 coords = DeleteDuplicates[coords];
 
 (* replace boundary points by indices into list of coordinates *)
 boundaries = 
  boundaries /. 
   Line[pts_] :> 
    Line[
     pts /. 
      p : {_?NumberQ, _?NumberQ} :> FirstPosition[coords, p][[1]]];

 (* remove repeated successive coordinates *)
 boundaries = 
  boundaries /. 
   Line[pts_] :> 
    Line[pts //. {first___, a_, a_, rest___} :> {first, a, rest}];
 
 (* convert boundary lines into mesh elements *)
 elements = 
  boundaries /. Line[pts_List] :> LineElement[Partition[pts, 2, 1]];
 
 (* mesh with internal boundaries between the materials *)
 bmesh = 
  ToBoundaryMesh["Coordinates" -> coords, 
   "BoundaryElements" -> elements];
 
 (* random point in each connected part of each component to specify markers in the mesh *)
 SeedRandom[123];
 pointInEachRegion = 
  Table[reg = 
    ImageMesh[
     Image[components /. Thread[DeleteCases[Range[3], i] -> 0]]];
   parts = ConnectedMeshComponents[reg];
   RandomPoint /@ parts, {i, 3}];
 
 (* markers indicating each material, in this case, markers 1, 2 and 3 for the three components *)
 markers = 
  Flatten[Table[{#, i} & /@ pointInEachRegion[[i]], {i, 3}], 1];

(* extend boundary mesh to full mesh with markers for each material *)
     ToElementMesh[bmesh, "RegionMarker" -> markers]
 ]

This code creates a single ElementMesh for the whole region, with small mesh elements near the boundary. You can adjust mesh size with options to ToElementMesh.

NDSolve can use this mesh, e.g., to compute heat transport, with material properties, such as thermal conductivity, specified by the value of ElementMarker, which in this case has the values 1, 2 and 3.

Visualize the mesh with colors indicating the marker associated with each mesh triangle:

%["Wireframe"[PlotRangePadding -> None, 
  "MeshElementStyle" -> (Directive[FaceForm[#], 
       EdgeForm[Opacity[.2]]] & /@ {Lighter@Red, Green, LightBlue})]]

One possible issue with this approach is the boundary between materials returned by ComponentMeasurements is fairly jagged in some places. Smoother boundaries between materials would require a different approach. E.g., use a contour plot of the image data, extract the lines of the contours and then convert them to the form required for ToBoundaryMesh, as done in the above code for boundaries from ComponentMeasurements. This will require more manual adjustment of parameters, e.g., to pick the contours.

p.s., if the image is noisy, you can filter the image first. E.g., with MedianFilter or a filter that preserves edges better, such as BilateralFilter.

Answer 2

I guess, the cc=ClusteringComponents[img, 3] is good here:

It gives you an array where point of certain color is marked by numbers 1-2-3 (I asked for just three regions). You can select any of them by replacement of all rest by 0 and make the desired ImageMesh of the segment:

s1=cc /. {1 -> 0, 2 -> 0};
s2=cc /. {2 -> 0, 3 -> 0};
s3=cc /. {1 -> 0, 3 -> 0};
ImageMesh[Image@s1] 

Similarly, you can make the meshes for s2 and s3.

The combined mesh can be made from initial cc:

ImageMesh[Image@cc]

m1 = DiscretizeRegion@ImageMesh[Image@s1];
m2 = DiscretizeRegion@ImageMesh[Image@s2];
m3 = DiscretizeRegion@ImageMesh[Image@s3];
Graphics[{EdgeForm[Black], Red, m1, Green, m2, Blue, m3}]

Answer 3

It sounds like maybe you want a mesh for each colour (?)

img = Import["https://i.sstatic.net/zD7Ar.jpg"];
cols = {Black, Gray, White};
cq = ColorQuantize[img, cols, Dithering -> False]
ImageMesh[ColorReplace[cq, {_ -> Black, # -> White}]] & /@ cols

Unfortunately RegionUnion doesn't work, even on the triangulated meshes, but it's still possible to present the meshes with the wireframe:

Graphics[{EdgeForm[Darker@Purple], 
  Riffle[cols, TriangulateMesh /@ meshes]}]

Answer 4

img = Import["https://i.sstatic.net/zD7Ar.jpg"];
whiteImg = MorphologicalBinarize[img, 0.9];
blackImg = MorphologicalBinarize[ColorNegate@img, 0.7];
blackgrayMesh = ImageMesh[ColorNegate@whiteImg];
whiteMesh = ImageMesh[whiteImg];
blackMesh = ImageMesh[blackImg];
grayMesh = RegionDifference[blackgrayMesh, blackMesh];
Needs["NDSolve`FEM`"]
ToElementMesh[whiteMesh][
  "Wireframe"["MeshElementStyle" -> FaceForm[White]]];
ToElementMesh[grayMesh][
  "Wireframe"["MeshElementStyle" -> FaceForm[Green]]];
ToElementMesh[blackMesh][
  "Wireframe"["MeshElementStyle" -> FaceForm[Red]]];
Show[%%%, %%, %]

Edit

Another possible way.

img = Import["https://i.sstatic.net/zD7Ar.jpg"];
result = DominantColors[img, 
  Automatic, {"CoverageImage", "MaskCoverage", "Color"}, 
  Method -> Automatic]
{gray, white, black, unknow} = ImageMesh /@ result[[All, 1]];
Needs["NDSolve`FEM`"]
ToElementMesh[white][
  "Wireframe"["MeshElementStyle" -> FaceForm[White]]];
ToElementMesh[gray][
  "Wireframe"["MeshElementStyle" -> FaceForm[Green]]];
ToElementMesh[black]["Wireframe"["MeshElementStyle" -> FaceForm[Red]]];
ToElementMesh[unknow][
  "Wireframe"["MeshElementStyle" -> FaceForm[Cyan]]];
Show[%%%%, %%%, %%, %]