How to calculate and display possible graphs from 3 directed branches?

Question

I have 3 directed branches and I want to create all possible graphs that can be created from these branches with the condition that each branch is used once.

Q1: How can I do create and graph them?

Here are some example graphs:

Q2: Same as Q1 but now add one more condition that the branch a and branch b are connected as in the image below.

Answer 1

edges = {"A" -> "B", "C" -> "D", "E" -> "F"};

styledlabelededges = MapThread[Labeled[Style[#, #2], #3] &, 
   {edges, 
   {Red, Green, Blue}, 
   Style[#, 16, Background -> White] & /@ {"a", "b", "c"}}];

g0 = Graph[styledlabelededges, 
  ImageSize -> 400, 
  VertexLabelStyle -> Medium, 
  VertexLabels -> "Name", 
  GraphLayout -> "CircularEmbedding"]

ClearAll[vContract]
vContract[g_] := Graph @@ 
  ({EdgeList[g], Options[g]} /. #[[2]] -> #[[1]] /. #[[1]] -> #) &

vreplacements = {{"B", "E"}, {"B", "F"}, {"B", "C"}, {"A", "D"}};

Grid[Partition[vContract[g0] /@ vreplacements, 2], Dividers -> All]

Answer 2

The following is a brute force solution, but it is easy to understand:

This is the starting graph:

g0 = Graph[{"a" -> "b", "c" -> "d", "e" -> "f"}];

You want to contract vertices in all possible ways. For simplicity, we will use IGVertexContract from IGraph/M, as it can handle multiple contractions simultaneously.

Needs["IGraphM`"]

Contracting the two endpoints of an existing edge (such as a -> b) is not allowed:

vertices = VertexList[g0]

disallowed = Partition[vertices, 2]
(* {{"a", "b"}, {"c", "d"}, {"e", "f"}} *)

These are the allowed contractions:

possibleContractions = Complement[Subsets[vertices, {2}], disallowed]
(* {{"a", "c"}, {"a", "d"}, {"a", "e"}, {"a", "f"}, {"b", "c"}, 
    {"b", "d"}, {"b", "e"}, {"b", "f"}, {"c", "e"}, {"c", "f"}, 
    {"d", "e"}, {"d", "f"}} *)

We can get all combinations with Subsets[possibleContractions]. However, given a vertex, we may only contract it with one other vertex, not multiple one. Thus, we need a helper function to detect multiple contractions:

disjointQ[list_] := Length[Union @@ list] == Length[Join @@ list]

These are the allowed contractions: Select[Subsets[possibleContractions], disjointQ].

IGVertexContract[g0, #, GraphStyle -> "VintageDiagram"] & /@ 
 Select[Subsets[possibleContractions], disjointQ]

Here's a screenshot of the first few results:

Note that graphs with reciprocal edges are also generated. You did not make it clear if you need them. If not, just filter them out.