How to the plot results of a differential equation

Question

Please help me to plot the solution of a differential equation as a parameter of Delta. Here is what I've tried.

(**Constants**)

tin := -50;
tfin := 50;
t := 0.05;
v := 1;

(**Solve differential equation**)

sol = NDSolve[Delta == Module[{x0},
  Table[x0, {x0, 0, 10}]],
  {I y1'[t] == v t y1[t] +
    Delta y2[t], I y2'[t] == -v t y2[t] + Delta y1[t], y1[tin] == 1, y2[tin] == 0}, {y1, y2}, {t, tin, tfin}];

(**Probability**)

Prob1[t_] := 
      Re[Evaluate[y1[t] /. sol]]^2 + Im[Evaluate[y1[t] /. sol]]^2;

(**we need to plot this result as a function of delta**)

a = Plot[{Prob1[t]}, {Delta, -10, 10}]

Answer 1

Is this the plot you want?

(**Constants**)
tin := -50;
tfin := 50;
t1 := 0.05;
v := 1;

(**Solve differential equation**)
sol = ParametricNDSolve[{I y1'[t] == v t y1[t] + Delta y2[t], 
    I y2'[t] == -v t y2[t] + Delta y1[t], y1[tin] == 1, 
    y2[tin] == 0}, {y1, y2}, {t, tin, tfin}, Delta];

(**Probability**)
Prob1[Delta_, t_] := Abs[y1[Delta][t]]^2;

(**we need to plot this result as a function of delta**)
a = ListPlot[Table[{Delta, Prob1[Delta, t1]} /. sol, {Delta, -10, 10}]]