How to refine the output of DiscretizeRegion & ImplicitRegion?

Question

This code

DiscretizeRegion[
ImplicitRegion[y/(0.2*Max[x,z]) >= Max[x,z]/Abs[x-z] && y/(0.9*Max[x,z]) <= Max[x,z]/Abs[x-z] && 
x + y + z == 1, {{x, 0, 1}, {y, 0, 1}, {z, 0, 1}}], 
 MaxCellMeasure -> {"Length" -> 0.01}, Method -> "ContourPlot3D", PlotTheme -> "DarkMesh"]

produces the graph below, whose lower tails are chopped.

Could it be refined somehow so that the full graph is shown?

Answer 1

Method-1

• To see the lower tails, we can use ContourPlot3D+RegionFunction at first.

plot = ContourPlot3D[x + y + z == 1, {x, 0, 1}, {y, 0, 1}, {z, 0, 1}, 
   RegionFunction -> 
    Function[{x, y, z}, 
     y/(0.2*Max[x, z]) >= Max[x, z]/Abs[x - z] && 
      y/(0.9*Max[x, z]) <= Max[x, z]/Abs[x - z]], PlotPoints -> 80, 
   MaxRecursion -> 4] // Quiet

• And use the default plottheme.

DiscretizeGraphics[plot, PlotTheme -> Automatic, 
 ViewPoint -> {1, 1, 1}]

Method-2

• Or Method -> "Semialgebraic".

DiscretizeRegion[
 ImplicitRegion[
  y/(0.2*Max[x, z]) >= Max[x, z]/Abs[x - z] && 
   y/(0.9*Max[x, z]) <= Max[x, z]/Abs[x - z] && 
   x + y + z == 1, {{x, 0, 1}, {y, 0, 1}, {z, 0, 1}}], 
 MaxCellMeasure -> {"Length" -> 0.01}, Method -> "Semialgebraic", 
 PlotTheme -> "DarkMesh", Boxed -> True, ViewPoint -> {2, 3, 1}]