How to ask FrontEnd to wait until an Evaluation has finished?

Question

I am writing a notebook programmatically. I would like the FrontEnd to wait until an evaluation is finished, before continuing. This is best explained with examples:

The following opens a notebook, writes a text cell, writes an input cell, evaluates it, and continues to write more text cells. Notice that the evaluation doesn't finish until the the the the FrontEnd finishes.

NotebookWrite[exampleNB, 
 Cell["example of evaluating input programmatically", 
  "Text"]]; NotebookWrite[exampleNB,
 Cell["D[Sin[ RandomReal[] x],x]" , "Input", CellTags -> 1]];
SelectionMove[exampleNB, Previous, Cell];
SelectionEvaluate[exampleNB];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]];
Pause[5];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]];

This is related to a similar post, the answer to which almost gets me to a solution. How to wait a Cell in a Notebook to be executed until another Notebook's Cell expressions executed?

That post's solution doesn't work for my case, because this will evaluate all input cells:

NotebookWrite[exampleNB, 
 Cell["example of evaluating input programattically", 
  "Text"]]; NotebookWrite[exampleNB,
 Cell["D[Sin[ RandomReal[] x],x]" , "Input", CellTags -> 1]];
SelectionMove[exampleNB, Previous, Cell];
NotebookEvaluate[exampleNB, InsertResults -> True];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]];
Pause[1];
NotebookWrite[exampleNB,
  Cell["D[Sin[ RandomReal[] x],x]" , "Input", CellTags -> 1]];
SelectionMove[exampleNB, Previous, Cell];
NotebookEvaluate[exampleNB, InsertResults -> True];
Pause[1];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]];

I've tried a solution with CellTags. This works, but there is a problem: there is no output from the evaluation.

NotebookWrite[exampleNB, 
 Cell["example of evaluating input programattically", 
  "Text"]]; NotebookWrite[exampleNB,
 Cell["D[Sin[ RandomReal[] x],x]" , "Input", CellTags -> 1]];
SelectionMove[exampleNB, Previous, Cell];
NotebookEvaluate[exampleNB, 
  EvaluationElements -> {"CellTags" -> 1}];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]];
Pause[2];
NotebookWrite[exampleNB,
  Cell["D[Sin[ RandomReal[] x],x]" , "Input", CellTags -> 2]];
SelectionMove[exampleNB, Previous, Cell];
NotebookEvaluate[exampleNB, EvaluationElements -> {"CellTags" -> 2}];
Pause[2];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]];

One might think that adding the InsertResults->True option would insert results, but it doesn't:

NotebookWrite[exampleNB, 
 Cell["example of evaluating input programattically", 
  "Text"]]; NotebookWrite[exampleNB,
 Cell["D[Sin[ RandomReal[] x],x]" , "Input", CellTags -> 1]];
SelectionMove[exampleNB, Previous, Cell];
NotebookEvaluate[exampleNB, InsertResults -> True, 
  EvaluationElements -> {"CellTags" -> 1}];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]];
Pause[2];
NotebookWrite[exampleNB,
  Cell["D[Sin[ RandomReal[] x],x]" , "Input", CellTags -> 2]];
SelectionMove[exampleNB, Previous, Cell];
NotebookEvaluate[exampleNB, InsertResults -> True, 
  EvaluationElements -> {"CellTags" -> 2}];
Pause[2];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]];

I think that this may be a buglet.

Is there a work-around? My goal here is simple. Get the input's evaluation to display before the rest of the cells are written.

It may seem like a strange thing to want to do, but if is anyone is interested a out why, I'll add this as a comment.

Answer 1

You could try the following approach, with a secondary kernel (K2) and using CellInformation to check if a cell or notebook is currently in the "Evaluating" state:

1. Get the current evaluator names:

evaluators = EvaluatorNames /. Options[$FrontEnd, EvaluatorNames];

2. Add a "K2" kernel if there isn't one:

SetOptions[$FrontEnd, Union[Join[evaluators, {"K2" -> {"AutoStartOnLaunch" -> False}}]]]

3. Function which checks if any cell in a notebook is currently evaluating:

NotebookEvaluatingQ[nb_] := Module[{},
  SelectionMove[nb, All, Notebook];
  Or @@ Map["Evaluating" /. # &, Developer`CellInformation[nb]]
  ]

4. Make a new notebook with a "K2" kernel:

nb = CreateDocument[{}, Evaluator -> "K2"]

5. Write a test input Pause[2], evaluate it and pause until it is done. Repeat for a total of three times:

SelectionMove[nb, All, Notebook];
FrontEndTokenExecute[nb, "Cut"];
Do[
 NotebookWrite[nb, 
  Cell[BoxData[MakeBoxes[Pause[2], StandardForm]], "Input"]];
 SelectionMove[nb, Previous, Cell];
 FrontEndTokenExecute[nb, "Evaluate"];
 SelectionMove[nb, Previous, Cell];
 While[NotebookEvaluatingQ[nb], Pause[.1]];
 SelectionMove[nb, After, Notebook];
 , 3]

Answer 2

An example of evaluating the expression outside the notebook and then write the result in the notebook.

exampleNB = CreateDocument[];
NotebookWrite[exampleNB, 
 Cell["example of evaluating input programmatically", 
  "Text"]]; NotebookWrite[exampleNB, 
 Cell["D[Sin[ RandomReal[] x],x]", "Input", CellTags -> 1]];
NotebookWrite[exampleNB, 
  Cell[StandardForm@ToString@D[Sin[ RandomReal[] x], x], "Output"]];
Pause[2];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]]
Pause[2];
NotebookWrite[exampleNB, Cell[RandomWord[], "Text"]]