3
$\begingroup$

I mean $$\sum _{n=0}^{\infty } \frac{Q_n\left(\frac{\sqrt{2}}{2}\right)}{n+1}. $$

It's unclear to me whether the series under consideration converges. I have strong doubts concerning its closed form. My best is

NSum[LegendreQ[n, Sqrt[2]/2]/(n + 1), {n, 0, 200}]
(*0.307806*)

However, the command

NSum[LegendreQ[n, Sqrt[2]/2]/(n + 1), {n, 0, Infinity}]

is running without any response for hours. Maple finds it, but Maple uses another definition of LegendreQ[n, x] and results in a complex number.

$\endgroup$
3
  • $\begingroup$ The true convergence of a series is its absolute convergence. However, NSum[RealAbs[LegendreQ[n, Sqrt[2]/2]]/(n + 1), {n, 0, Infinity}, Method -> {"WynnEpsilon", "ExtraTerms" -> 20, "Degree" -> 1}, NSumTerms -> 20, WorkingPrecision -> 30] is running without any respose for dozen minutes. $\endgroup$
    – user64494
    Oct 30, 2020 at 6:19
  • $\begingroup$ With NSum's option setting VerifyConvergence -> False that computation runs for less than 0.03 on my laptop with Version 12.1. $\endgroup$ Oct 30, 2020 at 12:10
  • $\begingroup$ @PeterMortensen: Please, don't edit the title from "How to find,,," to "How can I find...". Do you understand me? $\endgroup$
    – user64494
    Oct 31, 2020 at 8:31

4 Answers 4

7
$\begingroup$

Update

One of the (brute force) estimates I posted earlier using the Method option:

 Method -> {"WynnEpsilon", "ExtraTerms" -> 200, "Degree" -> 2}

is in agreement with the estimates from Bob Hanlon's and Ulrih Neumann's answers:

0.3071246932

First comment/answer

(Not an answer, extended comment -- I have to investigate some more when I have more time...)

You can experiment with NSum's methods and their options :

Options[NSum`WynnEpsilon]

(* {"ExtraTerms" -> 15, "Degree" -> 1} *)

 AbsoluteTiming[
 NSum[LegendreQ[n, Sqrt[2]/2]/(n + 1), {n, 0, Infinity}, 
  Method -> {"WynnEpsilon", "ExtraTerms" -> 200, "Degree" -> 1}, 
  NSumTerms -> 200, WorkingPrecision -> 100]
 ]

(* During evaluation of In[113]:= NumericalMath`NSequenceLimit::seqlim: The general form of the sequence could not be determined, and the result may be incorrect. *)

(*{2.98816, 0.3067630883738178981725444510087078866354171794104} *)

AbsoluteTiming[
 NSum[LegendreQ[n, Sqrt[2]/2]/(n + 1), {n, 0, Infinity}, 
  Method -> {"WynnEpsilon", "ExtraTerms" -> 200, "Degree" -> 2}, 
  NSumTerms -> 200, WorkingPrecision -> 100]
 ]

(* During evaluation of In[114]:= NumericalMath`NSequenceLimit::seqlim: The general form of the sequence could not be determined, and the result may be incorrect. *)

(* {2.95999, 0.3071246932} *)

Options[NSum`AlternatingSigns]

(*{"ExtraTerms" -> Automatic, "Method" -> None}*)

AbsoluteTiming[
 NSum[LegendreQ[n, Sqrt[2]/2]/(n + 1), {n, 0, Infinity}, 
  Method -> {"AlternatingSigns", "ExtraTerms" -> 200}, 
  NSumTerms -> 200, WorkingPrecision -> 100]
 ]

(* {2.9436, 0.30778346567187937249641347178243295192965243540504244041119905365363\
13013362226542629291522107099502} *)
$\endgroup$
5
  • $\begingroup$ +1. Thank you for the options of NSum. As far as I understand "NumericalMathNSequenceLimit::seqlim: The general form of the sequence could not be determined, and the result may be incorrect. ", you do not do the job as yet. Thank you anyway. I will be waiting when you will have more time... $\endgroup$
    – user64494
    Oct 29, 2020 at 17:02
  • $\begingroup$ Sorry, but the result of Table[LegendreQ[n, Sqrt[2]/2]/(n + 1), {n, 0, 16}] // N does not show any alternating signs. Also how about VerifyConvergence? I will be waiting when you will have more time... $\endgroup$
    – user64494
    Oct 29, 2020 at 17:34
  • $\begingroup$ Thank you. I think about the accepting. Unfortunately, NSum[RealAbs[LegendreQ[n, Sqrt[2]/2]]/(n + 1), {n, 0, Infinity}, Method -> {"WynnEpsilon", "ExtraTerms" -> 200, "Degree" -> 2}] is running without any response for dozen minutes. $\endgroup$
    – user64494
    Oct 30, 2020 at 11:54
  • $\begingroup$ With NSum's option setting VerifyConvergence -> False that computation runs for less than 0.03 on my laptop with Version 12.1 $\endgroup$ Oct 30, 2020 at 12:11
  • $\begingroup$ NSum[RealAbs[LegendreQ[n, Sqrt[2]/2]]/(n + 1), {n, 0, Infinity}, Method -> {"WynnEpsilon", "ExtraTerms" -> 200, "Degree" -> 2}] produces 2.27213. $\endgroup$
    – user64494
    Oct 30, 2020 at 12:21
11
$\begingroup$

The result is

1/4 (ArcCosh[3] ArcSinh[1] -
ArcSinh[1 - Sqrt[2]] Log[7 - 4 Sqrt[2] - 2 Sqrt[2 (10 - 7 Sqrt[2])]])

You can get to it using the integral representation of LegendreQ and then pulling the integral before the sum.

With this integral repesentation of LegendreQ (omitting a purely imaginary part)

I1=Integrate[(1/Sqrt[2] + I Cosh[t]/Sqrt[2])^(-1 - n), {t, 0, Infinity}]

you get

Sum[1/(n+1)I1,{n,0,Infinity}],

then exchange summation and integral to arrive at

Integrate[(-I (-I + 
 Cosh[t]) Log[(-I + I Sqrt[2] + Cosh[t])/(-I + Cosh[t])]/(Sqrt[
  2] (1/Sqrt[2] + (I Cosh[t])/Sqrt[2]))), {t, 0, Infinity}]

Now evaluate the antiderivative, enter the limits and take the real part of
the result. By checking the remaining PolyLogs you find they are all zero.

For (-1<z<1) I get the more general result

Re[PolyLog[2, 2 /(1 - Sqrt[I Sqrt[1 - z^2] - z])] + PolyLog[2, 2 /(1 + Sqrt[I Sqrt[1 - z^2] - z])] - PolyLog[2, 2 /(1 - Sqrt[2 z (z - I Sqrt[1 - z^2]) - 1])] - PolyLog[2, 2 /(1 + Sqrt[2 z (z - I Sqrt[1 - z^2]) - 1])]]

The real part of the above is

ArcTanh[z]^2/2 + 1/2 Log[(Sqrt[2] - Sqrt[1 - z])/Sqrt[1 + z]]^2 + ArcTanh[Sqrt[1 - z]/Sqrt[2]] Log[2] +1/2 (ArcTanh[Sqrt[1 - z]/Sqrt[2]] +Log[2]) Log[(1 + z)/(3 + 2 Sqrt[2 - 2 z] - z)] + \[Pi]^2/24 + 1/2 Log[1 + Sqrt[2]]^2 + 1/4 PolyLog[2, -3 - 2 Sqrt[2]] + 1/4 PolyLog[2, -3 + 2 Sqrt[2]]

The derivation is along the line of the special case, I integrated only the real part of the integral representation to obtain a real expression.

We can even get rid of the PolyLog constants:

ArcTanh[z]^2/2 + ArcTanh[Sqrt[1 - z]/Sqrt[2]] Log[2] + 1/2 Log[(Sqrt[2] - 
Sqrt[1 - z])/Sqrt[1 + z]]^2 + 1/2 (ArcTanh[Sqrt[1 - z]/Sqrt[2]] + Log[2]) Log[(1 + z)/(3 + 2 Sqrt[2 - 2 z] - z)] - 4 ArcCoth[Sqrt[2]]^2 + 
4 ArcSinh[1]^2 + 2 ArcSinh[1 - Sqrt[2]] Log[7 - 4 Sqrt[2] - 2 Sqrt[2] Sqrt[10 - 7 Sqrt[2]]] - Log[7 - 4 Sqrt[2] + 2 Sqrt[2] Sqrt[10 - 7     Sqrt[2]]]^2

I noticed that this can further be simplified to a short and beautiful

ArcTanh[z]^2/2-ArcTanh[Sqrt[1 - z]/Sqrt[2]]^2 + 
1/2 Log[(Sqrt[2] - Sqrt[1 - z])/Sqrt[1 + z]]^2.

And still shorter, so that we finally have:

Sum[LegendreQ[n, z]/(n + 1), {n, 0, Infinity}] = 
(ArcTanh[z]^2 - Log[(Sqrt[2] + Sqrt[1 - z])/Sqrt[1 + z]]^2)/2, (-1 < z < 1).
$\endgroup$
8
  • 2
    $\begingroup$ Er… Can you elaborate a bit more? Which integral representation do you choose? $\endgroup$
    – xzczd
    Oct 30, 2020 at 11:34
  • $\begingroup$ I used functions.wolfram.com/07.10.07.0002.01 $\endgroup$
    – Andreas
    Oct 30, 2020 at 12:03
  • $\begingroup$ @Andreas: I see the condition Re[z]>1 there, but z==Sqrt[2]/2 and z is less than 1. $\endgroup$
    – user64494
    Oct 30, 2020 at 12:08
  • $\begingroup$ I know, but my result matches the given numeric estimates anyway $\endgroup$
    – Andreas
    Oct 30, 2020 at 12:12
  • $\begingroup$ @Andreas: Can you present your derivation in the forum? TIA. $\endgroup$
    – user64494
    Oct 30, 2020 at 12:25
9
$\begingroup$
Clear["Global`*"]

Defining the sum recursively:

LegendreQ[n, Sqrt[2]/2]/(n + 1) /. n -> 0 // Simplify

(* 1/2 Log[3 + 2 Sqrt[2]] *)

sum[0] = Log[3 + 2 Sqrt[2]]/2.0`20;

sum[m_Integer?Positive] := sum[m] =
  sum[m - 1] + LegendreQ[m, Sqrt[2]/2]/(m + 1)

Calculating the points for a plot (this is slow)

sum[1000]

(* 0.30718615098022934340 *)

Plotting,

ListPlot[Callout[sum[#], If[Mod[#, 4] == 2, #, ""]] & /@ Range[0, 1000], 
 DataRange -> {0, 1000}]

enter image description here

The sum converges slowly unless restricted to values of m such that Mod[m, 4] == 2

The sum is approximately,

approx = Mean[sum /@ {994, 998}]

(* 0.30712469378349263758 *)

Show[
 ListPlot[Callout[sum[#], #] & /@ Range[2, 998, 4], DataRange -> {2, 998}],
 Plot[approx, {x, 0, 1000}, PlotStyle -> Red]]

enter image description here

$\endgroup$
12
  • $\begingroup$ -1. This is not it: you count partial sums. Are you serious? $\endgroup$
    – user64494
    Oct 30, 2020 at 4:53
  • 4
    $\begingroup$ @user64494 - I don't understand your comment. I am plotting the partial sum as a function of the number of terms. This is a fairly normal way of looking at the convergence of a sum. As the number of terms increase, the partial sum converges slowly. However, the subset of partial sums with the number of terms equal to 2 mod 4 converges faster. The labels are used to highlight these values of the number of terms. It is more efficient to work with this subset to get an approximate value for the infinite sum. $\endgroup$
    – Bob Hanlon
    Oct 30, 2020 at 5:09
  • $\begingroup$ There is not an infinite sum. There is a notion of the sum of a series which involves the limit. $\endgroup$
    – user64494
    Oct 30, 2020 at 5:31
  • 1
    $\begingroup$ @user64494 Then Bob has shown the partial sum seems to converge, and when Mod[m, 4] == 2, NSum[LegendreQ[n, Sqrt[2]/2]/(n + 1), {n, 0, m}] converges faster. A ListPlot isn't a strict proof of course, but it's not surprising the answer gets upvotes. Also, as mentioned in the Details and Options section of document of NSum, "…with sufficiently pathological summands, the algorithms used by NSum can give wrong answers. In most cases, you can test the answer by looking at its sensitivity to changes in the setting of options for NSum", so NSum won't prove convergency either. $\endgroup$
    – xzczd
    Oct 30, 2020 at 7:17
  • 1
    $\begingroup$ @BobHanlon Thank you for your post! It produces an estimate which is in agreement with one of my "brute force" computed estimates. $\endgroup$ Oct 30, 2020 at 11:59
3
$\begingroup$

Based on @BobHanlon's very interesting answer one can proceed a little bit forward to get an approximated limit( !not a proof, only applied numerics!) .

As Bob mentioned there is a dominant harmonic in the solution sum[m]~a+b Sin[2Pi (t-c)/8], which might be detected by Fouriertransformation.

Alternatively I try NonlinearModelFit to get the harmonic

data = Table[{m, sum[m]}, {m, 900, 1000}];
mod = NonlinearModelFit[data, {a + b Sin[2 Pi (t - c)/8] }, {a, b, c},t]
fit = mod["BestFitParameters"]
limit = a /. fit (*best guess: 0.307124 *)

The approximated limit is 0.307124.

Show[{ListPlot[data], Plot[mod[t], {t, 900, 1000}]}, PlotRange -> All,GridLines -> {None, {{limit, {Thickness[.01], Red} }}  }]

enter image description here

$\endgroup$
3
  • $\begingroup$ I have never heard about "an approximated limit". Think of a scientific publication. $\endgroup$
    – user64494
    Oct 30, 2020 at 11:41
  • 1
    $\begingroup$ Perhaps "asymptotic limit" ? $\endgroup$ Oct 30, 2020 at 11:45
  • $\begingroup$ Nice approach -- it produces an estimate which is in agreement with one of my "brute force" computed estimates. $\endgroup$ Oct 30, 2020 at 11:58

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.