4
$\begingroup$

I want to check a claimed identity that involves Log and PolyLog functions. The relation can be found on this paper and more specifically eq.(5.7) on page 35.

The description of the task at hand:

The object

$$ \begin{equation} \Phi(z,\bar{z}) = \frac{1}{z-\bar{z}} \left(\log(z \bar{z}) \log\left(\frac{1-z}{1-\bar{z}}\right) + 2 \text{Li}(z) - 2 \text{Li}(\bar{z}) \right) \end{equation} $$

satisfies the differential equation

$$ \begin{equation} \partial_z \Phi = - \frac{1}{z-\bar{z}}\Phi - \frac{1}{z(z-\bar{z})}\log(-1+z)(-1+\bar{z}) + \frac{1}{(-1+z)(z-\bar{z})}\log(z\bar{z}) \end{equation} $$

The way I went about it is the following:

Define the $\Phi(z,\bar{z})$

Phi[z_][zbar_] := 
 1/(z - zbar) (Log[z zbar] Log[(1 - z)/(1 - zbar)] + 
    2 PolyLog[2, z] - 2 PolyLog[2, zbar])

Define the LHS and RHS of the differential equation that we want to show

eqn1 = D[Phi[z][zbar], z];
eqn2 = -(1/(z - zbar)) Phi[z][zbar] - 
   1/(z (z - zbar)) Log[(-1 + z) (-1 + zbar)] + 
   1/((-1 + z) (z - zbar)) Log[z zbar];

Subtract eqn2 from eqn1 and get a zero

eqn1 - eqn2 // FullSimplify // PowerExpand

This final command, however, does not return a zero.

Any ideas? Is this possible that this is not implemented into Mathematica? I am using 12.0.0 for Linux x86 (64-bit)

$\endgroup$
4
  • $\begingroup$ The authors are quite sloppy unfortunately. They never exactly define what is Li (is it the polylog with n=2?) and in the first term with the log, it's unclear to me if the (-1 + zbar) is inside the log or not. Neither case works btw. $\endgroup$
    – Hans Olo
    Aug 3 at 10:48
  • $\begingroup$ Seeing their Ref[72], I think Li is indeed Polylog with n=2, and it seems that paper is more clear, albeit with a slightly different notation. $\endgroup$
    – Hans Olo
    Aug 3 at 10:50
  • $\begingroup$ @HansOlo Li is indeed the Polylog with n=2. I have checked other sources as well. They call it the dilogarithm, so I guess a bit of sloppy notation does not really matter. I checked that pulling the (-1 + zbar) ourside of the Log only complicates things. $\endgroup$ Aug 3 at 10:57
  • $\begingroup$ I would try substituting numerical values $\endgroup$
    – mikado
    Aug 3 at 11:56
5
$\begingroup$
Clear["Global`*"]

Phi[z_, zbar_] := 
 1/(z - zbar) (Log[z*zbar] Log[(1 - z)/(1 - zbar)] + 2 PolyLog[2, z] - 
    2 PolyLog[2, zbar])

eqn1 = D[Phi[z, zbar], z];
eqn2 = -(1/(z - zbar)) Phi[z, zbar] - 
   1/(z (z - zbar)) Log[(-1 + z) (-1 + zbar)] + 
   1/((-1 + z) (z - zbar)) Log[z*zbar];

Presumably, there are some assumptions given in the paper. Let's assume that Phi is real. This requires

cons = FunctionDomain[Phi[z, zbar], {z, zbar}]

(* (0 < z < 1 && 0 < zbar < 1 && z - zbar != 0 && z zbar > 0) || (0 < z < 1 && 
   zbar < 0 && z - zbar != 0 && z zbar > 0) || (z < 0 && 0 < zbar < 1 && 
   z - zbar != 0 && z zbar > 0) || (z < 0 && zbar < 0 && z - zbar != 0 && 
   z zbar > 0) *)

Then

eqn1 - eqn2 // FullSimplify[#, cons] &

(* 0 *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.