Mathematica Stack Exchange is a question and answer site for users of Wolfram Mathematica. It only takes a minute to sign up.
Sign up to join this community
Is there a pattern that can match repeated elements that appear more than twice in a row?
For the sake of example let's say I want to use pattern matching to delete subsequent duplicate:
l = {1,2,2,3,4};
l/.{b___,x_,x_,r___}->{b,r}
(*{1,3,4}*)
But
l = {1,2,2,2,3,4};
l/.{b___,x_,x_,r___}->{b,r}
(*{1,2,3,4}*)
I can try to use Repeated, but it doesn't seem to work:
l = {1, 2, 2, 2, 3, 4};
l /. {b___, x_, (x_) .., r___} -> {b, r}
(*{1,2,3,4}*)
Am I using it wrong?
Use the Longest pattern command to find the longest repeated sequence that matches the pattern.
l = {1, 2, 2, 2, 3, 4};
l /. {b___, x_, Longest[(x_) ..], r___} :> {b, r}
(*{1, 3, 4}*)
l={1,1,1,2} returns {2} when I test it. Are you sure that both the b and r have three blanks?
$\endgroup$
Another possibility is to use SequenceReplace:
SequenceReplace[{1, 2, 2, 2, 3, 4}, {x_, x_ ..} -> Sequence[]]
{1, 3, 4}
Try the following:
l = {1, 2, 2, 2, 3, 4};
l /. {b___, x_, (x_) .., r___} -> {{b}, {r}}
(* {{1}, {2, 3, 4}} *)
and you see that that r is ill-defined. Therefore we must restrict r:
l //. {b___, Repeated[x_, {2, 10}], Shortest@r___} :> {b, r}
(*{1, 3, 4}*)
You might also consider using the two-argument form of Repeated for finer control:
{1, 2, 2, 3, 4} /. {a___, Repeated[x_, {2, ∞}], b___} :> {a, b}
{1, 3, 4}
SequenceReplace[{1, 2, 2, 2, 3, 4}, {Repeated[x_, {2, ∞}]} -> Sequence[]]
{1, 3, 4}
Not pattern matching, but one other way:
Cases[Split@l2, {x_}:>x]
{1, 3, 4}
Cases[{a_, 1} :> a] @ Tally @ list
{1, 3, 4}
