How do I analytically-continue the dilogarithm function?

Question

Here's the dilogarithm definition:

$$\text{Li}_2(z)=\sum_{k=1}^{\infty} \frac{z^k}{k^2};\quad |z|<1$$

However, the function can be analytically-continued by several integral means for all $z$ with branch points at 0 and 1. The resulting continued function is similar to a logarithmic helix and so infinitely-valued. If I plot PolyLog[2,z], I get the principal-branch. Shown below is the imaginary surface:

p2 = ParametricPlot3D[{Re@z, Im@z, Im@PolyLog[2, z]} /. 
    z -> r Exp[I t], {r, 0, 3}, {t, 0, 2 Pi}];

The plot clearly shows the (principal) branch point and branch cut at z=1. Here is what Wikipedia says about the two branch-points of polylogarithm here: Polylogarithm

The polylogarithm has two branch points; one at z = 1 and another at z = 0. The second branch point, at z = 0, is not visible on the main sheet of the polylogarithm; it becomes visible only when the function is analytically continued to its other sheets.

I was wondering if there is an easy way to plot several other sheets in particular the sheet showing the branch point at z=0? I can, with a lot of effort, construct additional sheets by differentially-continuing the principal branch via: $$ f(z)=\text{PolyLog[2,z]} $$ then $$ \frac{df}{dt}=-1/2 \log(1-z)\frac{dz}{dt}; $$ and then meticulously constructing the sheeting by running this DE and DE for $\log(1-z)$ hundreds of times and connecting them and generating the polygon surface. The plot shows two such continuations this way as the blue and red traces. However, to generate the whole sheet would take a lot more effort to perfect for me. Is there an easier way?

Answer 1

Lewin's book gives a useful continuation formula:

$$\operatorname{Li}_n^{(k_0,\dots,k_{n-1})}(z)=\operatorname{Li}_n(z)+\frac1{(n-1)!}\sum_{m=0}^{n-1}k_m\binom{n-1}{m}(2\pi i)^{m+1}(\log z)^{n-m-1}$$

which can be used to visualize the Riemann surface of the dilogarithm:

With[{ε = 1*^-12},
     GraphicsRow[{ParametricPlot3D[Flatten[Table[{r Cos[φ], r Sin[φ], 
                                                  Re[PolyLog[2, r Exp[I φ]] + 
                                                     2 I π (Log[r] + I φ) j - 4 π^2 k]},
                                                 {j, -2, 2}, {k, -2, 2}], 1],
                                   {r, 0, 7}, {φ, ε, 2 π - ε},
                                   BoxRatios -> {1, 1, 4}, Mesh -> None,
                                   PlotRange -> {{-7, 7}, {-7, 7}, {-21, 21}}, 
                                   PlotStyle -> Directive[Hue[0.56], Opacity[0.6]]], 
                  ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], 
                                          Im[PolyLog[2, r Exp[I φ]] + 
                                             2 I π (Log[r] + I φ) j]}, {j, -2, 2}],
                                   {r, 0, 7}, {φ, ε, 2 π - ε}, 
                                   BoxRatios -> {1, 1, 4}, Mesh -> None, 
                                   PlotRange -> {{-7, 7}, {-7, 7}, {-21, 21}}, 
                                   PlotStyle -> Directive[Hue[0.56], Opacity[0.6]]]}]]

Answer 2

I'd like to refer to the Maple documentation on this topic. I think so does Mathematica. Also consider the Riemann surface for PolyLog[2, z].