1
$\begingroup$

I want to know if the following integral can be evaluated in Mathematica:

$$ g(t)= c\int_{0}^{1-t} t^{m-1}\left[(u+t)^{m}-u^{m}\right]^{n-2}(u+t)^{m-1} d u$$ where $$ c= m^2n(n-1)$$

g[u_] = ct^(m - 1)((u + t)^m - u^m)^(n - 2)(u + t)^(m - 1)
Integrate[g[u], {u, 0, 1 - t},Assumptions->{m>0,n>0}]

Could somebody kindly paste it in Mathematica under the assumptions $m,n \in \mathbb{N},$ the set of natural numbers? I would also like to know if we can evaluate it in Mathematica for the case when $m$ and $n$ approach infinity and the numerical evaluation of the integral for given $m$ and $n$. Right now I do not have access to Mathematica. I would be highly grateful for any help.

$\endgroup$
8
  • $\begingroup$ You have many syntactic errors. $\endgroup$ May 7, 2021 at 5:46
  • $\begingroup$ @David G.Stork ,now I have written the integral in mathematical form as well.kindly point out the syntactic errors $\endgroup$ May 7, 2021 at 6:06
  • 1
    $\begingroup$ Wrong: g[u] =. Right: g[u_] := . Wrong: t^{m - 1}. Right: t^(m-1). Wrong: [(u + t)^{m} - u^{m}. Right: (u+t)^m - u^m]^(n - 2). Wrong: (u + t)^{m - 1}. Right: (u+t)^(m-1). Also: don't include useless, irrelevant constant factor. Waste of time. $\endgroup$ May 7, 2021 at 6:31
  • 1
    $\begingroup$ c = m^2*n*(n - 1); c*Integrate[ t^(m - 1)*((u + t)^m - u^m)^(n - 2)*(u + t)^(m - 1), {u, 0, 1 - t}] $\endgroup$
    – cvgmt
    May 7, 2021 at 7:59
  • $\begingroup$ Maybe try Wolfram alpha. $\endgroup$
    – bill s
    May 7, 2021 at 11:11

1 Answer 1

4
$\begingroup$

Let us focus on the underlying indefinite integral,

Integrate[((u + t)^m - u^m)^(n - 2)*(u + t)^(m - 1), u, 
    Assumptions -> (n | m) ∈ Integers && n > 1]

Unfortunately, it returns unevaluated. In contrast, Integrate returns a result for any n satisfying the assumptions. For instance,

With[{n = 3}, Integrate[((u + t)^m - u^m)^(n - 2)*(u + t)^(m - 1), u]]
(* (t + u)^(2 m)/(2 m) - (u^(1 + m) (t + u)^m (1 + u/t)^-m 
   Hypergeometric2F1[1 - m, 1 + m, 2 + m, -(u/t)])/((1 + m) t) *)

To seek a pattern for the solution, try

Table[Simplify[Integrate[((u + t)^m - u^m)^(n - 2)*(u + t)^(m - 1), u],
    m ∈ Integers], {n, 2, 10}]

from which the general solution easily can be identified.

f[n_?IntegerQ] := (t + u)^((n - 1) m)/((n - 1) m) +  
    Sum[(-1)^nn Binomial[n - 2, nn] t^((n - nn - 1) m) u^(1 + nn m) Hypergeometric2F1[
    1 - (n - nn - 1) m, 1 + nn m, 2 + nn m, -u/t]/((1 + nn m ) t), {nn, 1, n}]

This result can be tested by

Table[Simplify[Integrate[((u + t)^m - u^m)^(n - 2)*(u + t)^(m - 1), u] == f[n], 
    m ∈ Integers], {n, 2, 10}]
(* {True, True, True, True, True, True, True, True, True} *)

after which the multiplier c t^(m - 1) and the limits of integration can be applied.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.