0
$\begingroup$

I am trying to solve these three coupled linear equations but this gives me zero value. I don't know why it is happening. If anyone can resolve this is most welcome.

p11 = 1;
omega = .2;
C11 = 2.030;
beta = 1;
C55 = 0.600;
alpa = 1;
C13 = 0.750;
e31 = 0.200;
e15 = 3.700;
C33 = 2.450;
e33 = 1.300;
ep11 = 38.90;
ep33 = 25.70;
NSolve[{(p11*omega^2 - C11*beta^2 - C55*alpa^2)*A1 - (C13 + C55)*alpa*
     beta*B1 - (e31 + e15)*alpa*beta*C1 == 
   0, (p11*omega^2 - C55*beta^2 - C33*alpa^2)*B1 - (C13 + C55)*alpa*
     beta*A1 - (e15*beta^2 + e33*alpa^2)*C1 == 
   0, (ep11*beta^2 + ep33*alpa^2)*C1 - (e15*beta^2 + e33*alpa^2)*
     B1 - (e15 + e31)*alpa*beta*A1 == 0}, {A1, B1, C1}]
$\endgroup$
1
  • $\begingroup$ I’m voting to close this question because the issued raised is not really a problem; it arises from the OP not understanding of the result returned by Mathematica. $\endgroup$ – m_goldberg Feb 24 at 2:33
4
$\begingroup$

{0, 0, 0} is the solution

Clear["Global`*"]

p11 = 1;
omega = .2;
C11 = 2.030;
beta = 1;
C55 = 0.600;
alpa = 1;
C13 = 0.750;
e31 = 0.200;
e15 = 3.700;
C33 = 2.450;
e33 = 1.300;
ep11 = 38.90;
ep33 = 25.70;

eqns = {(p11*omega^2 - C11*beta^2 - C55*alpa^2)*A1 - (C13 + C55)*alpa*beta*
      B1 - (e31 + e15)*alpa*beta*C1 == 
    0, (p11*omega^2 - C55*beta^2 - C33*alpa^2)*B1 - (C13 + C55)*alpa*beta*
      A1 - (e15*beta^2 + e33*alpa^2)*C1 == 
    0, (ep11*beta^2 + ep33*alpa^2)*C1 - (e15*beta^2 + e33*alpa^2)*
      B1 - (e15 + e31)*alpa*beta*A1 == 0};

Solve[Rationalize@eqns, {A1, B1, C1}]

(* {{A1 -> 0, B1 -> 0, C1 -> 0}} *)

Graphically,

ContourPlot3D[Evaluate@eqns, {A1, -1, 1}, {B1, -1, 1}, {C1, -1, 1}]

enter image description here

$\endgroup$
1
$\begingroup$

Your equations can be written in terms of the matrix $M$:

M = {{-beta^2 C11 - alpa^2 C55 + omega^2 p11, -alpa beta (C13 + C55), -alpa beta (e15 + e31)},
     {-alpa beta (C13 + C55), -alpa^2 C33 - beta^2 C55 + omega^2 p11, -beta^2 e15 - alpa^2 e33},
     {-alpa beta (e15 + e31), -beta^2 e15 - alpa^2 e33, beta^2 ep11 + alpa^2 ep33}};

Thread[M . {A1, B1, C1} == 0]
(*    your equations    *)

In general, this matrix $M$ has three nonzero eigenvalues and therefore $\{0,0,0\}$ is the only solution of these equations:

Eigenvalues[M] /. {p11 -> 1, omega -> .2, C11 -> 2.030, 
                   beta -> 1, C55 -> 0.600, alpa -> 1,
                   C13 -> 0.750, e31 -> 0.200, e15 -> 3.700,
                   C33 -> 2.450, e33 -> 1.300, ep11 -> 38.90,
                   ep33 -> 25.70}
(*    {-4.74509, -1.43481, 65.1799}    *)

You could now ask: under what conditions does this matrix $M$ have a zero eigenvalue, and therefore a nontrivial solution space (nullspace)?

$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.