1
$\begingroup$

I try to get a numerically evaluation of the following sum:

$$\sum _{j=0}^{\infty } \frac{j^2}{\sqrt{j \left(j^2+\frac{1}{2}\right)}}$$

using different methods. With Euler-Maclaurin we get

NSum[
j^2/Sqrt[j (j^2 + 1/2)]
, {j, 1, \[Infinity]}
, Method -> "EulerMaclaurin"
, WorkingPrecision ->  20]

with Levin u-transform we get the same result: Infinity

I think the correct sum is $$-0.78403507353706181$$ maybe it is part of some analytic continuation?

$\endgroup$

1 Answer 1

3
$\begingroup$

Start by noticing that the $j=0$ term is zero,

Limit[j^2/Sqrt[j (1/2 + j^2)], j -> 0]
(*    0    *)

so we can sum from $j=1$. Then extract the dominant singular term $\sqrt{j}$ from the sum,

Asymptotic[j^2/Sqrt[j (1/2 + j^2)], j -> ∞]
(*    Sqrt[j]    *)

for easier numerical convergence through analytic continuation:

$$ \sum_{j=1}^{\infty}\frac{j^2}{\sqrt{j\left(j^2+\frac12\right)}} = \sum_{j=1}^{\infty}\sqrt{j} + \sum_{j=1}^{\infty}\left(\frac{j^2}{\sqrt{j\left(j^2+\frac12\right)}}-\sqrt{j}\right)\\ = \zeta\left(-\frac12\right) + \sum_{j=1}^{\infty}\left(\frac{j^2}{\sqrt{j\left(j^2+\frac12\right)}}-\sqrt{j}\right) $$

Zeta[-1/2] + NSum[j^2/Sqrt[j (1/2 + j^2)] - Sqrt[j],
                  {j, 1, ∞}, 
                  Method -> "EulerMaclaurin"] // Chop
(*    -0.783497    *)

By playing with NSum's parameters you may get more accurate values.

$\endgroup$
1
  • 1
    $\begingroup$ It should be noticed that Sum[Sqrt[j], {j, 1, Infinity}, Regularization -> "Dirichlet"] performs Zeta[-(1/2)]. $\endgroup$
    – user64494
    Aug 3, 2021 at 10:27

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.