1
$\begingroup$

How to approximate $$\sum_{n=1}^\infty\frac{{4n\choose 2n}\overline{H}_{2n}}{n 2^{4n}} ?$$ Where $\overline{H}_n=\sum_{k=1}^n \frac{(-1)^{k-1}}{k}$ is the skew harmonic number. The mathematica command for $\overline{H}_{2n}$ is $\log[2]-\text{LerchPhi}[-1,1,2n+1]$.

I tried Michael E2' command:

 major = Normal@Series[(Log[2] - LerchPhi[-1, 1, 2 n + 1]) Binomial[4 n, 
   2 n]/(n 2^(4 n)), {n, Infinity, 12}];
 majorsum = Sum[major, {n, Infinity}];
 majorsum + 
 NSum[(Log[2] - LerchPhi[-1, 1, 2 n + 1]) Binomial[4 n, 
  2 n]/(n 2^(4 n)) - major, {n, 1, Infinity}, NSumTerms -> 20, 
 WorkingPrecision -> 20, Method -> "WynnEpsilon"]

but it gave a result in terms of $n$ : enter image description here

which something unusual to see. Is there any other command or maybe we can do little changes to Michael E2's solution?

Thank you,

$\endgroup$
5
  • $\begingroup$ How about a simple-minded approach N[Sum[Binomial[4 n, 2 n]*(Log[2] - LerchPhi[-1, 1, 2 n + 1])/n/ 2^(4 n), {n, 1, 2000}], 15] which results in 0.584900923610039? I leave an estimate of the rest on your own (or ask it in MSE). $\endgroup$
    – user64494
    Apr 6, 2021 at 6:04
  • $\begingroup$ N[Binomial[4 n, 2 n]*(Log[2] - LerchPhi[-1, 1, 2 n + 1])/n/2^(4 n) /. n -> 2000, 15] equals 3.09099743792782*10^-6. $\endgroup$
    – user64494
    Apr 6, 2021 at 6:14
  • $\begingroup$ Making use of that , N[Sum[Normal[ Series[Binomial[4 n, 2 n]*(Log[ 2] + (-1)^ n*(1/2)*(HarmonicNumber[-(1/2) + n/2] - HarmonicNumber[n/2]))/n/2^(4 n), {n, Infinity, 10}]], {n, 2001, Infinity}], 15] results in 0.0123649321640052. $\endgroup$
    – user64494
    Apr 6, 2021 at 6:19
  • $\begingroup$ It should be Log[2] - (-1)^n*LerchPhi[-1, 1, 1 + n] instead of Log[2] - LerchPhi[-1, 1, 1 + n] in your question. $\endgroup$
    – user64494
    Apr 6, 2021 at 12:35
  • $\begingroup$ @user64494 note that $(-1)^{2n}=1$. $\endgroup$ Apr 7, 2021 at 2:21

3 Answers 3

4
$\begingroup$

You can use a different representation of the skew harmonic numbers in terms of harmonic numbers: $$ \bar{H}_n=\frac{1}{2} (-1)^n \left(H_{\frac{n-1}{2}}-H_{\frac{n}{2}}\right)+\log (2) $$ This expression can be expanded around infinity

f[n_] := HarmonicNumber[(n - 1)/2] - HarmonicNumber[n/2]
Series[f[n], {n, Infinity, 6}]

$$-\frac{1}{n}+\frac{1}{2 n^2}-\frac{1}{4 n^4}+\frac{1}{2 n^6}+O\left({n}^{-7}\right)$$

and summed up

Sum[Binomial[4 n, 2 n]/(n 2^(4 n)) (Log[2] + (-1)^n 
    (-(1/(2 n)) + 1/(4 n^2) - 1/(8 n^4) + 1/(4 n^6))), 
    {n, Infinity}]
(*3/64 (4 HypergeometricPFQ[{1, 1, 1, 5/4, 7/4}, {3/2, 2, 2, 2}, -1]
-2 HypergeometricPFQ[{1, 1, 1, 1, 5/4, 7/4}, {3/2, 2, 2, 2, 2}, -1] 
+ HypergeometricPFQ[{1, 1, 1, 1, 1, 1, 5/4, 7/4}, {3/2, 2, 2, 2, 2, 2, 2}, -1]
-2 HypergeometricPFQ[{1, 1, 1, 1, 1, 1, 1, 1, 5/4, 7/4}, {3/2, 2, 2, 2, 2, 2, 2, 2, 2}, -1] 
+8 HypergeometricPFQ[{1, 1, 5/4, 7/4}, {3/2, 2, 2}, 1] Log[2])*)
$\endgroup$
9
  • $\begingroup$ The result of Series is not a good approximation for f[n] if n is small. Your calculation is not correct:N[3/64 (4 HypergeometricPFQ[{1, 1, 1, 5/4, 7/4}, {3/2, 2, 2, 2}, -1] - 2 HypergeometricPFQ[{1, 1, 1, 1, 5/4, 7/4}, {3/2, 2, 2, 2, 2}, -1] + HypergeometricPFQ[{1, 1, 1, 1, 1, 1, 5/4, 7/4}, {3/2, 2, 2, 2, 2, 2, 2}, -1] - 2 HypergeometricPFQ[{1, 1, 1, 1, 1, 1, 1, 1, 5/4, 7/4}, {3/2, 2, 2, 2, 2, 2, 2, 2, 2}, -1] + 8 HypergeometricPFQ[{1, 1, 5/4, 7/4}, {3/2, 2, 2}, 1] Log[2])] is 0.72777.See my comments to the question. $\endgroup$
    – user64494
    Apr 6, 2021 at 10:43
  • $\begingroup$ I did my answer, having collected my comments. Don't hesitate to ask for further explanation in need. $\endgroup$
    – user64494
    Apr 6, 2021 at 10:56
  • $\begingroup$ I wonder the upvoter: the answer is wrong as explained in my comments. $\endgroup$
    – user64494
    Apr 6, 2021 at 11:51
  • $\begingroup$ @user64494 I voted for the different representation of the skew harmonic number. $\endgroup$
    – Greg Hurst
    Apr 6, 2021 at 12:06
  • $\begingroup$ @ChipHurst: That was noticed in my comment to the question before the yarchik's answer. $\endgroup$
    – user64494
    Apr 6, 2021 at 12:19
2
$\begingroup$

We can use Michael E2's method with a different representation for the skew Harmonic number:

f[n_] = (Log[2] + (-1)^n/2 (HarmonicNumber[(n - 1)/2] - HarmonicNumber[n/2])) Binomial[4n, 2n]/(n*2^(4n));

major = Normal@Series[f[n], {n, Infinity, 12}];
majorsum = Sum[major, {n, Infinity}];
approxtail = N[Sum[f[n] - major, {n, 1, 500}], 30];

majorsum + approxtail
0.79573336271051611600770246918
$\endgroup$
1
  • $\begingroup$ Thank you for the efforts (+1) $\endgroup$ Dec 5, 2021 at 7:39
1
$\begingroup$

First, we directly calculate the sum of the first 2000 terms:

N[Sum[Binomial[4 n, 2 n]*(Log[2] - LerchPhi[-1, 1, 2 n + 1])/n/     2^(4 n), {n, 1, 2000}], 15]

0.584900923610039

Second, making use of that answer by Andreas,

N[Sum[Normal[Series[Binomial[4 n,2 n]*(Log[2] + (-1)^n*(1/2)*(HarmonicNumber[-(1/2) + n/2] - 
HarmonicNumber[n/2]))/n/2^(4 n), {n, Infinity, 10}]], {n,2001, Infinity}], 15]

0.0123649321640052

Finally, the sum under consideration approximately equals 0.0123649321640052 + 0.584900923610039.

Addition. There is a substantial difference between

N[Sum[Binomial[4 n, 2 n]*(Log[2] - LerchPhi[-1, 1, 2 n + 1])/n/
2^(4 n), {n, 1, 2000}], 15]

0.584900923610039

and

N[Sum[Binomial[4 n, 
2 n]*(Log[
    2] + (-1)^
     n*(1/2)*(HarmonicNumber[-(1/2) + n/2] - 
      HarmonicNumber[n/2]))/n/2^(4 n), {n, 1, 2000}], 15]

0.783368430546511

The OP writes an incorrect formula Log[2] - LerchPhi[-1, 1, 1 + n] instead of the correct one Log[2] - (-1)^n*LerchPhi[-1, 1, 1 + n] in the question.

$\endgroup$
1
  • $\begingroup$ Thanks for the efforts (+1) $\endgroup$ Dec 5, 2021 at 7:39

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.