0
$\begingroup$

I have the following equation

$$\Delta v = -g I_\mathrm{SP} \left( 1 + \frac{1}{24} \frac{\mu}{r^3} \frac{g^2 {I_\mathrm{SP}}^2}{T^2} \frac{{m_p}^2}{n^2} \right) ^{-1} \sum _{k=1} ^n \log \left( \epsilon + (1-\epsilon) \frac{n \, m_\textrm{payload} (1-\epsilon) + (n-k) m_p}{n \, m_\textrm{payload} (1-\epsilon) + (n-k+1) m_p} \right)$$

and I wish to take the limit when $n\rightarrow\infty$.

This is a bit of an eyesore, but everything is an input parameter except $m_p$, which is what I want to know.

Now, I suspect this might converge. Why? Look at the plot below

mp vs n

which was produced by the following code

gEarth= 9.8067`32(*m/s^2*);
μEarth = 0.39860`32*10^6 (1*10^3)^3(*SI equivalent of 0.39860*10^6\km^3/s^2*);
radiusEarth = 6371*10^3(*SI equivalent of 6371 km; volumetric mean radius*);
Module[{g = gEarth, Isp = 300, μ = μEarth, r = radiusEarth + 200*10^3, T = 
20*10^3, mPayload = 1*10^3, ϵ = 0.0381622, Δv = 2*10^3, sol},
sol = Table[
First[NSolve[
((-g)*Isp*Sum[Log[ϵ + (1 - ϵ)*((n*mPayload*(1 - ϵ) + (n - k)*mp)/(n*mPayload*(1 - ϵ) + (n - k + 1)*mp))], {k, 1, n}])/(1 + (1/24)*(μ/r^3)*((g^2*Isp^2)/T^2)*(mp^2/n^2)) == Δv && mp > 0, mp, Reals]], {n, 1, 25}]; 
ListPlot[Table[{n, mp /. sol[[n]]}, {n, 1, Length@sol}],
ImageSize -> Full,
FrameLabel -> {Row[{"n"}], Row[{"mp/", Quantity[None, "Kilograms"]}]},
FrameTicksStyle -> Directive[FontSize -> ticksFontSize],
LabelStyle -> {FontSize -> labelFontSize},
PlotRange -> All,
PlotStyle -> {Directive[ColorData[97, "ColorList"][[1]], 
  AbsolutePointSize[pointSize]]},
GridLines -> Automatic,
PlotMarkers -> Automatic,
Joined -> True,
Frame -> {{True, False}, {True, False}}]
]

The problem is, when I take the limit

Limit[((-g)*Isp*Sum[Log[ϵ + (1 - ϵ)*((n*mPayload*(1 - ϵ) + (n - k)*mp)/(n*mPayload*(1 - ϵ) + (n - k + 1)*mp))], {k, 1, n}])/(1 + (1/24)*(μ/r^3)*((g^2*Isp^2)/T^2)*(mp^2/n^2)), n -> Infinity]

Mathematica doesn't give me an answer (it simply keeps running, and has been for a while now). There is also the question that the limit might not exist, but the plot seems to suggest otherwise.

Is there a way to know for sure if the limit exists, and if there is an analytical expression for it?

Ps: This question is borderline between this and the Mathematics Stack Exchange. However, since I'm looking for a practical answer using Mathematica's features, I've decided to post it here.

Update

My Mathematica actually crashed while running Limit[].

Edit

Added missing values for constans.

$\endgroup$
4
  • $\begingroup$ This is a mixture Sum. The quotient is not very much influenced by the k and the sum is independent of ϵ. ` Log[1]` approx. 0. The second th summand of the denominator is very small. The denominator is 1. So the term is dominated by the leading factor. And there is no solution with this Δ𝑣. Your input is either incomplete and does not belong to the plot. $\endgroup$ Nov 18, 2020 at 21:12
  • $\begingroup$ @SteffenJaeschke I'm sorry if I'm taking this personally, but clearly your rationale fails. Every input is defined for the plot (which is the solution of the Eq for certain values of n). As shown by the proposed answer, you can simplify the equation and find a solution. Finally, neither can you take the limit inside the summation independently nor it is well done. $n \rightarrow \infty$, which means that $k$ will be $\infty$ at some point. When this happens, how much is $n - k = \infty - \infty$? Clearly, one can't simplify to Log[1]. I think you should think twice before making such claims. $\endgroup$
    – Jak
    Nov 18, 2020 at 21:53
  • $\begingroup$ Already the input value are not defined: gEarth, μEarth, μEarth, radiusEarth, ... I can not copy'n'paste and have the curve immediately in little time. If I set them realistc or arbitrary I get messages from First for empty lists. I can not easily and comfortable as promised reproduce the plot. $\endgroup$ Nov 20, 2020 at 7:39
  • $\begingroup$ @SteffenJaeschke Values for these constants were indeed missing. Still, these are only needed in order to reproduce the plot. As you can see from Roman's answer, this does not influence the simplification of the Eq. (which was my question) nor the existence of a solution. $\endgroup$
    – Jak
    Nov 20, 2020 at 19:12

1 Answer 1

5
$\begingroup$

The tricky part is the sum:

Sum[Log[ϵ + (1-ϵ)*((n*mPayload*(1-ϵ) + (n-k)*mp)/(n*mPayload*(1-ϵ) + (n-k+1)*mp))], {k, 1, n}]

(*    Log[Gamma[-(((mp - mPayload n) (-1 + ϵ))/mp)]/Gamma[1 - n + (mPayload n (-1 + ϵ))/mp - ϵ]] - 
      Log[Gamma[(mPayload n (-1 + ϵ))/mp]/Gamma[-((n (mp + mPayload - mPayload ϵ))/mp)]]    *)

This difference of two logarithms can be written as the logarithm of the ratio of the two arguments:

Log[(Gamma[-(((mp - mPayload n) (-1 + ϵ))/mp)]/Gamma[1 - n + (mPayload n (-1 + ϵ))/mp - ϵ])/
        (Gamma[(mPayload n (-1 + ϵ))/mp]/Gamma[-((n (mp + mPayload - mPayload ϵ))/mp)])]

The limit of the argument of this logarithm as $n\to\infty$ is

Assuming[Element[n, Integers] && n > 1 && mPayload > 0 && 0 < ϵ < 1 && 0 < mp < n*mPayload,
  Asymptotic[(Gamma[-(((mp - mPayload n) (-1 + ϵ))/mp)] Gamma[-((n (mp + mPayload - mPayload ϵ))/mp)])/(Gamma[1 - n + (mPayload n (-1 + ϵ))/mp - ϵ] Gamma[(mPayload n (-1 + ϵ))/mp]), 
             n -> ∞] // FullSimplify]

(*    -mPayload (-1 + ϵ) (mPayload - mPayload ϵ)^-ϵ (mp + mPayload - mPayload ϵ)^(-1 + ϵ)    *)

So in this limit your equation becomes

Solve[-g Isp Log[-mPayload (-1 + ϵ) (mPayload - mPayload ϵ)^-ϵ (mp + mPayload - mPayload ϵ)^(-1 + ϵ)] == Δv,
      mp] // FullSimplify

(*    {{mp -> E^(-((I g Isp π + Δv + g Isp (Log[mPayload] + Log[-1 + ϵ] - ϵ Log[mPayload - mPayload ϵ]))/(g Isp (-1 + ϵ)))) - mPayload + mPayload ϵ}}    *)

You can probably prettify this expression by removing the complex logarithms.

$\endgroup$
1
  • $\begingroup$ Thank you, this seems to work pretty well. Still, I forgot to mention I'm using Mathematica v 11.3. Is there an equivalente code for Asymptotic in this version? $\endgroup$
    – Jak
    Nov 18, 2020 at 19:24

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.