I am trying to find the area between these three curves y=6/x, y=x+4 and y=x-4. Is there any good command to use in mathematica to make it simple?
2 Answers
To get an overview:
ContourPlot[{y == 6/x, y == x + 4, y == x - 4}, {x, -10, 10}, {y, -10, 10}]
Define it as a region through logical combinations, the signs of which you have to guess a bit, based on the above plot:
J = ImplicitRegion[x*y < 6 && x-4 < y < x+4, {x, y}];
RegionPlot[J]
The area is
RegionMeasure[J] // FullSimplify
(* 8*Sqrt[10] + 12*ArcTanh[2*Sqrt[10]/7] *)
% // N
(* 43.1902 *)
This problem is easy to solve by changing to a different coordinate system. Let $$p=\tfrac12(x+y),\\q=y-x.$$ The Jacobian is easy to show to be equal to 1.
Next, we plot the region to determine the integration domain.
fig = ContourPlot[{y == 6/x, y == x + 4, y == x - 4, y == x, y == -x},
{x, -10, 10}, {y, -10, 10},
PlotLegends -> {p^2 == 6 + q^2/4, q == 4, q == -4, q == 0, p == 0}]
Now we see that $$\text{Area} = 4\int_0^{4}\!dq\int_0^{\sqrt{6+q^2/4}}\!dp$$.
Putting this into MA yields
4 Integrate[1, {q, 0, 4}, {p, 0, Sqrt[6 + q^2/4]}]
$$\text{Area} = 8 \left(\sqrt{10}+3 \mathrm{ArcSinh}\sqrt{\frac{2}{3}}\right).$$
ContourPlot[{y == 6/x, y == x + 4, y == x - 4}, {x, -10, 10}, {y, -10, 10}]
gives you an idea of the area's shape. $\endgroup$