Get Coordinates in Image Processing

Question

I'm new to Mathematica. I'm very impressed about it's abilities. It's very easy to achieve complex tasks. But I fail the simple ones.

How can I get coordinates in image processing?

I'd like to detect one of the following things

• absolute vertical center of the rectangle surrounding all white parts
• gravity center of all white parts

e.g.: for this picture

I want to find the green point (center of outbound box).

Answer 1

ImageValuePositions, new in 9, can return a list of white pixel positions.

i = Import@"https://i.stack.imgur.com/opzqB.png";
p = ImageValuePositions[i, White] // Mean
(* {298.896, 21.3231} *)

HighlightImage[i, {p},
 Method -> {"CrossMarkers", 5}]

Update: Surrounding rectangle

Get the min/max of white pixel coordinates.

whites = ImageValuePositions[i, White];
corners = Transpose[{
   Through[{Min, Max}[First /@ whites]],
   Through[{Min, Max}[Last /@ whites]]}]
(* {{218.5, 0.5}, {373.5, 50.5}} *)

Make a rectangle boundary and highlight that region on the image.

rect = corners /. {{x1_, y1_}, {x2_, y2_}} :>
    With[{dx = 2}, Join[
      Table[{x1, y1} + {0, y}, {y, 0, y2 - y1, dx}],
      Table[{x1, y2} + {x, 0}, {x, 0, x2 - x1, dx}],
      Table[{x2, y2} - {0, y}, {y, 0, y2 - y1, dx}],
      Table[{x2, y1} - {x, 0}, {x, 0, x2 - x1, dx}]]];

HighlightImage[i, rect,
 Method -> {"DiskMarkers", 1}]

Answer 2

For another approach, there's always the ComponentMeasurements way:

cm = ComponentMeasurements[Dilation[i, BoxMatrix[5]] , "Centroid"]

{1 -> {297.633, 23.7345}}

mean = Mean@cm[[All, 2]] (* not needed if only one component found*)

HighlightImage[i, 
 List@mean, 
 Method -> {"DiskMarkers", 3}, 
 HighlightColor -> Green]

I'm not happy with the Dilation approach, though, which is a bit sloppy.

Answer 3

Suppose your original image is img.

First we Binarize it:

imgBinarized = img // Binarize;

Then crop all the black boarders:

imgConcerned = ImageCrop[imgBinarized]

So now, using the HitMissTransform (also wiki page), we can easily get its center position:

centerPos = HitMissTransform[imgBinarized, ImageData[imgConcerned]]

To achieve the appearance of your last picture, we construct a diamond marker first:

markerMatrix = Graphics[{EdgeForm[{White, Thick}], FaceForm[],
       Rotate[Rectangle[], π/4]},
      Background -> Black,
      ImageSize -> {15, 15}] // Rasterize //
    ColorConvert[#, "Grayscale"] & // ImageData;

Then convolve it with the centerPos image:

imgCenter = ImageConvolve[centerPos, markerMatrix];

Colorize it:

imgCenterColored = Image[
  # ImageData[imgCenter] & /@ {0, 3/4, 0, 1},
  "Real", ColorSpace -> "RGB", Interleaving -> False];

Compose it with the original image img:

ImageCompose[img, imgCenterColored]

You can explore the image processing functions in Mathematica and find yourself how to add the red boundary box.

Edit

As cormullion suggested, in case you want the coordinate of the center point, you can extract it from the mask image centerPos straightway:

Position[Transpose[ImageData[centerPos, DataReversed -> True]], 1]

{{297, 26}}

Answer 4

A variation of BoLe's center-of-gravity method for version 7:

img = Import["https://i.stack.imgur.com/opzqB.png"]

SparseArray[ImageData@Binarize@img]["NonzeroPositions"] // Mean // N

{30.1769, 299.396}

Output in (y,x) order.

SparseArray is much faster than Position:

dat = ImageData@Binarize@img;

Do[SparseArray[dat]["NonzeroPositions"], {1500}] // Timing // First

Do[Position[dat, 1], {1500}] // Timing // First

0.14

2.465

Links to other uses of SparseArray Properties here.

Answer 5

Here's one way that exploits the fact that you have a constant black background. If your image is called img, then

small = ImageCrop[img]

crops it and leaves just the central rectangle.

Now you want the center of the cropped image, which can be found

cen = ImageDimensions[ImageCrop[img]]/2

To display the small image and the centerpoint:

Show[small, Graphics[{Thick, Orange, Point[{{cen, cen}}]}]]

This gives you a little orange dot at the center.

You can of course, change the orange dot to whatever you like.