Delete columns of table where the sum of column adds to zero

Question

Given,

data = {{1, 0, 1, 0, 1}, {2, 0, 2, 0, 2}, {3, 0, 3, 0, 3}, {4, 0, 4, 
    0, 4}, {5, 0, 5, 0, 5}};

Delete the columns whose sum totals to zero. Specifically, columns 2 and 4. I have tried creating a list of the sums:

list = Total[data, {1}];
{15, 0, 15, 0, 15}

and then summing through this list and deleting the cases in "data" where its total is zero. However, this is not working. If anyone could help me with this problem, I would appreciate it.

Answer 1

f1 = Transpose @* Select[UnequalTo[0] @* Tr] @* Transpose;

f1 @ data

{{1, 1, 1}, {2, 2, 2}, {3, 3, 3}, {4, 4, 4}, {5, 5, 5}}

f2 = Transpose @* DeleteCases[_?(EqualTo[0] @* Tr)] @* Transpose;

f2 @ data

{{1, 1, 1}, {2, 2, 2}, {3, 3, 3}, {4, 4, 4}, {5, 5, 5}}

Answer 2

And another fun one

Drop[data, 
  None, {##, 2} & @@ Flatten@Position[Total@data, 0]] // MatrixForm

Answer 3

Another possibility is to use SequenceCases:

data = {{1, 0, 1, 0, 1}, {2, 0, 2, 0, 2}, {3, 0, 3, 0, 3}, {4, 0, 4, 0, 4}, {5, 0, 5, 0, 5}};

Transpose[Map[If[SequenceCases[#, list_ /; Total[list] =!= 0] === {}, Nothing, #] &, Transpose[data]]]

Answer 4

Another approach is the following:

data = {{1, 0, 1, 0, 1}, {2, 0, 2, 0, 2}, {3, 0, 3, 0, 3}, {4, 0, 4, 0, 4}, {5, 0, 5, 0, 5}};

Transpose[Map[If[Total[data[[All, #]]] === 0, Nothing, data[[All, #]]] &, Range[Length[data]]]]

Answer 5

Another possibility is to use Table:

data = {{1, 0, 1, 0, 1}, {2, 0, 2, 0, 2}, {3, 0, 3, 0, 3}, {4, 0, 4, 0, 4}, {5, 0, 5, 0, 5}};

Transpose[Table[If[Total[data[[All, i]]] > 0, data[[All, i]], Nothing], {i, 1, Length[data]}]]

Answer 6

data = {{1, 0, 1, 0, 1}, {2, 0, 2, 0, 2}, {3, 0, 3, 0, 3}, {4, 0, 4, 
    0, 4}, {5, 0, 5, 0, 5}};

pos = Flatten@Position[Total[data], 0]

{2, 4}

data[[All, pos]] = Nothing

Result:

{{1, 1, 1}, {2, 2, 2}, {3, 3, 3}, {4, 4, 4}, {5, 5, 5}}

Answer 7

We have

data = {{1, 0, 1, 0, 1}, {2, 0, 2, 0, 2}, {3, 0, 3, 0, 3}, {4, 0, 4, 
    0, 4}, {5, 0, 5, 0, 5}};

data // MatrixForm

1. Use Position and Total to locate which columns you want removed and then Delete to delete them.

The code is:

Transpose@
  Delete[Transpose@data, Position[Total@data, 0]] // MatrixForm

2. This is a minor comment. You can use Select and Total as was suggested in the comment but there's no need for Transpose.

The code is:

Select[Total@# != 0 &] /@ data // MatrixForm

Answer 8

Just for fun, another possibility is to use MapIndexed (there has to be at least 10 different ways to solve the same problem in Mathematica. I counted only 7 so far (including in comments). This forum needs to become more active :)

data = {{1, 0, 1, 0, 1}, {2, 0, 2, 0, 2}, {3, 0, 3, 0, 3}, {4, 0, 4, 0, 4}, {5, 0, 5, 0, 5}};

sum = Total[data, {1}]
MapIndexed[If[#1 == 0, data[[All, First[#2]]] = Sequence[], Nothing] &, sum];

Answer 9

Since @Nasser wrote the infamous statement about the 10 ways, I cannot resist.

Drop[data, None, 
  Append[2]@Flatten@Position[Total@data, 0]] // MatrixForm