1
$\begingroup$

I have been solving this equation x^x^x == 36 , Mathematica does not give me a solution by applying traditional methods , neither with Solve , nor with Reduce , and so I've used the Newton-Raphson method and arrived to this approximation 2.10703646396.

Someone told me that the result is a non-square root , well in particular

  • Does anyone know an approach to solve this equation in Mathematica?
  • Is it possible to find a radical approximation with minimal error?

I have tried

Reduce[ x^x^x == 36, x > 0, x]
Solve[ x^x^x == 36, x > 0, x]
Improve this question
$\endgroup$
2
  • 2
    $\begingroup$ Here is the proper syntax: Reduce[x^x^x == 36 && x > 0, x] and Solve[x^x^x == 36 && x > 0, x] The output of these is a RootObject. MMA can sometimes convert RootObjects to radicals using ToRadicals (see the documentation), but it doesn't seem to work in this case. I suspect the reason is that ToRadicals is designed for cubics and quartics. For more background, see mathematica.stackexchange.com/questions/217138/… and mathematica.stackexchange.com/questions/13767/… $\endgroup$
    – theorist
    Commented May 12, 2021 at 0:06
  • 2
    $\begingroup$ @theorist ToRadicals will not approximate a radical if given an expression that is not algebraic. $\endgroup$
    – Daniel Lichtblau
    Commented May 12, 2021 at 2:13

1 Answer 1

Reset to default
4
$\begingroup$

Symbolic functions like Reduce and Solve provide an exact solution of the given equation in terms of the Root objects.

xs = x /. First @ Solve[ x^x^x == 36 && x > 0, x]

Root[{-36 + #1^#1^#1 & ,
       2.10703646395674928520879246974369419433`20.601147030102787}]

This is not an algebraic number and cannot be represented as a root of polynomial with rational coefficients. Nonetheless solutions of transcendental equations represented with Root objects are exact as well even though they cannot be represented in terms of radicals. For more detailed discussion of Root objects see e.g. How do I work with Root objects?

Our solution xs can be numerically approximated with arbitrary precision, e.g.

N[ xs, 50]

2.1070364639567492852140489758794729541219024075415

We can also find an algebraic approximation of the solution xs with RootApproximant, e.g. in terms of a root of third order polynomial:

RootApproximant[xs, 3] // InputForm

Root[-9946 + 4127*#1 - 262*#1^2 + 258*#1^3 & , 1, 0] 

ToRadicals @ %

1/387 (131 + (3850120229 + 15093 Sqrt[98585357943])^(1/3)/2^(2/3) - 
      1562827/(2 (3850120229 + 15093 Sqrt[98585357943]))^(1/3))

this is quite a good approximation

N[{xs, RootApproximant[xs, 3]}, 17]

 {2.1070364639567493, 2.1070364639567491}

Let's represent the solution graphically:

Plot[ -Log[36] + Log[x] x^x, {x, 0, 2.5}, PlotStyle -> Thick]

enter image description here

Warning

Equation x^x^x == 36 can be rewritten equivalently as Exp[x Log[x]] Log[x] - Log[36] == 0. Solving it with Reduce or Solve yields another Root object which is the same solution even though Mathematica does not demonstrate automatically that they are mathematically equal.

Improve this answer
$\endgroup$
1
  • 1
    $\begingroup$ You can show the two Root expressions are equal to any desired precision using With[{wp = 1000}, N[xs, wp] - N[xs2, wp]] $\endgroup$
    – Bob Hanlon
    Commented May 12, 2021 at 13:51

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.