0
$\begingroup$

I have to plot some points in the 3d space. This is the code I use

data = {{1.5403, 0.583853, 0.0100075, 0.346356, 1.28366}, {2.5403, 1.58385, 
  1.01001, 1.34636, 2.28366}, {3.5403, 2.58385, 2.01001, 2.34636, 
  3.28366}, {4.5403, 3.58385, 3.01001, 3.34636, 4.28366}, {5.5403, 
  4.58385, 4.01001, 4.34636, 5.28366}}

PLOT = ListPointPlot3D[data, ColorFunction -> "Rainbow", 
  FillingStyle -> Directive[Opacity[0.8], Thickness[0.0025]], 
  PlotTheme -> "Web", Axes -> True,
  PlotStyle -> PointSize[0.025]]

enter image description here

but I need to add a kind of grid that connects the points, enter image description here

$\endgroup$

1 Answer 1

1
$\begingroup$
PLOT = ListPointPlot3D[data, ColorFunction -> "Rainbow", Axes -> True,
    PlotStyle -> PointSize[0.025]];

lp3d = ListPlot3D[Join @@ MapIndexed[Append[Reverse@#2, #] &, data, {2}], 
   MeshFunctions -> {# &, #2 &}, 
   Mesh -> (Range /@ Dimensions[data]), 
   PlotStyle -> None, 
   MeshStyle -> Dashed,
   BoundaryStyle -> Dashed];

Show[PLOT, lp3d, BoxRatios -> 1]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.