2
$\begingroup$

I would like to find the range of the function below, but only for values of $a$ strictly greater than zero.

v[a_]=-a*Log[1-(a - a E^(-1 - 1/a + ProductLog[E^(1 + 1/a)]))/a]

In other words: what is the range of $v(a)$, for/conditional on $a>0$ (reals).


  • I have tried this: (ie without restricting) FunctionRange[v[a], a, y], but the computation time is too long, I can't manage to get an output.

  • I also have tried to define the $v(a)$ function over the domain that interests me using this:

    v[a_ /; 0 < a] := -a*Log[1-(a - a E^(-1 - 1/a + ProductLog[E^(1 + 1/a)]))/a] (solution found here), and then FunctionRange[v[a], a, y], but the computation time seems to bee stil too long. Probably due to the fact that my restricted definition doesn't seem to have worked: even in that case, FunctionDomain[v[a],a]returns $a≠0$ (instead of $a>0$ as I would have expected since it is what I defined in the first place).

EDIT

  • This doesn't seem to work either: Assuming[a>0,FunctionRange[v[a], a, y]].
$\endgroup$
5
$\begingroup$
FunctionRange[{-a*
   Log[1 - (a - a E^(-1 - 1/a + ProductLog[E^(1 + 1/a)]))/a], 
  a > 0}, a, y]

5.14988*10^-9 <= y <= 0.5

and warming message:

Unable to find the exact range. Returning bounds on the range
computed using numeric optimization methods

So we have to consider Derivative

FunctionRange[{D[-a*
     Log[1 - (a - a E^(-1 - 1/a + ProductLog[E^(1 + 1/a)]))/a], a] // 
   Evaluate, a > 0}, a, y]

y > 0

It means that v[a] is a monotonic function ! So we just need to calculate the Limit just as @Akku14 have done.

Limit[-a*Log[1 - (a - a E^(-1 - 1/a + ProductLog[E^(1 + 1/a)]))/a], 
 a -> 0, Direction -> "FromAbove"]
Limit[-a*Log[1 - (a - a E^(-1 - 1/a + ProductLog[E^(1 + 1/a)]))/a], 
 a -> ∞]

0

1/2

$\endgroup$
3
$\begingroup$
Limit[v[a], a -> 0, Direction -> -1]

(*   0   *)

Limit[v[a], a -> Infinity]

(*   1/2   *)

NMaximize[{v[a], a > 0}, a, WorkingPrecision -> 100]

(*   {0.4999999999999999999999999999999996695802781800686528047791793409305\
917941358131704720756957033359931, {a -> 
 1.89153358206810035345892896405454026939268176767953621670767804301\
 9662196519029316421185286618066641*10^32}}   *)

NMinimize[{v[a], a > 0}, a, WorkingPrecision -> 100]

(*   {9.2396091222066804246261095335668388330820970607385777570018055570761\
38791443783933838210621794192294*10^-7, {a -> 
 5.52917699540862549895289484183558798401702920323792264099048675666\
3524280963344309794142794231985742*10^-8}}   *)
$\endgroup$
1
  • $\begingroup$ Series[-a* Log[1 - (a - a E^(-1 - 1/a + ProductLog[E^(1 + 1/a)]))/a], {a, 0, 2}, Assumptions -> a > 0] results in $-a \log (a)+a^2 (\log (a)+1)+O\left(a^3\right)$, confirming positive values of v[a] and Series[-a*Log[ 1 - (a - a E^(-1 - 1/a + ProductLog[E^(1 + 1/a)]))/a], {a, Infinity, 2}] results in $\frac{1}{2}-\frac{1}{16 a}+\frac{1}{192 a^2}+O\left(\left(\frac{1}{a}\right)^3\right)$, confirming the inequality v[a]<1/2 at Infinity. $\endgroup$
    – user64494
    Jul 20 at 6:50

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.