Find all instances of a function with a given head and replace their arguments

Question

I'm trying to pattern-match all the functions with head Sin in list and replace their single input with a value.

Clear[a,x,y,z]
testList = {x, Sin[x], Sin[y],x^2*y, g[y,x], h[x,y,z], Cos[Tan[x]]}
testList /. f_Sin[a_] :> (f[a] /. a->10)

However, this is giving me

{x, Sin[x], Sin[y], x^2*y, g[y, x], h[x, y, z], Cos[Tan[x]]}

Why? What am I doing wrong?

consider testList2 = {x, Sin[x], Sin[y][t], x^2*y, g[y, x], h[x, y, z], Cos[Tan[x]]}; testList2 /. f_Sin[a_] :> (f[a] /. a -> 10) — kglr, Dec 22, 2020 at 10:46
the pattern _Sin (and the pattern f_Sin) matches any expression with Head Sin, that is, expressions Sin[x] and Sin[y] in your testList. But the pattern _Sin[a_] is any expression with Head Sin evaluated at a single argument and there are no such expressions in your testList. — kglr, Dec 22, 2020 at 10:58
Btw, you can do testList /. (f : Sin)[a_] :> (f[a] /. a -> 10) to get the desired result. — kglr, Dec 22, 2020 at 11:07

m_goldberg · Accepted Answer · 2020-12-22 11:11:23Z

What kglr recommends is the best practice for what you want to do, but here is pattern that does it your way.

testList = {x, Sin[x], Sin[y], x^2*y, g[y, x], h[x, y, z], Cos[Tan[x]]};
testList /. f : Sin[a_] :> (f /. a -> 10)

{x, Sin[10], Sin[10], x^2 y, g[y, x], h[x, y, z], Cos[Tan[x]]}

This works because it recognizes that f matches the whole expression Sin[...], so that writing f[a] in (f[a] /. a -> 10) is wrong.

This approach is not without it uses. Say you wanted pick out the expressions with the heads Sin and Cos. Then

testList /. f : (Sin | Cos)[a_] :> (f /. a -> 10)

{x, Sin[10], Sin[10], x^2 y, g[y, x], h[x, y, z], Cos[10]}

is a reasonable solution.

Wolfgang123 · Accepted Answer · 2020-12-22 10:17:45Z

0

Is this what you want?

testList /. Sin[a_] -> (f[a] /. a -> 10)

Hope this helps

answered Dec 22, 2020 at 10:17

Wolfgang123

3661 gold badge2 silver badges9 bronze badges

$\begingroup$ You have no reference to f before ->. Why should it work? $\endgroup$
– Our
Dec 22, 2020 at 10:19
$\begingroup$ And why mine doesn't work? $\endgroup$
– Our
Dec 22, 2020 at 10:20
$\begingroup$ and note that, this "answer" doesn't work $\endgroup$
– Our
Dec 22, 2020 at 10:26
$\begingroup$ May be I have misundestood how the final output should look like? Can you post the list how it should finally look like, please? $\endgroup$
– Wolfgang123
Dec 22, 2020 at 10:33
$\begingroup$ {{x, Sin[10], Sin[10], x^2*y, g[y, x], h[x, y, z], Cos[Tan[x]]}} $\endgroup$
– Our
Dec 22, 2020 at 10:46

Add a comment |

AsukaMinato · Accepted Answer · 2020-12-22 10:57:26Z

You want to choose all items with Sin head. And replace them with Sin[10]

So you can try

{x, Sin[x], Sin[y], x^2*y, g[y, x], h[x, y, z], Cos[Tan[x]]} /. x_Sin :> Sin[10]

notice x_Sin , x is useless, so we can delete it

{x, Sin[x], Sin[y], x^2*y, g[y, x], h[x, y, z], Cos[Tan[x]]} /. _Sin :> Sin[10]

Another angle:

Choose all the items look like Sin[_] , replace _ with 10

{x, Sin[x], Sin[y], x^2*y, g[y, x], h[x, y, z], Cos[Tan[x]]} /. Sin[x_] :> Sin[10]

the x in the Sin[x_] can be deleted.

3 Answers 3