Join two lists according to False condition

Question

I am new to MMA. I have a question of joining two lists according to a condition. Suppose I have two lists with same number of elements,

l1={a>b,x>y,m>n}
l2={c>d,False,j>k}

I want to join the two lists according to a condition: join each list's element according to their positions in the list if they both are inequalities. If there is a False in l2, then ignore both elements of that position. For example,

1. The first element of l1 is a>b, and the first element of l2 is c>d, then the first element of the new list will be {a>b,c>d}.
2. The second element of l1 is x>y, but the second element of l2 is False. So we will ignore position number 2.
3. The third element of l1 is m>n, and the third element of l2 is j>k, then the second element of the new list will be{m>n,j>k}.

Therefore, the new list will be {{a>b,c>d},{m>n,j>k}}.

Another example:

l3={a>b,c>d,x>y,j>k}
l4={False,False,False,m>n}.

Then the new list I want will be {{j>k,m>m}}

Thank you in advance for your generous help!

Answer 1

One way of going about it is with a, in some sense, fundamental part of MMA called pattern matching via DeleteCases.

l1 = {a > b, x > y, m > n};
l2 = {c > d, False, j > k};
Transpose@{l1, l2} (*Gets corresponding pairs of elements*)
DeleteCases[
  % (*This is the shorthand to refer to the previous output and is technically Out[-1]*),
  {_, False} (*The general structure of a pair of elements such that the second one is exactly False*)
]

(*Output 1*) {{a > b, c > d}, {x > y, False}, {m > n, j > k}}

(*Output 2*) {{a > b, c > d}, {m > n, j > k}}

Here we first transposed the two lists of vectors so that we get a lists of the corresponding elements in each list. Then it's a matter of telling Mathematica which "forms" or "cases" to look out for and delete them with the fortunately native function DeleteCases.

I have a feeling there's another way to do it with Pick, but also that it would take some finagling and, while faster, be more of a "because you can" method.

Answer 2

l1 = {a > b, x > y, m > n};
l2 = {c > d, False, j > k};
MapThread[
 If[#1 =!= False && #2 =!= False, List[#1, #2], Nothing] &, {l1, l2}]

{{a > b, c > d}, {m > n, j > k}}

Answer 3

Select[Transpose[{l1,l2}],#[[2]] =!= False &]

(* {{a > b, c > d}, {m > n, j > k}} *)


Select[Transpose[{l3,l4}],#[[2]] =!= False &]

(* {{j > k, m > n}} *) 

where

l1={a>b,x>y,m>n}
l2={c>d,False,j>k}
l3={a>b,c>d,x>y,j>k}
l4={False,False,False,m>n}

(Original Answer)

Select[Transpose[{l1,l2}],FreeQ[#[[2]], False]&]
(* {{a > b, c > d}, {m > n, j > k}} *)