How can I change the size of the plot markers

Question

I use ListPlot in order to plot four sets of data and also insert legends in my plot. Here is the Mathematica code

data1 = {{0, 48}, {50, 59}, {100, 69}, {150, 78}, {200, 86}, {250, 
87}, {300, 88}, {350, 88.5}, {400, 89}, {450, 89.5}, {500, 90}};
data2 = {{0, 50}, {21, 57}, {45, 65}, {69, 73}, {100, 82}, {150, 
86}, {200, 90}, {250, 90.5}, {300, 91}, {350, 92}, {400, 
93}, {450, 93.5}, {500, 94}};
data3 = {{0, 55}, {50, 60}, {100, 65}, {150, 72}, {200, 80}, {250, 
84}, {300, 87}, {350, 89}, {400, 91}, {450, 91.5}, {500, 92}};
data4 = {{0, 63}, {50, 66}, {100, 69}, {150, 72}, {200, 74.5}, {250, 
77}, {300, 79}, {350, 81}, {400, 83}, {450, 85}, {500, 87}};

col = {Blue, Darker[Green], Red, Magenta};
leg = {"\!\(\*SubscriptBox[\(L\), \(z\)]\) = 5", 
"\!\(\*SubscriptBox[\(L\), \(z\)]\) = 20", 
"\!\(\*SubscriptBox[\(L\), \(z\)]\) = 40", 
"\!\(\*SubscriptBox[\(L\), \(z\)]\) = 60"};
plrange = {45, 100};

P0 = ListPlot[{data1, data2, data3, data4}, Frame -> True, 
PlotStyle -> Table[{Thickness[0.003], col[[i]]}, {i, 1, 4}], 
Joined -> True, PlotMarkers -> {Automatic, 12}, 
FrameLabel -> {Subscript["M", "n"], 
"Percentage of chaotic orbits (%)"}, 
FrameStyle -> Directive[FontSize -> 17, FontFamily -> "Helvetica"], 
PlotRange -> plrange, Axes -> False, ImageSize -> 600, 
PlotLegends -> 
LineLegend[leg, LegendMarkers -> Automatic, 
LegendMarkerSize -> {{20, 25}}, 
LabelStyle -> 
 Directive[FontSize -> 15, FontFamily -> "Helvetica"]]]

which produces the following output using version 9

My main issue is how to increase the size of the plot markers in the legend. Inside the main plot, I can control the size of the markers by PlotMarkers -> {Automatic, 12}. On the other hand, even though I tried a lot, I cannot do the same regarding the markers in the legend. Any ideas?

---

Update 2015-07-22: In versions 10.x, the above input does create legend markers that are the same size as in the plot itself. But if we specify custom plot makers, we will quickly discover that the legend markers will be inconsistently sized.

ListPlot[
 Table[Accumulate@RandomReal[1, 10] + i, {i, 2}],
 PlotMarkers -> {
   Graphics[{Disk[]}, ImageSize -> 7], 
   Graphics[{Rectangle[]}, ImageSize -> 13]
 },
 Joined -> True,
 PlotLegends -> {"line1", "line2"}
 ]

So the fundamental issue remains.

Answer 1

You also aren't getting the right line thickness in your legend. I'd suggest a slightly different route, of creating custom legend markers, similar to the method described in this answer, and including them in a SwatchLegend.

legmarkers =  MapThread[Graphics[{#1, AbsoluteThickness[2], 
     Line[{{-1, 0}, {1, 0}}], #2}] &, {col, {Disk[{0, 0}, 0.3], 
    Rectangle[{-0.3, -0.3}, {0.3, 0.3}], 
    GeometricTransformation[
     Polygon[{{-0.3, -0.3}, {0.3, -0.3}, {0.3, 0.3}, {-0.3, 0.3}}], 
     RotationTransform[45 Degree]], 
    Polygon[0.3 ({{1, -Sqrt[3.]/2}, {0, 
         Sqrt[3]/2}, {-1, -Sqrt[3.]/2}})]} }]

You can then specify the markers as shown. Notice that I had to tweak the LegendMarkerSize option to get the aspect ratio of the graphics correct.

P0 = ListPlot[{data1, data2, data3, data4}, Frame -> True, 
  PlotStyle -> Table[{Thickness[0.003], col[[i]]}, {i, 1, 4}], 
  Joined -> True, PlotMarkers -> {Automatic, 12}, 
  FrameLabel -> {Subscript["M", "n"], 
    "Percentage of chaotic orbits (%)"}, 
  FrameStyle -> Directive[FontSize -> 17, FontFamily -> "Helvetica"], 
  PlotRange -> plrange, Axes -> False, ImageSize -> 600, 
  PlotLegends -> 
   SwatchLegend[leg, LegendMarkers -> legmarkers , 
    LegendMarkerSize -> {{30, 12}}, 
    LabelStyle -> 
     Directive[FontSize -> 15, FontFamily -> "Helvetica"]]]

Answer 2

In 10.x, the simplest thing is to specify the PlotMarkers directly, but as noted, the legends ignore ImageSize if specified within the graphic. The correct way to do this is to use the

{{g1, s1}, {g2, s2} ...}

form of PlotMarkers, e.g.

ListPlot[Table[Accumulate@RandomReal[1, 10] + i, {i, 2}], 
 PlotMarkers -> {{Graphics[{Disk[]}], 1/4}, {Graphics[{Rectangle[]}], 1/8}}, 
 Joined -> True, PlotLegends -> {"line1", "line2"}]

The reason is the legend is not otherwise passed any sizing info, e.g.

In[25]:= Options[g[[2,1]], LegendMarkers]

Out[25]= {LegendMarkers -> 
 {{Graphics[{Disk[]}, ImageSize -> 7],Automatic}, 
  {Graphics[{Rectangle[]}, ImageSize -> 13], Automatic}}}

where g is your version, and note, I swapped GraphicsBox for Graphics for readability. As these are essentially put together using Inset, the graphic is assumed to take the entire picture, and then it is scaled down to size. But, the scaling is now set to Automatic.

Answer 3

For version 10.x the answer can be found in the documentation:

ListPlot[Table[Accumulate@RandomReal[1, 10] + i, {i, 2}], 
 PlotMarkers -> {{"\[FilledCircle]", 20}, {"\[FilledSquare]", 10}}, 
 Joined -> True, PlotLegends -> {"line1", "line2"}]

This should work for graphics objects like the OP used too.