0
$\begingroup$

For positive real $a \leq \pi$ and $b \leq \pi$

$\int_{-a/2}^{a/2} \frac{\sin{(b/2)}}{\sqrt{1+\cos^2 (b/2)\tan^2 (\phi )}} \; d \phi = 2 \arcsin \left[ \sin (a/2) \sin (b/2) \right] $

as can be verified numerically. Mathematica fails to compute this integral except under a condition which is only satisfied for $a= \pi $ and $b = \pi$. A version of Maple I tried also failed to yield a result.

Given the simplicity of the result, I would think there should be a neat way to prove this identity symbolically. Any ideas?

$\endgroup$
0
1
$\begingroup$

Next time please post plain Mathematica code.

Rubi gives the result, but in different form, which Mathematica can't simplify to the one you show, but numerically one can show it is the same. (or try to do it by hand)

<< Rubi`
ClearAll[a, b, phi]
integrand = Sin[b/2]/Sqrt[1 + Cos[b/2]^2*Tan[phi]^2]
anti = Int[integrand, {phi, -a/2, a/2}]

$$ 2 \tan ^{-1}\left(\frac{\tan \left(\frac{a}{2}\right) \sin \left(\frac{b}{2}\right)}{\sqrt{\tan ^2\left(\frac{a}{2}\right) \cos ^2\left(\frac{b}{2}\right)+1}}\right) $$

Numerically showing it is the same

book = 2*ArcSin[Sin[a/2]*Sin[b/2]]
Manipulate[
 N[(book - anti) /. {a -> a0, b -> b0}],
 {{a0, 1, "a"}, -5, 5, .1},
 {{b0, 1, "b"}, -5, 5, .1},
 TrackedSymbols :> {a0, b0}
 ]

enter image description here

difference is zero.

$\endgroup$
1
  • $\begingroup$ Thanks. Didn't know about Rubi. It looks useful. $\endgroup$
    – ulvi
    Aug 11 '21 at 0:42
1
$\begingroup$

If you know the answer, it is easy to coerce Mathematica to get it. Follow the suggestion of @Nasser and simplify the result

<< Rubi`
y = Int[Sin[b/2]/Sqrt[1 + Cos[b/2]^2 Tan[x]^2], {x, -a/2, a/2}]
FullSimplify[2 ArcSin[TrigExpand[Sin[y/2]]], Assumptions -> {a > 0, b > 0, a < Pi, b < Pi}]
(* 2 ArcSin[Sin[a/2] Sin[b/2]] *)
$\endgroup$
1
$\begingroup$

Expand the Tan to Sin/Cos in the integrand to get

Integrate[(Cos[phi]*Sin[b/2])/
Sqrt[Cos[phi]^2 + Cos[b/2]^2*Sin[phi]^2], 
{phi, -(a/2), a/2}]
(* 2 ArcSin[Sin[a/2] Sin[b/2]] *)
$\endgroup$
1
  • $\begingroup$ Interesting. I should have tried that substitution. $\endgroup$
    – ulvi
    Aug 12 '21 at 1:36
0
$\begingroup$

Integrate[Sin[b/2]/Sqrt[1 + Cos[b/2]^2 Tan[phi]^2], {phi, -a/2, a/2}, Assumptions -> {a > 0, b > 0, a < Pi, b < Pi}] gives

Pi + 2 I ArcCsch[2/Sqrt[-3 + Cos[a] (-1 + Cos[b]) - Cos[b]]]

which appears correct numerically, but how does it simplify to the desired RHS?

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.