1
$\begingroup$

I need to prove something like that:

For a,b,c>0 prove: $abc(a+b+c)^2≤(a^3+b^3+c^3)(ab+bc+ca)$.

I know that $3abc≤(a^3+b^3+c^3)$, but then I derived $3(ab+bc+ca) ≤ (a+b+c)^2$, I can't move on.

Can anyone help me?

$\endgroup$
1
  • 3
    $\begingroup$ Please add the Mathematica code you've tried to your question. $\endgroup$
    – creidhne
    Commented Nov 28, 2020 at 16:13

5 Answers 5

4
$\begingroup$

For a proof, in the mathematical sense, ask on math.SE. For a Mathematica verification, here's a way:

(a > 0 && b > 0 && c > 0) \[Implies] 
  Reduce[a*b*c*(a + b + c)^2 <= (a^3 + b^3 + c^3)*(a*b + b*c + c*a),
   {a, b, c}, PositiveReals] // Simplify
(*  True  *)
$\endgroup$
2
$\begingroup$

It's easy to disprove by finding a counter-example:

FindInstance[a*b*c*(a + b + c)^2 > (a^3 + b^3 + c^3)*(a*b + b*c + c*a), {a, b, c}]

(*    {{a -> -1, b -> -1, c -> 0}}    *)
$\endgroup$
1
  • $\begingroup$ Sorry, I forgot to add conditions that a,b,c>0 $\endgroup$
    – musk
    Commented Nov 28, 2020 at 16:05
2
$\begingroup$

This is not true on the reals as

NMinimize[-a*b*c *(a + b + c)^2 + (a^3 + b^3 + c^3)* (a*b + b*c + c*a), {a, b, c}]

says. The inequality is valid on the positive reals:

Minimize[-a*b*c*(a + b + c)^2 + (a^3 + b^3 + c^3)*(a*b + b*c + c*a), {a, b, c}, PositiveReals]
(*{0, {a -> 1, b -> 1, c -> 1}}*)

Addition. Here is the proof by logic tools without bells and jingles

Resolve[ForAll[{a, b, c},a*b*c*(a + b + c)^2 <= (a^3 + b^3 + c^3)*(a*b + b*c + 
c*a)], PositiveReals]
(*True*)
$\endgroup$
1
  • $\begingroup$ Sorry, I forgot to add conditions that a,b,c>0. I want to prove it on the positive reals $\endgroup$
    – musk
    Commented Nov 28, 2020 at 16:05
1
$\begingroup$

We can prove the result directly.

Expand[(a^3 + b^3 + c^3)*(a*b + b*c + c*a) - 
   a*b*c*(a + b + c)^2] // Factor

(a + b) (a + c) (b + c) (a^2 - a b + b^2 - a c - b c + c^2)

and $$a^2 - a b + b^2 - a c - b c + c^2=((a-b)^2+(b-c)^2+(c-a)^2)/2\geq 0$$

ForAll[{a, b, c}, a^2 - a b + b^2 - a c - b c + c^2 >= 0] // Resolve

True

So if $a,b,c\geq 0$,the inequality is true.

If we depend all of this by MMA, it also work.

ForAll[{a, b, c}, 
  a >= 0 && b >= 0 && 
   c >= 0 , (a^3 + b^3 + c^3)*(a*b + b*c + c*a) - 
    a*b*c*(a + b + c)^2 >= 0] // Resolve

True

$\endgroup$
2
  • 1
    $\begingroup$ Maybe your last step can be made with Mathematica too, using for instance this approach mathematica.stackexchange.com/questions/26283/… $\endgroup$
    – yarchik
    Commented Nov 28, 2020 at 23:30
  • $\begingroup$ @yarchik Thanks for your links. $\endgroup$
    – cvgmt
    Commented Nov 28, 2020 at 23:34
0
$\begingroup$

Or similar to the version of @MichaelE2

Reduce[a*b*c*(a + b + c)^2 <= (a^3 + b^3 + c^3)*(a*b + b*c + c*a), {a,
b, c}, Reals] // 
Simplify[#, a > 0 && b > 0 && c > 0] &

(*   True   *)
$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.