# Oak Island, extending the "Alignment", possible Great Circle?

During these days of COVID, I indulged in the guilty pleasure of watching The Curse of Oak Island - Season 8, Episode 4 Alignment, which viewed last night (1 Dec 2020).

During the episode, some "historians" advising the treasure hunters tell the team that they have identified a line starting from, the Dome of the Rock Mosque on Temple Mount, Jerusalem that runs directly along the long axis of the cross in the Jardins du Château de Versailles (France) and then along the precise trajectory to Oak Island, Nova Scotia the presumed location of buried Knights Templar treasure including the Arc of the Covenant.

Let me state again, I view this as a great fantastic guilty pleasure - real Indiana Jones stuff.

Avoiding my actual real work, I start playing around with Google and Mathematica.

I find the geo coordinates (longitude & latitude) for the 3 locations:

versaillesCross = GeoPosition[{48.81008221499617, 2.100137383293789}];
oakIsland = GeoPosition[{44.5167, -64.2992}];
domeOfTheRock = GeoPosition[{31.778063322333196, 35.23541700515525}];


Let's find this trajectory:

GeoGraphics[{Red,
GeoPath[
{domeOfTheRock, versaillesCross, oakIsland},
"Geodesic"]},
GeoRange -> "World",
GeoProjection -> "Robinson"]


Alternatively:

GeoGraphics[{Red,
GeoPath[
{domeOfTheRock, versaillesCross, oakIsland},
"Geodesic"]},
Frame -> True]


• At first glance the 3 locations look aligned, but do they truly align?
• Do they align on a geodesic?
• If so, how do I determine if the geodesic traces the arc of a Great Circle?
• What else would an extension of such a geodesic align with around the globe (other treasure sites)?

Seems like the way to explore this starts with mapping the GeoPath on a globe.

@whuber's answer in How to draw a great circle on a sphere? gives a start:

im = Import["http://www.ngdc.noaa.gov/mgg/topo/pictures/GLOBALeb6colshadesmall.jpg"];

globe = ParametricPlot3D[
0.99 {Cos[u] Sin[v], Sin[u] Sin[v], Cos[v]}, {u, 0, 2 \[Pi]}, {v,
0, \[Pi]}, Mesh -> None,
TextureCoordinateFunction -> ({#4, 1 - #5} &),
PlotStyle -> Directive[Specularity[White, 20], Texture[im]],
Lighting -> "Neutral", Axes -> False, RotationAction -> "Clip"];
Manipulate[
Block[
{normal =
Cross[{Cos[\[Theta]], Sin[\[Theta]],
0}, {Cos[\[Alpha]] (-Sin[\[Theta]]),
Cos[\[Alpha]] Cos[\[Theta]], Sin[\[Alpha]]}]},
Show[
globe,
ContourPlot3D[x^2 + y^2 + z^2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1},
Contours -> {1},
ContourStyle -> Opacity[0.5],
Mesh -> None,
RegionFunction -> Function[{x, y, z}, normal.{x, y, z} >= 0]],
Boxed -> False]],
{{\[Alpha], 0, "Elevation"}, -\[Pi]/2, \[Pi]/2},
{{\[Theta], 0, "Azimuth"}, -\[Pi], \[Pi]}]


But now I need to figure a way to apply the Oak Island GeoPath to it and do a comparison to see if it does yield a Great Arc and in any case where an extension of the GeoPath around the world goes.

I'll keep nudging this exploration along myself, but will much appreciate any guidance, suggestions, solutions, or alternatives.

Maybe we can get a cameo for Mathematica on The Curse of Oak Island!

• You could use DynamicGeoGraphics to see for yourself if the line is perfectly in line... I look forward to giving this a bit of messing around on the weekend! Dec 3, 2020 at 13:46
• (Having used DynamicGeoGraphics with GeoBackground->"Satellite", I can tell you that the line definitely does directly through the gardens in Versailles, right along the axis...) Dec 3, 2020 at 14:20
• I thought this would give us a bit of fund ;-) Dec 3, 2020 at 14:48
• @CarlLange - I meant "fun". Dec 3, 2020 at 15:27
• @Jagra Maybe funds too if you go dig up the treasure! Dec 3, 2020 at 19:56

Well, this was a healthy waste of my time! Sometimes, Mathematica lets you play at being in National Treasure.

So, let's start out with seeing if the path really goes through the gardens so nicely.

versaillesCross =
GeoPosition[{48.81008221499617, 2.100137383293789}];
oakIsland = GeoPosition[{44.5167, -64.2992}];
domeOfTheRock = GeoPosition[{31.778063322333196, 35.23541700515525}];

Table[GeoGraphics[{Red,
GeoPath[{domeOfTheRock, versaillesCross, oakIsland}, "Geodesic"],
Blue, Point /@ {versaillesCross, oakIsland, domeOfTheRock}},
GeoRange -> p,
Quantity[0.01, "AngularDegrees"]], {p, {oakIsland, versaillesCross,
domeOfTheRock}}]


This appears a conclusive yes:

Now, let's look at the various options for lines that we have. We want to see how to extend the line to view other locations along the same path.

GeoGraphics[
{Red, GeoPath[{oakIsland, domeOfTheRock}, "Geodesic"],
Blue, GeoPath[{oakIsland, versaillesCross, domeOfTheRock},
"Geodesic"],
Purple, GeoPath[{oakIsland, domeOfTheRock}, "GreatCircle"],
Green, GeoPath[{oakIsland, versaillesCross, domeOfTheRock},
"GreatCircle"]}, GeoBackground -> None, GeoRangePadding -> None
]


It's only been 30 minutes but I've forgotten what I was trying to do there... Oh well.

Now let's use GeoHemisphereBoundary to extend that line. By default it's centred on {0, 0}, so let's use a Manipulate to find the centre for our line.

Manipulate[GeoGraphics[{
GeoHemisphereBoundary[GeoPosition[{lat, lon}]], Red,
GeoPath[{oakIsland, domeOfTheRock}, "GreatCircle"]},
GeoRange -> GeoPath[{oakIsland, domeOfTheRock}, "GreatCircle"]
], {lat, -90, 90}, {lon, -180, 180}]


A bit of messing around later, we have a line that looks really close to our original line. I am supposed to be working, so I only went by eye - there is definitely a way to calculate this properly.

Now let's get points along the boundary and see what's Nearest to them. But first, what's nearest the centre of the hemisphere boundary that describes our line?

GeoListPlot[{GeoPosition[{-38.4, -25.4}]}, GeoRange -> "World"]


I suppose there might be some sort of secret island there, kept off the maps for all time by the templars...

GeoImage[GeoPosition[{-38.4, -25.4}],


Or perhaps Atlantis?? It's more than possible that the hemisphere boundary is actually centred directly on one of those protusions, I only went to one decimal place...

Anyway, points along the line. Let's see what else is on this line if you extended it. We'll use GeoEvaluate to break the hemisphere boundary down into basic parts.

pts = GeoGraphicsGeoEvaluate[
GeoHemisphereBoundary[GeoPosition[{-38.4, -25.4}]]] /.
Line[pts_] -> pts // Map@Reverse // Map@GeoPosition;


Let's filter out the oceanic points, since we've already established the location of Atlantis.

Now we can get the closest cities to the line, give or take.

nearestCities = DeleteDuplicates@Flatten[{
GeoNearest["City", pts[[170 ;; 260]]],
GeoNearest["City", pts[[300 ;; 410]]]
}]


And now let's filter those back down to ones that are actually close to our line. First we'll use Nearest to get the distances, and then get the 20 closest by sorting the flattened result from Nearest.

n = Nearest[nearestCities -> {"Element", "Distance"}, pts,
DistanceFunction -> (GeoDistance[EntityValue[#2, "Position"], #1] &)]


reallyNearest = SortBy[Flatten[n, 1], Last][[;; 20]]


Now let's zoom in on each of these closest cities!

Based on this, I can conclusively determine that the real Declaration of Independence is hidden somewhere in Verona.

(I note now that my hemisphere boundary was accidentally based on a line that doesn't include the point in Versailles. Or perhaps I left inaccuracies so that I can make it to the treasure first...)

• I just finished packing my knapsack and got a shovel out of the storage room. Got to find my whip and revolver. Where did I leave them? Also, keep in mind the original Shakespeare manuscripts packed in mercury by Francis Bacon to preserve the parchment. Dec 3, 2020 at 16:11
• This is exactly the kind of thing that makes me enjoy Mathematica. You can just sit down and toy around with things and like an hour later you know exactly where to dig to strike it rich in the antiquities market. Dec 3, 2020 at 21:42
• Yeah, I completely agree, it really is where it shines. If we can have a "mystery" tag on the SE I'd have a gold badge straight away. Dec 3, 2020 at 22:26
• "Tough Soles" -- great blog! No wonder I piqued your curiosity. Dec 4, 2020 at 2:05
• +1 for actually establishing the location of Atlantis Dec 4, 2020 at 12:36

There's a problem with using GeoPath[{domeOfTheRock, versaillesCross, oakIsland},"Geodesic"]} to verify if a path from the Dome of the Rock to the Versailles Cross is connected to Oak Island. The path created by GeoPath represents a path formed by joining paths between consecutive locations, so that each segment connects consecutive locations with a geodesic path. This means we have a path connecting the Dome to Versailles, and a second path connecting Versailles to Oak Island, so the Versailles to Oak Island segment will always connect to the island!

Update:

One way to illustrate if the path from the Dome to Versailles connects to the island is to extend the path to the island. Jagar’s comment suggests a second method using a plane through the Dome and Versailles.

Here’s my original method using the true shape of the Earth, and extending the path. I’ve added a demonstration using a plane that assumes the Earth is a perfect sphere. This plane-and-sphere method shows a solution without correcting for the Earth’s true shape.

Extend path using geographic coordinates

To check if a path from the Dome to Versailles really does connect to Oak Island, find the direction from the Dome to Versailles, and then follow the path past Versailles to see if the path connects to the island.

We need the direction from the Dome to Versailles and a rough estimate of the distance from the Dome to the island. The direction is -45.9623°, and the distance is about 5,200 miles, which we get from GeoDistance[domeOfTheRock, oakIsland].

If we compare the direction from the Dome to Versailles (-45.9623°) to the direction from the Dome to the island (-46.9061°), which we get from GeoDirection[domeOfTheRock,oakIsland], we see that the path may overshoot the island.

Let’s check the path from the Dome for 6,000 miles starting with direction a... thanks to Carl’s test.

versaillesCross = GeoPosition[{48.81008221499617, 2.100137383293789}];
oakIsland = GeoPosition[{44.5167, -64.2992}];
domeOfTheRock = GeoPosition[{31.778063322333196, 35.23541700515525}];
a = GeoDirection[domeOfTheRock, versaillesCross];
Table[GeoGraphics[{Red,
GeoPath[{domeOfTheRock, Quantity[6000,"Miles"], a},"Geodesic"],
Blue, PointSize[Large],
Point /@ {versaillesCross, oakIsland, domeOfTheRock}},
GeoRange -> p,
Quantity[0.01, "AngularDegrees"]], {p, {oakIsland, versaillesCross,
domeOfTheRock}}]


However close the path appears on the world map, the path misses the island! How far is the path from the island? This map shows the path and the GeoPosition of the island.

GeoGraphics[{
Blue, PointSize[Large], Point[oakIsland],
Red, Thick, GeoPath[{domeOfTheRock, Quantity[6000, "Miles"], a},"Geodesic"]},
GeoRange -> Quantity[250,"Miles"],
GeoCenter -> oakIsland, GeoScaleBar->"Imperial"]


We can get a close estimate of the distance from the path to the island by splitting the path into points and finding the nearest point on the path to the island.

pathPoints = GeoDestination[domeOfTheRock,
GeoDisplacement[
{Range[Quantity[5000, "Miles"], Quantity[5200, "Miles"]], a}]];
geoPosition = First@Nearest[pathPoints, oakIsland];(*nearest to island*)
GeoDistance[oakIsland, geoPosition]

62.8529 miles


Another map shows the distance.

GeoGraphics[{
Blue, PointSize[Large], Point[oakIsland], Point[geoPosition],
Blue, Thick, GeoPath[{geoPosition, oakIsland}, "Geodesic"],
Red, Thick,
GeoPath[{domeOfTheRock, Quantity[6000, "Miles"], a}, "Geodesic"]},
GeoRange -> Quantity[100, "Miles"],
GeoCenter -> oakIsland,
GeoScaleBar -> "Imperial"]


Note:

Mathematica uses a model for the Earth’s surface that is not a sphere. If we assume a sphere and use spherical trigonometry, the result would be different. Someone doing a paper-and-pencil solution might not have corrected for the true shape of the Earth, and maybe the path would pass closer to Oak Island.

Illustrate a plane and the Earth as a sphere

A paper-and-pencil solution would probably not correct for true shape of the Earth. I’ll use the same coordinates, but assume the Earth is a sphere.

We need a plane through the center of the Earth that includes the Dome and Versailles, a sphere with grid lines for orientation, and the three points on the sphere's surface.

versaillesCross = GeoPosition[{48.81008221499617, 2.100137383293789}];
oakIsland = GeoPosition[{44.5167, -64.2992}];
domeOfTheRock = GeoPosition[{31.778063322333196, 35.23541700515525}];
QuantityMagnitude[

(*plane through the Dome, Versailles, and the center of the Earth*)
pCenter = {0., 0., 0.};
domeVersaillesPlane = Graphics3D[{
Blue, Opacity[.5], InfinitePlane[{p1, p2, pCenter}]},

(*sphere with grid lines*)
sphereGrid = SphericalPlot3D[
earthRadius, {θ, 0, Pi}, {ϕ, 0, 2 Pi},
Axes -> False, Boxed -> False];

(*points on the surface of the sphere*)
{p1, p2, p3} = FromSphericalCoordinates[
{earthRadius, π/2 - #1, #2}] & @@@
Normal@LatitudeLongitude[{domeOfTheRock, versaillesCross, oakIsland}];


This view shows the Dome and Versailles at the right and the island near the middle, with the plane that connects the Dome and Versailles.

Show[
sphereGrid,
pointsOnSphere,
domeVersaillesPlane
]


A close-up view of the island shows the plane overshoots the island by a small amount.

Show[
sphereGrid,
pointsOnSphere,
domeVersaillesPlane,
ViewAngle -> π/50
]


This next view shows the red plane (connecting the Dome, Versailles and Oak Island), does not match the blue plane through the Dome, Versailles and Earth's center.

Show[
sphereGrid,
pointsOnSphere,
Graphics3D[{
Red, Opacity[.8], InfinitePlane[{p1, p2, p3}],
Blue, Opacity[1], InfinitePlane[{p1, p2, pCenter}]}]
]


In each of these views, it appears that the distance between the plane and the island is small. How close is the plane to the island?

UnitConvert[
Quantity[RegionDistance[InfinitePlane[{p1, p2, pCenter}], p3],
"Meters"], "Miles"]

0.0425934 miles


So assuming the Earth is a sphere, and that the geographic locations are points on the sphere, the error is much smaller than the result we get when we use the geodesic path on the Earth's true surface.

Summary

By extending the geodesic path from the Dome to Versailles, the path misses the island by about 60 miles on the Earth's true surface. However, assuming the Earth is a sphere, the error is negligible. The plane-and-sphere method illustrates a paper-and-pencil solution without correction for the Earth's true shape.

So the we can assume historians in the The Curse of Oak Island episode also assumed a spherical Earth, and with this approximation, they found their presumed location of the Knights Templar treasure.

• Ah yes, I knew I had made some logical error somewhere. I think you can even see it in one of the images I have, that the GeoPath doesn't line up if you don't explicity make it go through Versailles. Or maybe... that's what they want you to think! Dec 3, 2020 at 20:35
• @creidhne / @CarlLange -- I think putting a plane through the sphere/globe through the two points will best illustrate the failure or closeness of the asserted arc connecting the 3 locations. Wrap it in a Manipulate to spin the globe as well as zoom in and one could readily see what it actually passes through around the earth. Maybe the treasure hunters have looked in the wrong place. Seems like my (maybe our) explorations may extend into the weekend. Many thanks Dec 4, 2020 at 2:03
• @Jagra - I've added an illustration that assumes the Earth is a sphere. I found a plane to connect the Dome and Versailles. With these approximations (a paper-and-pencil solution), the error at the island is very small. Dec 5, 2020 at 22:16
• Great solution with Earth as a sphere! As I fell asleep last night, I wondered about the mathematical, geographic, and navigation tools that the Templers might have had. They certainly had Euclid. They likely had access to some of the early ways to assess longitude. I woke up trying to build on a similar Earth as a sphere model and started looking at some possibly interesting near intersections of the great circle with places like: Socootra, Izmir, Thessaloniki, and NY & Mexico City in the New World. I'll post something when I can. Dec 6, 2020 at 0:21

Just to entice further general reverie...

I've cobbled together (from too many sources to cite) a Manipulate along the lines of @creidhne's:

Illustrate a plane and the Earth as a sphere

I've just taken the approach of drawing a great circle on the sphere/globe and seeing what it might evoke.

One can certainly get more detailed and specific (and given the time we've all already put into this, who knows where that will go ;-)

Manipulate[

Module[{rx, rz, u, v, SC, r, places, dom, ver, oak, pos, nyc, verona,
theso, izmir, socrota, centers},

ver = {48.81008221499617, 2.100137383293789};
oak = {44.5167, -64.2992};
dom = {31.778063322333196, 35.23541700515525};
pos = {19.69242584751161, -98.84353081841152};
nyc = {40.688943330006296, -74.04594759881309};
verona = {45.43984116351433, 10.998023166145238};
socrota = {12.551296, 54.515833};
theso = {40.63271743626375, 22.946026906725685};
izmir = {38.40925238535213, 27.145629351830948};

centers = {dom, ver, oak, pos, nyc, verona, theso, izmir, socrota};

rx = RotationTransform[deg Degree, {0, 1, 0}] (*
Rotation deg\[Degree] out of the xy plane *);
rz = RotationTransform[\[Phi] Degree, {0, 0, 1}]     (*
Spin around z axis *);
{u, v} = rz@rx@{{1, 0, 0}, {0, 1, 0}};
SC[{lat_, lon_}] :=
r {Cos[lon \[Degree]] Cos[lat \[Degree]],
Sin[lon \[Degree]] Cos[lat \[Degree]], Sin[lat \[Degree]]};
r = 1;
places = CountryData["Countries"];
Column[{
Show[
Graphics3D[
{Opacity[0.95], Sphere[{0, 0, 0}, r],
Map[
Line[
Map[SC, CountryData[#, "SchematicCoordinates"], {-2}]] &,
places],
{Red, PointSize[Large],
Point[SC[#]] & /@ centers}},
Boxed -> False,
SphericalRegion -> True,
ViewAngle -> .3,
ImageSize -> 600],

ParametricPlot3D[
{Cos[\[Theta]] u + Sin[\[Theta]] v, (*
The great circle in question *)
{Cos[\[Theta]],
Sin[\[Theta]], 0},(* Normal unit circle *)

RotationTransform[\[Theta], {0, 0, 1}] /@ {u, -u} (*
Red circles at top & bottom of great circle *)},
{\[Theta], -Pi, Pi},
PlotStyle -> {
Directive[Blue, Medium],
Directive[Black, Thin],
Directive[Red, Thin]
}
]
],
Grid[{
{"Interesting points on/near Great Circle", SpanFromLeft,
SpanFromLeft}, {},
{"", "Latitude", "Longitude"},
{"   Socrota", 12.551296, 54.515833},
{"   Temple Mount", 31.77806332233319, 35.23541700515525},
{"   Iizmir", 38.40925238535213, 27.145629351830948},
{"   Thesalaniki", 40.63271743626375, 22.946026906725685},
{"   Verona", 45.43984116351433, 10.998023166145238},
{"   Versailles", 48.81008221499617, 2.100137383293789},
{"   Oak Island", 44.5167, -64.2992},
{"   New York", 40.688943330006296, -74.04594759881309}, 19.69242584751161, -98.84353081841152}
},
Alignment -> {{Left, ".", "."}, Automatic},
Dividers -> {None, {4 -> Gray}}]
}]
],
{{deg, 128, "Inclination"}, -180, 180, 0.05, Appearance -> "Open"},
{{\[Phi], 335}, 0, 360, 1, Appearance -> "Open"}]
`

As I mentioned in a comment, I fell asleep the other night, wondering about the mathematical, geographic, and navigation tools that the "Templars" might have had available to them. They certainly had Euclid. They likely had access to some of the early ways to assess longitude. They certainly could have projected a great circle.

In a way, I like starting with the "draw a circle on the globe approach". Just dumb/silly enough to maybe get us to how someone - pre-Columbus and pre clocks to accurately calculate longitude - might have approached the problem.

Once I had a great circle, roughly passing through Oak Island and Versailles, one goes right down the rabbit hole (or at least starts chasing the rabbit around the great circle).

So, I marked the locations of possibly interesting points on/near the great circle and fiddled with aligning the circle for an "eyeballed" best fit. Templars would have had access to all of the listed locations in Europe and the Middle East.

On the other side of the world, following the arc of the great circle gets one to the Pyramid of the Sun in Teotihuacan one of the largest pyramids in Mesoamerica, constructed about 200 AD.

Or...

The Pyramid or the Sun, Oak Island, and Versailles look like they line up better than the Temple Mount does.

So, just sayin' we may see a new reality exploration show coming...

Oak Island meets Ancient Aliens

Who else would have known about the pyramid?

Hmmm... what about Golden Ratios of the distances between these spots?

If anyone can recommend a lost in the rabbit-hole support group, please advise.