0
$\begingroup$

How I can calculate a limit using l'Hopital's Rule, limit of (e^-2x +3x)^1/x , as x approaches infinity.

How can I do it in Mathematica?

$\endgroup$
2
  • 1
    $\begingroup$ Did you look in the documentation to the Limit command? The second example there is helpful. $\endgroup$ – user64494 Apr 5 at 15:05
  • 2
    $\begingroup$ Try to write correct syntax. It is not clear what "(e^-2x +3x)^1/x" means. Exponentiation is written by: Exp[...] . And Hopital's Rule needs 2 function. $\endgroup$ – Daniel Huber Apr 5 at 15:10
2
$\begingroup$
Clear["Global`*"]

What you wrote is

(E^-2 x + 3 x)/x // Simplify

(* 3 + 1/E^2 *)

Presumably you meant to write

expr = (E^(-2 x) + 3 x)/x;

First, check that l'Hopital's rule is applicable

Limit[#, x -> Infinity] & /@ {Numerator[expr], Denominator[expr]}

(* {∞, ∞} *)

The derivatives are

D[{Numerator[expr], Denominator[expr]}, x]

(* {3 - 2 E^(-2 x), 1} *)

The limits of the derivatives are

Limit[%, x -> Infinity]

(* {3, 1} *)

The ratio of the limits is the limit of expr

Divide @@ %

(* 3 *)

Verifying,

Limit[expr, x -> Infinity]

(* 3 *)

Clear["Global`*"]

EDIT: As bill s pointed out in a comment, I misinterpreted your expression. A slightly modified approach is needed.

expr2 = (E^(-2 x) + 3 x)^(1/x);

To use l'Hopital's rule we must work with the Log

expr3 = Log[expr2] // PowerExpand

(* Log[E^(-2 x) + 3 x]/x *)

Then following the same procedure

Limit[#, x -> Infinity] & /@ {Numerator[expr3], Denominator[expr3]}

(* {∞, ∞} *)

D[{Numerator[expr3], Denominator[expr3]}, x]

(* {(3 - 2 E^(-2 x))/(E^(-2 x) + 3 x), 1} *)

Limit[%, x -> Infinity]

(* {0, 1} *)

Divide @@ %

(* 0 *)

Since we were working with the Log, the limit of expr2 is

E^%

(* 1 *)

Verifying,

Limit[expr2, x -> Infinity]

(* 1 *)
$\endgroup$
5
  • 1
    $\begingroup$ My guess would have been: Limit[(E^(-2 x) + 3 x)^(1/x), x -> Infinity] which has a limit of 1. $\endgroup$ – bill s Apr 5 at 16:04
  • $\begingroup$ @bills - Thanks, corrected. $\endgroup$ – Bob Hanlon Apr 5 at 16:25
  • 2
    $\begingroup$ @bills Now ma.stackexchange goes to the next level---not only providing, but also guessing the questions :) $\endgroup$ – yarchik Apr 5 at 17:08
  • 3
    $\begingroup$ @yarchik Is that a surprise? I thought most of us are AI bots anyway. $\endgroup$ – Daniel Lichtblau Apr 5 at 17:24
  • $\begingroup$ Thank you for your explanation.... $\endgroup$ – osha Apr 7 at 13:17

Not the answer you're looking for? Browse other questions tagged or ask your own question.