Set a background color for several adjacent cells and "page"

Question

I'm using a book style sheet but this question applies to the standard notebook interface as well.

I'm writing a sequence of cells in different styles (text, equation, figure, figure caption, ...) in a special section (e.g., "Example") and would like to color the background of all content in the Example. I group the cells, click-select the associated grouping bar and select Format>Background color to be pink (for example). This changes the background in each cell to be pink. Great!

Almost...

This procedure colors the background of the cells, but not of the "page" behind. This looks a bit choppy and ununified, as here:

Merging cells forces them to be the same style, which of course is not appropriate (as I have text, equations, ...).

I'm seeking a way to color the background page as well, but of course just between the beginning and end of the chosen cells. I'm not interested in the global option of setting the background color of the entire document.

There are several questions here about setting the backgrounds of multiple cells with a single command, but none that I could find that colors the "page" as well.

Answer 1

So I can show the pic:

CurrentValue[{StyleDefinitions, "Text", CellMargins}]

{{66, 10}, {7, 8}}

CurrentValue[{StyleDefinitions, "Text", CellFrameMargins}]

8

Cell[
  CellGroupData[
   {
    Cell[
     "top",
     "Text",
     FontColor -> White,
     Background -> Pink,
     CellMargins -> {{66, 10}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {7, 8}}
     ],
    Cell[
     "bottom",
     "Text",
     FontColor -> White,
     Background -> Pink,
     CellMargins -> {{66, 10}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {7, 8}}
     ]
    },
   Open
   ]
  ] // CellPrint

With different colors

Cell[
  CellGroupData[
   {
    Cell[
     "top",
     "Text",
     FontColor -> White,
     Background -> Pink,
     CellMargins -> {{66, 10}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {7, 8}}
     ],
    Cell[
     "bottom",
     "Text",
     FontColor -> Black,
     Background -> LightBlue,
     CellMargins -> {{66, 10}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {7, 8}}
     ]
    },
   Open
   ]
  ] // CellPrint

This obviously admits a simple stylesheet solution too

Per the comment, Mathematica doesn't resize content in the CellFrameLabels (you can look up on the site the many, many attempts to make that content resize properly). This is a problem with numbered equations. There are three straightforward solutions. The first is less flexible but works with documents where the cell heights can be parametrized

Cell[CellGroupData[{
    Cell["blah", "DisplayFormulaNumbered", FontColor -> White, 
     Background -> Pink,
     CellMargins -> {{66, 3}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {4, 4}},
     CellFrameLabelMargins -> 0,
     CellFrameLabels -> {
       {None,
        Cell[
         TextData[{"(", CounterBox["DisplayFormulaNumbered"], ")"
           }], "DisplayFormulaEquationNumber",
         CellMargins -> {{0, 0}, {0, 0}},
         CellFrameMargins -> {{5, 5}, {4, 4}},
         TextAlignment -> {Center, Center},
         CellSize -> {Automatic, 26}
         ]
        },
       {None, None}
       }
     ],
    Cell["top", "FigureCaption", FontColor -> Black, Background -> LightBlue,
     CellMargins -> {{66, 3}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {4, 4}}
     ]
    }, Open]
  ] // CellPrint

You'll notice it spans fine, but this is fragile because I hard-coded the height and it also floats oddly to the top-right corner and this is basically unfixable.

The second option is to remove the background on the labels and make sure the label widths are identical

Cell[CellGroupData[{
    Cell["blah", "DisplayFormulaNumbered", FontColor -> White, 
     Background -> Pink,
     CellMargins -> {{66, 3}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {4, 4}},
     CellFrameLabels -> {
       {None,
        Cell[
         TextData[{"(", CounterBox["DisplayFormulaNumbered"], ")"}], 
         "DisplayFormulaEquationNumber",
         FontColor -> Pink,
         Background -> None,
         CellSize -> {25, Automatic},
         CellMargins -> {{0, 0}, {0, 0}}
         ]
        },
       {None, None}
       }
     ],
    Cell["top", "FigureCaption", FontColor -> Black, Background -> LightBlue,
     CellMargins -> {{66, 3}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {4, 4}},
     CellFrameLabels -> {
       {None,
        Cell[
         "",
         "DisplayFormulaEquationNumber",
         CellSize -> {25, Automatic},
         Background -> None,
         CellMargins -> {{0, 0}, {0, 0}}
         ]
        },
       {None, None}
       }
     ]
    }, Open]
  ] // CellPrint

This is a much more robust solution. It is worth noting that the width is hard coded.

A final possibility, again, where the label width is hard coded, is to use a negative value for CellFrameLabelMargins. To do this, again, both the upper and lower cells need a label.

Cell[CellGroupData[{
    Cell["blah", "DisplayFormulaNumbered", FontColor -> White, 
     Background -> Pink,
     CellMargins -> {{66, 3}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {4, 4}},
     CellFrameLabelMargins -> -20
     ],
    Cell["top", "FigureCaption", FontColor -> Black, Background -> LightBlue,
     CellMargins -> {{66, 3}, {0, 0}},
     CellFrameMargins -> {{8, 8}, {4, 4}},
     CellFrameLabelMargins -> -20,
     CellFrameLabels -> {
       {None,
        Cell[
         "",
         "DisplayFormulaEquationNumber",
         Background -> None,
         CellMargins -> {{0, 0}, {0, 0}}
         ]
        },
       {None, None}
       }
     ]
    }, Open]
  ] // CellPrint

If you're interested in using these cells, make sure the starting content will allow you to type what you want (i.e. "" for text, BoxData[""] for code, and BoxData@FormBox["", TraditionalForm] for equations). Here's an example of this with equations

Cell[
  CellGroupData[{
    Cell[
     BoxData@FormBox["", TraditionalForm],
     "DisplayFormulaNumbered",
     TextAlignment -> Center, FontColor -> White, Background -> Pink, 
     CellMargins -> {{66, 3}, {0, 0}}, CellFrameMargins -> {{8, 8}, {4, 4}}, 
     CellFrameLabelMargins -> -20], 
    Cell["top", "FigureCaption", FontColor -> Black, Background -> LightBlue, 
     CellMargins -> {{66, 3}, {0, 0}}, CellFrameMargins -> {{8, 8}, {4, 4}}, 
     CellFrameLabelMargins -> -20, 
     CellFrameLabels -> {{None, 
        Cell["", "DisplayFormulaEquationNumber", Background -> None, 
         CellMargins -> {{0, 0}, {0, 0}}]}, {None, None}}]},
   Open]
  ] // CellPrint

then I can type math in the top cell