RootReduce and Simplify for an algebraic expression

Question

The American Invitational Mathematics Exam (AIME) 2006 asked contestants to reduce this expression:

$$\sqrt{104 \sqrt{6} + 468 \sqrt{10} + 144 \sqrt{15} + 2006}$$

The answer is $13 \sqrt{2} + 4 \sqrt{3} + 18 \sqrt{5}$, as can be verified by:

Reduce[Sqrt[104 Sqrt[6] + 468 Sqrt[10] + 144 Sqrt[15] + 2006] == 
  13 Sqrt[2] + 4 Sqrt[3] + 18 Sqrt[5]]

(* True *)

Alas, the direct approach for Mathematica-based such simplification of the expression in the problem doesn't work:

mySimple = RootReduce[Sqrt[104 Sqrt[6] + 468 Sqrt[10] + 144 Sqrt[15] + 2006]]

and

ToRadicals[mySimple]

I can make progress if I know (or guess) the algebraic extension:

term= Sqrt[104 Sqrt[6] + 468 Sqrt[10] + 144 Sqrt[15] + 2006];
FullSimplify@AlgebraicNumber[term, {Sqrt[2], Sqrt[5], Sqrt[15]}]

But what if I didn't know the extensions?

I've tried a number of methods, based on FullSimplify, Expand, and so on, but none work.

Suggestions?

Answer 1

There is already such a function on FunctionRepository called RadicalDenest.

term = Sqrt[104 Sqrt[6] + 468 Sqrt[10] + 144 Sqrt[15] + 2006];
ResourceFunction["RadicalDenest"][term]

$13 \sqrt{2}+4 \sqrt{3}+18 \sqrt{5}$

Another possible approach

poly = MinimalPolynomial[term, x]
sol = Solve[Factor[poly, Extension -> Sqrt@{2, 3, 5}] == 0, x]
Select[sol, PossibleZeroQ[(x /. #) - term] &]

$2125355779600 - 13379972960 x^2 + 19011864 x^4 - 8024 x^6 + x^8$

$\left\{\left\{x\to -13 \sqrt{2}-4 \sqrt{3}-18 \sqrt{5}\right\},\left\{x\to 13 \sqrt{2}-4 \sqrt{3}-18 \sqrt{5}\right\},\left\{x\to -13 \sqrt{2}+4 \sqrt{3}-18 \sqrt{5}\right\},\left\{x\to 13 \sqrt{2}+4 \sqrt{3}-18 \sqrt{5}\right\},\left\{x\to -13 \sqrt{2}-4 \sqrt{3}+18 \sqrt{5}\right\},\left\{x\to 13 \sqrt{2}-4 \sqrt{3}+18 \sqrt{5}\right\},\left\{x\to -13 \sqrt{2}+4 \sqrt{3}+18 \sqrt{5}\right\},\left\{x\to 13 \sqrt{2}+4 \sqrt{3}+18 \sqrt{5}\right\}\right\}$

$\left\{\left\{x\to 13 \sqrt{2}+4 \sqrt{3}+18 \sqrt{5}\right\}\right\}$

Related Links:
Radical Denest: an ancient difficult task in symbolic computation,
Heuristic package to denest radicals