1
$\begingroup$

**I just need to find conditions on Subscript[[CapitalPhi], [Pi]] such that the fifth root of the polynomial is greater than 1 in absolute value. **

I have a 5-degree characteristic polynomial, for which I have roots in the form of 'Root' object. For certain values of the coefficients, I need to test if the absolute value of a specific root, (or the eigenvalue is greater than 1). I tried working with ConditionalExpression, If, etc. but no luck.

The following is the characteristic polynomial in z: ([CapitalPhi]_[Pi] is just a parameter in the model)


z^5 - 0.00204575 Subscript[\[CapitalPhi], \[Pi]] - 
 0.0487214 z Subscript[\[CapitalPhi], \[Pi]] + 
 1.04752 z^2 Subscript[\[CapitalPhi], \[Pi]] - 
 0.996752 z^3 Subscript[\[CapitalPhi], \[Pi]]
These are the roots:

z == Root[-3.81007 #1^4 + #1^5 + #1^2 (-0.659423 - 
        1.04752 Subscript[\[CapitalPhi], \[Pi]]) + #1 (-0.0163848 + 
        0.0487214 Subscript[\[CapitalPhi], \[Pi]]) + #1^3 (3.49068 + 
        0.996752 Subscript[\[CapitalPhi], \[Pi]]) + 
     0.00204575 Subscript[\[CapitalPhi], \[Pi]] &, 1] || 
 z == Root[-3.81007 #1^4 + #1^5 + #1^2 (-0.659423 - 
        1.04752 Subscript[\[CapitalPhi], \[Pi]]) + #1 (-0.0163848 + 
        0.0487214 Subscript[\[CapitalPhi], \[Pi]]) + #1^3 (3.49068 + 
        0.996752 Subscript[\[CapitalPhi], \[Pi]]) + 
     0.00204575 Subscript[\[CapitalPhi], \[Pi]] &, 2] || 
 z == Root[-3.81007 #1^4 + #1^5 + #1^2 (-0.659423 - 
        1.04752 Subscript[\[CapitalPhi], \[Pi]]) + #1 (-0.0163848 + 
        0.0487214 Subscript[\[CapitalPhi], \[Pi]]) + #1^3 (3.49068 + 
        0.996752 Subscript[\[CapitalPhi], \[Pi]]) + 
     0.00204575 Subscript[\[CapitalPhi], \[Pi]] &, 3] || 
 z == Root[-3.81007 #1^4 + #1^5 + #1^2 (-0.659423 - 
        1.04752 Subscript[\[CapitalPhi], \[Pi]]) + #1 (-0.0163848 + 
        0.0487214 Subscript[\[CapitalPhi], \[Pi]]) + #1^3 (3.49068 + 
        0.996752 Subscript[\[CapitalPhi], \[Pi]]) + 
     0.00204575 Subscript[\[CapitalPhi], \[Pi]] &, 4] || 
 z == Root[-3.81007 #1^4 + #1^5 + #1^2 (-0.659423 - 
        1.04752 Subscript[\[CapitalPhi], \[Pi]]) + #1 (-0.0163848 + 
        0.0487214 Subscript[\[CapitalPhi], \[Pi]]) + #1^3 (3.49068 + 
        0.996752 Subscript[\[CapitalPhi], \[Pi]]) + 
     0.00204575 Subscript[\[CapitalPhi], \[Pi]] &, 5]


I saved the last root as Root100 and then took the absolute value: The last two roots are imaginary and I just want to check if their absolute value is greater than 1 for [CapitalPhi]_[Pi] greater than or less than 1. Starting with the fifth root, I did the following:

Root100 = 
 z == Root[-3.8100716752443358` #1^4 + #1^5 + #1^2 \
(-0.6594231916363339` - 
        1.0475194467246431` Subscript[\[CapitalPhi], \[Pi]]) + #1 \
(-0.016384816689513255` + 
        0.048721356558687944` Subscript[\[CapitalPhi], \[Pi]]) + #1^3 \
(3.4906781487894887` + 
        0.9967523435624097` Subscript[\[CapitalPhi], \[Pi]]) + 
     0.0020457466035455397` Subscript[\[CapitalPhi], \[Pi]] &, 5]

Root101 = Abs[Root100]

Abs[z == Root[-3.81007 #1^4 + #1^5 + #1^2 (-0.659423 - 
        1.04752 Subscript[\[CapitalPhi], \[Pi]]) + #1 (-0.0163848 + 
        0.0487214 Subscript[\[CapitalPhi], \[Pi]]) + #1^3 (3.49068 + 
        0.996752 Subscript[\[CapitalPhi], \[Pi]]) + 
     0.00204575 Subscript[\[CapitalPhi], \[Pi]] &, 5]]

I have tried the following :

ConditionalExpression[Root101 > 1, 
 Subscript[\[CapitalPhi], \[Pi]] > 1]

Refine[Root101, Assumptions -> Subscript[\[CapitalPhi], \[Pi]] > 1]

FullSimplify[Root100, Subscript[\[CapitalPhi], \[Pi]] > 1]

Root101 = If[Subscript[\[CapitalPhi], \[Pi]] > 1, z]


If you could please suggest a way to prove that the absolute value of the fifth root would be greater than 1 for Subscript[[CapitalPhi], [Pi]] greater than as well as less than 1. I would really appreciate help with this.

****To make it more clear: I just need to find conditions on Subscript[[CapitalPhi], [Pi]] to prove that the fifth root of the polynomial is greater than 1 in absolute value. ****

Thank you very much, @Akku14 for your reply, but I think wasn't able to explain my objective too well.

I'm new to mathematica and would really appreciate any help with this. Thank you.

$\endgroup$
3
  • $\begingroup$ Are these the eigenvalues of a matrix? If yes, could you please share the matrix? $\endgroup$
    – Roman
    Aug 13, 2021 at 17:50
  • $\begingroup$ Hi, yes the roots above are the eigenvalues as the polynomial in the first line is the characteristic polynomial. The following is the matrix: {{1.79847, -5.12392 + 4.67648 Subscript[\[CapitalPhi], \[Pi]], -0.199451, -0.0666941, \ -0.341908}, {-0.213141, 1.03378, 0, 0.0236824, 0}, {0, 0, -0.0221797, 0, 0.010101}, {0, 1, 0, 1, 0}, {0., 0. + Subscript[\[CapitalPhi], \[Pi]], 0, 0., 0}} After this I subtracted the matrix z*I and took the determinant which gave me the characteristic polynomial above- the pedagogic way of finding the eigenvalues. Thanks! $\endgroup$
    – user15723
    Aug 13, 2021 at 18:26
  • $\begingroup$ Welcome to Mathematica.SE! I hope you will become a regular contributor. To get started, 1) take the introductory tour now, 2) when you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge, 3) remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign, and 4) give help too, by answering questions in your areas of expertise. $\endgroup$
    – bbgodfrey
    Aug 13, 2021 at 18:53

1 Answer 1

1
$\begingroup$
$Version

(* "12.3.1 for Mac OS X x86 (64-bit) (June 19, 2021)" *)

Clear["Global`*"]

poly = z^5 - 0.00204575 Subscript[Φ, π] - 
    0.0487214 z Subscript[Φ, π] + 
    1.04752 z^2 Subscript[Φ, π] - 
    0.996752 z^3 Subscript[Φ, π] // Rationalize[#, 0] &;

roots = Values[Solve[poly == 0, z]];

The absolute value of the last root equals 1 when

pts = FindRoot[
    Abs[roots[[-1]]] == 1, {Subscript[Φ, π], #}] & /@ {-1, 2}

(* {{Subscript[Φ, π] -> -0.604281}, {Subscript[Φ, π] -> 1.6579}} *)

Plot[{Abs[roots[[-1]]], 1}, {Subscript[Φ, π], -2, 3},
 Epilog -> {Red, AbsolutePointSize[4],
   Tooltip[Point[{Subscript[Φ, π], 1}], 
     Subscript[Φ, π]] /. pts},
 Frame -> True,
 PlotRange -> All,
 PlotPoints -> 75,
 MaxRecursion -> 10]

enter image description here

The absolute value of the last root is less than 1 for

Less @@ Insert[Values[pts] // Flatten, Subscript[Φ, π], 2]

(* -0.604281 < Subscript[Φ, π] < 1.6579 *)

EDIT: For the revised polynomial given in a comment

Clear["Global`*"]

poly2 = 0.` + 0.016384816689513255` z + 0.6594231916363339` z^2 - 
    3.4906781487894887` z^3 + 3.8100716752443358` z^4 - z^5 - 
    0.0020457466035455397` Subscript[Φ, π] - 
    0.048721356558687944` z Subscript[Φ, π] + 
    1.0475194467246431` z^2 Subscript[Φ, π] - 
    0.9967523435624097` z^3 Subscript[Φ, π] // 
   Rationalize[#, 0] &;

The last root is

root5 = Solve[poly2 == 0, z][[-1, 1, -1]];

Plotting the absolute value of the last root

plt = Plot[Abs[root5], {Subscript[Φ, π], -3, 3},
  MeshFunctions -> {#2 &},
  Mesh -> {{1}},
  MeshStyle -> {Red, AbsolutePointSize[4]}, Frame -> True]

enter image description here

val = Cases[plt // Normal, Point[pt_] :> pt, Infinity][[All, 1]]

(* {-0.384239, -0.0794879} *)

The absolute value of the last root is greater than 1 when

Less[Subscript[Φ, π], val[[1]]] ||
Greater[Subscript[Φ, π], val[[2]]]

$\endgroup$
7
  • $\begingroup$ Thanks very much, Bob, really appreciate your help. Can you please suggest how could I get a range/interval for the case when absolute value of the root is greater than 1? (like you did in the last step for the case with root less than 1) $\endgroup$
    – user15723
    Aug 15, 2021 at 11:30
  • $\begingroup$ From the plot, the absolute value of the last root is greater than 1 for Or[Less[Subscript[\[CapitalPhi], \[Pi]], pts[[1, 1, -1]]], Greater[Subscript[\[CapitalPhi], \[Pi]], pts[[2, 1, -1]]]] $\endgroup$
    – Bob Hanlon
    Aug 15, 2021 at 14:37
  • $\begingroup$ Right, thank you very much, @Bob. I was wondering if there is a way to get some sort of global interval for Subscript[[CapitalPhi], [Pi]] for which the fifth root would be greater than 1 in absolute value, instead of a plot. $\endgroup$
    – user15723
    Aug 15, 2021 at 22:14
  • $\begingroup$ The polynomial has also changed slightly to: ` poly = 0.` + 0.016384816689513255` z + 0.6594231916363339` z^2 - 3.4906781487894887` z^3 + 3.8100716752443358` z^4 - z^5 - 0.0020457466035455397` Subscript[[CapitalPhi], [Pi]] - 0.048721356558687944` z Subscript[[CapitalPhi], [Pi]] + 1.0475194467246431` z^2 Subscript[[CapitalPhi], [Pi]] - 0.9967523435624097` z^3 Subscript[[CapitalPhi], [Pi]] ` $\endgroup$
    – user15723
    Aug 15, 2021 at 22:18
  • $\begingroup$ Thank you very much for your help, @Bob! If you could please help me with one more clarification: In the code above where you specify the last root: root5 = Solve[poly2 == 0, z][[-1, 1, -1]]; Could you please elaborate on the RHS of this and the last bracket there. Specifically how did this line of code identify the fifth root (and not some other root). Thanks very much for all your help. $\endgroup$
    – user15723
    Aug 16, 2021 at 10:14

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.