Plotting a graph with legends that don't overlap the graph?

Question

Consider:

tmax = 100;
b = 0.1;
n[t_] := S[t] + P[t]
SP = NDSolveValue[{
    S'[t] == (-b/n[t])*S[t]*P[t],
    P'[t] == (b/n[t])*S[t]*P[t],
    S[0] == 0.99,
    P[0] == 0.01},
   {S, P},
   {t, 0, tmax}];
Plot[{Through[SP[t]], Total@Through[SP[t]]} // Evaluate, {t, 0, tmax},
  PlotStyle -> {Blue, Red, Dashed}, Frame -> True, 
 FrameLabel -> {Style[Time, Black, FontSize -> 15], 
   Style[Density, Black, FontSize -> 15]}, 
 PlotLegends -> Placed[{"A(t)", "B(t)"}, {Right, Top}]]

How do I plot the legends such that it doesn't overlap? for different inputs the graph changes so is there an automatic way for it not to overlap?

Side questions:

i) How do I put a box around the legends after they've been fixed?
ii) How to insert extra parameter in legends without it being a graph in the plot?
iii) How to put another dashed line at 0(and make the dashed lines both black in colour)?

EDIT(using Szabolcs's solution):

tmax = 100;
b = 0.2;
g = 0.2;
n[t_] := S[t] + P[t] + R[t]
SPR = NDSolveValue[{
    S'[t] == (-b/n[t])*S[t]*P[t],
    P'[t] == (b/n[t])*S[t]*P[t] - g*P[t],
    R'[t] == g*P[t],
    S[0] == 0.95,
    P[0] == 0.05,
    R[0] == 0},
   {S, P, R},
   {t, 0, tmax}];

{f1, f2, f3} = SPR;

st = Style[#, 15, Black] &;

Plot[{f1[t], f2[t], f3[t], f1[t] + f2[t] + f3[t], 0}, {t, 0, tmax}, 
 PlotStyle -> {Blue, Red, Green, Directive[Black, Dashed], 
   Directive[Black, Dashed]}, Frame -> True, 
 FrameLabel -> st /@ {"Time", "Density"}, 
 PlotLegends -> 
  Placed[LineLegend[{Blue, Red, Green, Black}, {"A(t)", "B(t)", 
     "C(t)"}, LegendFunction -> Framed], {0.85, 0.65}]]

We have overlapping; how can we place the legends automatically such that it doesn't overlap the graph?

EDIT 2

I manually shifted the legends and it worked fine.

Answer 1

All the legend-related questions can be answered by looking at examples in the PlotLegends doc page. Generally, it is a good idea to look through the examples in the relevant documentation pages.

You can do something like this:

{f1, f2} = SP;

st = Style[#, 15, Black] &;

Plot[{f1[t], f2[t], f1[t] + f2[t], 0},
 {t, 0, tmax}, 
 PlotStyle -> {Blue, Red, Directive[Black, Dashed], Directive[Black, Dashed]},  
 Frame -> True,
 FrameLabel -> st /@ {"Time", "Density"},
 PlotLegends -> 
  Placed[
   LineLegend[{Blue, Red, Black}, {"A(t)", "B(t)", "foo"}, LegendFunction -> Framed], 
   {0.85, 0.65}]
]

How do I plot the legends such that it doesn't overlap?

Use scaled coordinates for the legend position. See the PlotLegends doc page, Scope -> Legend Placement.

How do I put a box around the legends after they've been fixed?

See LegendFunction. There are also several examples in the doc page of PlotLegends under Scope -> Legend content. Check them to see how to use different frame styles.

How to insert extra parameter in legends without it being a graph in the plot?

Use an explicit legend specification. See e.g. LineLegend. There is an example with SwatchLegend in the PlotLegends doc page.

How to put another dashed line at 0(and make the dashed lines both black in colour)?

There are several ways:

• Add constant functions to your plot, as in my example
• Use GridLines with GridLinesStyle.
• Use Epilog with InfiniteLine.

As for making the existing dashed line in your plot black, use Directive to combine styles, as in my example.

Answer 2

I like to use Epilog to insert graphics primitives exactly as I like them. For example:

Plot[{Through[SP[t]], Total@Through[SP[t]]} // Evaluate, {t, 0, tmax},
  PlotStyle -> {Blue, Red, Dashed}, Frame -> True, 
 FrameLabel -> {Style[Time, Black, FontSize -> 15], 
   Style[Density, Black, FontSize -> 15]},
 Epilog -> {Text["A(t)", {65, .25}], Text["B(t)", {70, .8}], 
   Dashing[.02], Line[{{0, 0}, {100, 0}}]}]

Produces:

Answer 3

Clear["Global`*"]

tmax = 100;
n[t_] := S[t] + P[t]

For "different inputs" use ParametricNDSolveValue

SP = ParametricNDSolveValue[{S'[t] == (-b/n[t])*S[t]*P[t], 
    P'[t] == (b/n[t])*S[t]*P[t], S[0] == 99/100, P[0] == 1/100}, 
    {S, P}, {t, 0, tmax}, {b}];

Use Manipulate to see the effects of varying the parameter

Manipulate[
 Plot[
  {Through[SP[b][t]], Total@Through[SP[b][t]], 0} //
   Evaluate, {t, 0, tmax},
  PlotStyle ->
   {Blue, Red, {Black, Dashed}, {Black, Dashed}},
  Frame -> True,
  FrameLabel ->
   (Style[#, Black, FontSize -> 15] & /@
     {Time, Density}),
  PlotLegends -> Placed[
    LineLegend[
     {"A(t)", "B(t)"},
     LegendLabel -> 
      StringForm["b\[ThinSpace]=\[ThickSpace]``", NumberForm[b, {3, 2}]]],
    {If[b >= 0.1, Right, Left], Center}]],
 {{b, 0.1}, 0.01, 1, 0.01,
  Appearance -> "Labeled"}]