How to change the default color of the "joined" lines in BarChart function?

Question

is there any way to change the default color of the joined lines in BarChart function? As the joined function turns on (i.e., Joined -> True), the joined lines are plotted automatically with the colors of the bar chart. I want to use other colors to show these reference lines. Many thanks for your help!

Here is a toy example in the Mathematica manual.

BarChart[RandomReal[1, {5, 5}], ChartLayout -> "Stacked", Joined -> True, BarSpacing -> 0.5]

Answer 1

SeedRandom[1]
data = RandomReal[1, {5, 5}];

An alternative hack is to temporarily re-define Darker (which is used to style the joined lines) as the desired line color (say, Red):

Block[{Darker = (Red &)}, 
 BarChart[data, ChartLayout -> "Stacked", Joined -> True, BarSpacing -> 0.5]]

To have different colors for each line, post-process to replace Red with desired colors:

linecolors = {Red, Green, Blue, Orange, Magenta};

Block[{Darker = (Red &)}, 
 ReplaceAll[Red :> Last[linecolors = RotateLeft[linecolors]]]@
  BarChart[data, ChartLayout -> "Stacked", Joined -> True, BarSpacing -> 0.5]]

Answer 2

SeedRandom[1]
data = RandomReal[1, {5, 5}];

bc = BarChart[data, ChartLayout -> "Stacked", Joined -> True, BarSpacing -> 0.5]

Two post-processing hacks:

replaceAll1 = ReplaceAll[Directive[p_, a_, c_] :> Directive[p, a, Red]];

replaceAll2 = ReplaceAll[Line[x_] /; Length[x] > 2 :> {Red, Line @ x}];

replaceAll1 @ bc

replaceAll2 @ bc

same picture

To have a different color for each line:

linecolors = {Red, Green, Blue, Orange, Magenta};

replaceAll1b = ReplaceAll[Directive[p_, a_, c_] :> 
   Directive[p, a, Last[linecolors = RotateLeft[linecolors]]]]

replaceAll2b = ReplaceAll[Line[x_] /; Length[x] > 2 :> 
  {Last[linecolors = RotateLeft[linecolors]], Line @ x}];

replaceAll1b @ bc

replaceAll2b @ bc

same picture

Alternatively, we can use composition of Show and replaceAll1b as the setting for the option DisplayFunction:

displayfunction1 = Show @* replaceAll1b;

BarChart[data, ChartLayout -> "Stacked", Joined -> True, BarSpacing -> 0.5, 
   DisplayFunction -> displayfunction1]

Similarly, with replaceAll2b:

displayfunction2 = Show @* replaceAll2b;

BarChart[data, ChartLayout -> "Stacked", Joined -> True, BarSpacing -> 0.5, 
   DisplayFunction -> displayfunction2]

same picture