2
$\begingroup$

Below is the code.

Reduce[(a + b - c) (a - b + c) (-a + b + c) (a + b + c) >= 0 && 0 < a <= 1 && 0 < b <= 1 && 0 < c <= 1, {a, b, c}]

This does generate the constraints on $a,b$ and $c$ but can it be simplified further to a readable form?

Any help would be highly appreciated.

$\endgroup$
4
  • $\begingroup$ How do you imagine a simplification of (0 < a < 1/ 2 && ((a + b >= c && ((a == b && a < b + c) || (0 < b < a && a <= b + c) || (a + c >= b && a < b && a + b <= 1))) || (a + c >= b && b <= 1 && a + b > 1 && c <= 1))) || (1/2 <= a < 1 && ((c <= 1 && ((a == b && 0 < c) || (a + c >= b && a < b && b <= 1) || (a > b && a + b >= 1 && a <= b + c))) || (a + b < 1 && a + b >= c && a <= b + c && b > 0))) || (a == 1 && c <= 1 && ((b == 1 && 0 < c) || (b + c >= 1 && 0 < b && b < 1)))? $\endgroup$
    – user64494
    May 21 at 16:19
  • $\begingroup$ The original argument to Reduce is a more compact form. Asking to solve for {a, b, c} is what causes the expanded form. If you want to visualize the expression use RegionPlot3D[(a + b - c) (a - b + c) (-a + b + c) (a + b + c) >= 0 && 0 < a <= 1 && 0 < b <= 1 && 0 < c <= 1, {a, 0, 1}, {b, 0, 1}, {c, 0, 1}, PlotPoints -> 100, MaxRecursion -> 5] $\endgroup$
    – Bob Hanlon
    May 21 at 16:34
  • $\begingroup$ @BobHanlon Thanks for the help. $\endgroup$
    – Saliq Shah
    May 21 at 17:02
  • $\begingroup$ BTW, Maple 2021 produces the same result. $\endgroup$
    – user64494
    May 21 at 17:37
2
$\begingroup$

Let us make

 Reduce[(a + b - c) (a - b + c) (-a + b + c) (a + b + c) >= 0 && {a, b, c} > 0, {a, b, c}]

a > 0 && ((0 < b < a && a - b <= c <= a + b) || (b == a && a - b < c <= a + b) || (b > a && -a + b <= c <= a + b))

and then add {a,b,c} <= 1:

a > 0 && ((0 < b < a && a - b <= c <= a + b) || (b == a && 
 a - b < c <= a + b) || (b > a && -a + b <= c <= a + b)) && {a,b,c} <= 1

This is a simpler expression than the result of your code, but equivalent to it as

Resolve[ForAll[{a, b, c}, Equivalent[  a > 0 && ((0 < b < a && a - b <= c <= a + b) || (b == a && 
a - b < c <= a + b) || (b > a && -a + b <= c <= a + b)) && {a,
b, c} <= 1, (a + b - c) (a - b + c) (-a + b + c) (a + b + c) >=
0 && {a, b, c} > 0 && {a, b, c} <= 1]], Reals]

True

shows.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.