How to obtain numerical solutions of a system of two equations with two unknowns?

Question

I have two equations with two unknowns $-10<x<0$ and $0<y<15$ $$3 y \cosh (4 x) \cos (y)+(2 x+5) \cosh (x) \sin (y)=0,\\3 x \cosh (x) \cos (y)-(2 x+5) \sinh (x) \cos (y)=0$$

• I would like to find numerical solutions of $(x,y)$ which solve this system of equations. I use NSolve but it does not work.

NSolve[{3 y Cos[y] Cosh[4 x] + (5 + 2 x) Cosh[x] Sin[y] == 0, 
  3 x Cos[y] Cosh[x] - (5 + 2 x) Cos[y] Sinh[x] == 0}, {x, y}]

• Then, I want to show those points in a plot.

Any comments are greatly appreciated.

Answer 1

Clear["Global`*"]

EDIT: Corrected intervals in Solve

sol = Solve[{3 y Cos[y] Cosh[4 x] + (5 + 2 x) Cosh[x] Sin[y] == 0, 
    3 x Cos[y] Cosh[x] - (5 + 2 x) Cos[y] Sinh[x] == 0, -10 < x < 0, 
    0 < y < 15}, {x, y}] /. r_Root :> N[r]

(* {{x -> -(5/2), y -> π/2}, {x -> -(5/2), y -> (3 π)/2}, {x -> -(5/2), 
  y -> (5 π)/2}, {x -> -(5/2), y -> (7 π)/2}, {x -> -(5/2), 
  y -> (9 π)/2}, {x -> -0.737455, y -> 1.66515}, {x -> -0.737455, 
  y -> 4.74558}, {x -> -0.737455, y -> 7.87399}, {x -> -0.737455, 
  y -> 11.0099}, {x -> -0.737455, y -> 14.1483}} *)

If Solve or NSolve doesn't work, use FindRoot

sol = Flatten[
  Outer[FindRoot[{3 y Cos[y] Cosh[4 x] + (5 + 2 x) Cosh[x] Sin[y] == 
       0, 3 x Cos[y] Cosh[x] - (5 + 2 x) Cos[y] Sinh[x] == 
       0}, {{x, #1}, {y, #2}}] &, {-3, -1}, {2, 4, 8, 11, 14}], 1]

(* {{x -> -2.5, y -> 1.5708}, {x -> -2.5, y -> 4.71239}, {x -> -2.5, 
  y -> 7.85398}, {x -> -2.5, y -> 10.9956}, {x -> -2.5, 
  y -> 14.1372}, {x -> -0.737455, y -> 1.66515}, {x -> -0.737455, 
  y -> 4.74558}, {x -> -0.737455, y -> 7.87399}, {x -> -0.737455, 
  y -> 11.0099}, {x -> -0.737455, y -> 14.1483}} *)

Plotting,

ContourPlot[{3 y Cos[y] Cosh[4 x] + (5 + 2 x) Cosh[x] Sin[y] == 0, 
  3 x Cos[y] Cosh[x] - (5 + 2 x) Cos[y] Sinh[x] == 0}, {x, -10, 0}, {y, 0, 
  15}, Epilog -> {Red, AbsolutePointSize[4], Point[{x, y} /. sol]}, 
 PlotPoints -> 75, MaxRecursion -> 5, 
 PlotLegends -> Placed["Expressions", Top]]