0
$\begingroup$

I am given two functions, one is of the form $2F1(a,b,c;z)$, where $2F1$ is a hypergeometric series. The other one is a generalized hypergeometric series $3F2(d,e,f;g,h;w)$, where the characters are certain (specific) parameters. Is it possible to use mathematica to find the mapping between those two functions?

Thanks in advance!

$\endgroup$
3
  • $\begingroup$ Depends on the parameters. $\endgroup$
    – Bob Hanlon
    Jun 22 '21 at 17:02
  • $\begingroup$ Thank you for the response. Do you know of any mathematica tool which can be used for this? To be specific the functions are given by $2F_1\left(\frac{1}{4}, \frac{1}{2}, \frac{5}{4} ;-\frac{1}{x^{4}}\right)$ and $_3F_2\left(\frac{1}{6},\frac{1}{3},\frac{2}{3},\frac{7}{6},\frac{3}{2};\frac{-27}{2x^6}\right)$. $\endgroup$
    – john
    Jun 23 '21 at 14:19
  • $\begingroup$ What do you mean by mapping? What kind of answer would you consider satisfactory? $\endgroup$
    – bRost03
    Jul 23 '21 at 18:16
0
$\begingroup$
$Version

(* "12.3.0 for Mac OS X x86 (64-bit) (May 10, 2021)" *)

Clear["Global`*"]

(f21[x_] =
   Hypergeometric2F1[1/4, 1/2, 5/4, -1/x^4]) // TraditionalForm

enter image description here

(f32[x_] =
   HypergeometricPFQ[{1/6, 1/3, 2/3}, {7/6, 
     3/2}, -27/(2 x^6)]) // TraditionalForm

enter image description here

Both functions have even symmetry

f21[x] == f21[-x] && f32[x] == f32[-x]

(* True *)

Both functions asymptotically approach 1 from below

Asymptotic[#, {x, Infinity, 6}] & /@ {f21[x], f32[x]}

(* {1 - 1/(10 x^4), 1 - 2/(7 x^6)} *)

Graphically,

xmax = 2;

Plot[{f21[x], f32[x]}, {x, 0, xmax},
 PlotLegends -> Placed["Expressions", {0.6, 0.4}]]

enter image description here

You can use ParametricPlot to map from one function to the other

Legended[
 ParametricPlot[{f21[x], f32[x]}, {x, 0, xmax},
  Frame -> True,
  FrameLabel -> (Style[#, 12, Bold] & /@
     {HoldForm[f21[x]], 
      HoldForm[f32[x]]}),
  PlotRange -> All,
  ColorFunction -> Function[{f21, f32, x},
    ColorData["Rainbow"][x/xmax]],
  ColorFunctionScaling -> False,
  Epilog -> {Lighter[Gray, 0.5], Dashed,
    Line[{{0, 0}, {1, 1}}]}],
 Placed[
  BarLegend[{"Rainbow", {0, xmax}},
   LegendMarkerSize -> 175,
   LegendLabel -> Style[x, 14, Bold]],
  {0.2, 0.625}]]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.