So I am trying to use DSolve to solve the following system of equations:

eqns = {c1'[
 t] == -I/
  h (H12 c2[t] E^(-I W12 t ) + 
   H13 c3[t] E^(-I W13 t ) + 
   H14 c4[t] E^(-I W14 t )), c2'[t] == -I/
  h (H12 c1[t] E^(I W12 t ) + 
   H23 c3[t] E^(-I W23 t ) + 
   H24 c4[t] E^(-I W24 t )), c3'[t] == -I/
  h (H23 c2[t] E^(I W23 t ) + 
   H13 c1[t] E^(I W13 t ) + 
   H34 c4[t] E^(-I W34 t )), c4'[t] == -I/
  h (H24 c2[t] E^(I W24 t ) + 
   H34 c3[t] E^(I W34 t ) + 
   H14 c1[t] E^(I W14 t )), c1[0] == a,  c2[0] == b, c3[0] == c, c4[0] == d}; DSolve[eqns, {c1, c2, c3, c4}, t]

But Mathematica returns the input and doesn't do anything. Can someone help me out? Thanks! (Sorry for the bad layout, I don't know how to seperate the equations here without getting them out of the code section)

  • 1
    $\begingroup$ It usually means that it can't find a solution. Do you know if a symbolic solution is known? $\endgroup$
    – Michael E2
    Feb 4 at 19:37
  • $\begingroup$ @MichaelE2 no, unfortunately I have no idea what's the solution or even if there exists one. That's what I was hoping to find out... :) $\endgroup$ Feb 4 at 20:01
  • 2
    $\begingroup$ Well, it solves the system given some numeric values for the parameters, but not this one: Block[{H12, H13, H14, H23, H24, H34, h, W12, W13, W14, W23, W24, W34}, {H12, H13, H14, H23, H24, H34, h, W12, W13, W14, W23, W24, W34} = {1, 1, 1, 1, 1, 1, 1(*h*), 2, 0, 0, 0, 0, 0}; DSolve[eqns, {c1, c2, c3, c4}, t] ] -- one's hopes are diminished. Sorry. $\endgroup$
    – Michael E2
    Feb 4 at 20:45

It looks like you are trying to propagate the time-dependent Schrödinger equation in the interaction picture. If this is indeed the case, could it be that your W parameters can be written as $W_{ij}=w_i-w_j$? If yes, then the solution consists of going back to the Schrödinger picture, where the Hamiltonian becomes time-independent:

W12 = w1 - w2;
W13 = w1 - w3;
W14 = w1 - w4;
W23 = w2 - w3;
W24 = w2 - w4;
W34 = w3 - w4;
c1[t_] = a1[t] E^(-I w1 t);
c2[t_] = a2[t] E^(-I w2 t);
c3[t_] = a3[t] E^(-I w3 t);
c4[t_] = a4[t] E^(-I w4 t);

Your equations can now be written as a time-dependent Schrödinger equation with a time-independent Hamiltonian $H$ for the $a_i(t)$,

y[t_] = {a1[t], a2[t], a3[t], a4[t]};
H = {{-h w1, H12,   H13,   H14  },
     {H12,   -h w2, H23,   H24  },
     {H13,   H23,   -h w3, H34  },
     {H14,   H24,   H34,   -h w4}};
y'[t] == -(I/h) H . y[t] // Thread
(*    four differential equations equivalent to yours    *)

The solution is now found by matrix exponentiation,

Y[t_] = MatrixExp[-(I/h) H t, {a, b, c, d}]

which contains RootSum terms that you can convert to radicals with ToRadicals:

Y[t] // ToRadicals
(*    huge result    *)

From this solution for the $a_i(t)$ you can compute the $c_i(t)$ with the aforementioned formulas.

Alternatively, with the time-independent Hamiltonian $H$ you can go the more traditional route of using the time-independent Schrödinger equation and simply look for the (energy) eigenvalues of $H$,



Eigenvalues[H, Quartics -> True]

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.