How do I plot (1,1) (2,2) (3,3) and so on, on a Polar Plot?

Question

I recently downloaded Mathematica and am extremely new to the software. To start off, I wanted to work with Polar Coordinates and Archimedean Spirals. I want to be able to graph a continuous spiral with the coordinates (r, theta)=(n, n) where n is a positive integer. Essentially I would be creating a spiral between the points (0,0) (1,1) (2,2) (3,3) and it continues on. I would like to have a graph with just the points as well as one with a line connecting the points.

Also, is there a way to specify different ranges?

Similar to the question posed on this Math Stack Exchange.

Answer 1

Another approach is as follows.

a = ListPolarPlot[{{0, 0}, {1, 1}, {2, 2}, {3, 3}},PlotStyle -> {Red, Thick}];
f = Interpolation[{{0, 0}, {1, 1}, {2, 2}, {3, 3}}];
b = PolarPlot[f[x], {x, 0, 3}];
Show[{a, b}]

Answer 2

As i understand , you want this and this or this

ListPolarPlot[Table[{j, j}, {j, 0, 10}], 
   PlotStyle -> {Red, PointSize[.03]}]

ListPolarPlot[Table[{j, j}, {j, 0, 10}], Mesh -> {Range[0, 10]}, 
    MeshStyle -> {Red, PointSize[.03]}, Joined -> True]

PolarPlot[th, {th, 0, 10}, Mesh -> {Range[0, 10]}, 
   MeshStyle -> {Red, PointSize[.03]}]

Answer 3

Since you want to Archimedean Spirals,so we can set the form r == a*θ^(1/n) and then solve the equations.

polarpts = {{0, 0}, {1, 1}, {2, 2}, {3, 3}};
sol = Solve[
   r == a*θ^(1/n) /. Thread[{r, θ} -> #] & /@ polarpts, 
   Reals];
ArchimedeanSpirals = 
  PolarPlot[a*θ^(1/n) /. sol[[1]], {θ, 0, 20}, 
   MeshStyle -> Red];
Show[ArchimedeanSpirals, ListPolarPlot[polarpts, PlotStyle -> Red]]

Reply to comment

Here we insist on using Archimedean Spirals.

polarpts = {{1, 1.1}, {2.1, 2}, {3.3, 3}, {5, 5}, {8, 8.1}};
f = NonlinearModelFit[Reverse /@ polarpts, 
   a*θ^(1/n), {a, n}, θ];
Show[PolarPlot[f[θ], {θ, 0, 20}], 
 ListPolarPlot[polarpts, PlotStyle -> Red]]

Answer 4

Look for the function FromPolarCoordinates.

Unfortunately this function doesn't transform the Point {0,0}, That's why I used my own transformation:

r\[Theta] = Table[{i, i}, {i, 0, 10}]
xy = Map[#[[1]] {Cos[#[[2]]], Sin[#[[2]]]} &, r\[Theta]];
ListPlot[{xy, xy}, Joined -> {False, True}] 

Hope it helps!