0
$\begingroup$

I want to solve this transcendental equation, but I don't know the step by step to get F in form equation and value of F

f[F] = [exp^(I*p*b)/(16*A^2*B*H) {((A + H)^2)[(A + B)^2*exp^(2*I (k (a - b) - q*a)) - (A - B)^2*exp^(-2*I (k (a - b) - q*a))] + ((A - H)^2)[(A - B)^2*exp^(-2*I (k (a - b) + q*a)) - (A + B)^2*exp^(2*I (k (a - b) + q*a))] + 2 (A^2 - B^2) (A^2 - H^2)[exp^(2*I*q*a) - exp^(-2*I*q*a)]}] = 0

I need solution F in form equation (F=...) and, where

n = 2;
h = 1;
a = 0.01;
b = 0.02;
m = 1;
h = 1;
c = 137.036;
S1 = 0;
S2 = 0;
V1 = 0;
V2 = 50.000;
k = Sqrt[F^2 - m^2*c^4]/(h*c);
p = Sqrt[(F + m*c^2 - V2 + S2) (F - m*c^2 - V2 - S2)]/(h*c);
q = Sqrt[(F + m*c^2 - V1 + S1) (F - m*c^2 - V1 - S1)]/(h*c);
A = Sqrt[(F - m*c^2)/(F + m*c^2)];
B = Sqrt[(F - m*c^2 - V2 - S2)/(F + m*c^2 - V2 + S2)];
H = Sqrt[(F - m*c^2 - V1 - S1)/(F + m*c^2 - V1 + S1)];

I want to get value of F by using the variables that have been known above

Help me to get F function and value of F, please. Thank you very much.

$\endgroup$

2 Answers 2

2
$\begingroup$

Put this into Mathematica and evaluate it and look at the resulting graph

n = 2; h = 1; a = 1/100; b = 2/100; m = 1; h = 1;
c = 137036/1000; S1 = 0; S2 = 0; V1 = 0; V2 = 50;
k = Sqrt[F^2 - m^2*c^4]/(h*c);
p = Sqrt[(F + m*c^2 - V2 + S2) (F - m*c^2 - V2 - S2)]/(h*c);
q = Sqrt[(F + m*c^2 - V1 + S1) (F - m*c^2 - V1 - S1)]/(h*c);
A = Sqrt[(F - m*c^2)/(F + m*c^2)];
B = Sqrt[(F - m*c^2 - V2 - S2)/(F + m*c^2 - V2 + S2)];
H = Sqrt[(F - m*c^2 - V1 - S1)/(F + m*c^2 - V1 + S1)];
f[F_]:=(E^(I*p*b)/(16*A^2*B*H)(((A+H)^2)((A+B)^2*E^(2*I(k(a-b)-q*a))-
  (A-B)^2*E^(-2*I(k(a-b)-q*a)))+((A-H)^2)((A-B)^2*E^(-2*I(k(a-b)+q*a))-
  (A+B)^2*E^(2*I(k(a-b)+q*a)))+2(A^2-B^2)(A^2-H^2)(E^(2*I*q*a)-E^(-2*I*q*a))));
Plot[{Re[f[F]],Im[f[F]]},{F,-100000,100000},AxesOrigin->{0,0},PlotPoints->1000,PlotRange->All]

That will plot the real part and the imaginary part of your expression. It does not appear that there is an F such that your function clearly equals zero.

Does this make your problem clear?

$\endgroup$
5
  • 1
    $\begingroup$ On a different scale the plot shows a root in the vicinity of F = 18827, or have I missed something. $\endgroup$
    – LouisB
    Jan 2, 2021 at 10:36
  • $\begingroup$ I have put it into Mathematica, but it does not shown any plot after I run it. What should I do? @Bill $\endgroup$
    – Aff_
    Jan 4, 2021 at 3:40
  • $\begingroup$ How can you (@LouisB) get F=18827 ? Do you immediately copy and paste the answer shown by Bill on your Mathematica or add something before running the formula ? $\endgroup$
    – Aff_
    Jan 4, 2021 at 3:49
  • $\begingroup$ I restart Mathematica so it forgets any previous assignments and cached values, scrape my code above off the screen, paste it into the Mathematica notebook, tap <shift><enter> and a couple of seconds later I see the plot. Then I change the plot to be Plot[{Re[f[F]],Im[f[F]]},{F,18826,18828}] and see another plot. $\endgroup$
    – Bill
    Jan 4, 2021 at 4:08
  • $\begingroup$ Okay. Thank you very much @Bill $\endgroup$
    – Aff_
    Jan 5, 2021 at 2:08
1
$\begingroup$

Here is one method that works fairly well. First, define the parameters with lots of precision, say 100 decimal places here

{h = 1, a = 0.01`100, b = 0.02`100, m = 1, c = 137.036`100,
  S1 = 0, S2 = 0, V1 = 0, V2 = 50};

Now define the functions of variable $F$ and the overall function, $f$, whose root(s) we want to find.

k = Sqrt[F^2 - m^2*c^4]/(h*c);
p = Sqrt[(F + m*c^2 - V2 + S2) (F - m*c^2 - V2 - S2)]/(h*c);
q = Sqrt[(F + m*c^2 - V1 + S1) (F - m*c^2 - V1 - S1)]/(h*c);
A = Sqrt[(F - m*c^2)/(F + m*c^2)];
B = Sqrt[(F - m*c^2 - V2 - S2)/(F + m*c^2 - V2 + S2)];
H = Sqrt[(F - m*c^2 - V1 - S1)/(F + m*c^2 - V1 + S1)];

f = (E^(I*p*b)/(16*A^2*B*H) (((A + H)^2) ((A + B)^2*
          E^(2*I (k (a - b) - q*a)) - (A - B)^2*
          E^(-2*I (k (a - b) - q*a))) + ((A - H)^2) ((A - B)^2*
          E^(-2*I (k (a - b) + q*a)) - (A + B)^2*
          E^(2*I (k (a - b) + q*a))) + 
      2 (A^2 - B^2) (A^2 - H^2) (E^(2*I*q*a) - E^(-2*I*q*a))));

Now make a plot and look for a root. Since there are complex numbers in the formula, use ReImPlot.

ReImPlot[f, {F, 18000, 20000}]

enter image description here

The plot shows what may be root around F=18800. In this case FindInstance is able to locate the root.

soln = FindInstance[{f == 0, 18700 < F < 18900}, F] //
       Flatten // First;
N[{F, f} /. soln, 10]

(*  {18826.96586, 0.*10^-96 + 0.*10^-96 I}  *)

It doesn't hurt to zoom in on the root,

ReImPlot[f, {F, 18825, 18830}]

enter image description here

Note that this root is not a root of the trig form ($\tan(qa) = ... $) shown in the OP. It may be interesting to see what happens without the 100 decimal places of precision. It may also be interesting to try to get root using Solve or NSolve or FindRoot or by minimizing Abs[f] or f*Conjugate[f]. It may be interesting to use FunctionDomain on the {p, k, q, A, B, H} and f functions.

$\endgroup$
3
  • $\begingroup$ Thankyou very much @LouisB. By the way, if the value of the variables n, h, b, m, c, S1, S2, V1, and V2 are not known, can the equation F be determined? $\endgroup$
    – Aff_
    Jan 4, 2021 at 7:16
  • $\begingroup$ @Afaf_H If such solutions do exist the key to finding them probably lies in the expressions (boundary conditions?) and the model that led to your expressions for $f, k, p, q,$ etc. If I come up with anything, I'll post a new answer to this question. Also, you may want to use Manipulate to study how the various parameters affect the root(s). Plotting the $k, p, q, A, B, H$ functions may also provide insight into where to look for roots. $\endgroup$
    – LouisB
    Jan 4, 2021 at 9:24
  • $\begingroup$ Okay, thank you very much @LouisB. Oh yeah, sorry in advance, would you please if I asked you more about this discussion via email for example or other social media, not in a public forum? $\endgroup$
    – Aff_
    Jan 5, 2021 at 3:26

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.