Computing a difficult integral which is taking too long

Question

I am trying to solve the following code:

R1 = 100;
R5 = 45;
L1 = 346*10^(-3);
L2 = 7169*10^(-9);
c = 360*10^(-5);
Vi = LaplaceTransform[230*Sqrt[2]*Sin[100*Pi*t], t, s];
R2 = s*L1;
R3 = 1/(s*c);
R4 = s*L2;
x = (R2 R3 R5 Vi)/(
  R1 R3 (R4 + R5) + R2 R3 (R4 + R5) + R1 R2 (R3 + R4 + R5));
FullSimplify[
 Limit[Sqrt[(1/
      n)*(Integrate[(InverseLaplaceTransform[x, s, t])^2, {t, 0, 
       n}])], n -> Infinity]]

But it is taking so long to complete, how can I improve the runtime?

Answer 1

Split the calculation in two steps:

int=Integrate[(InverseLaplaceTransform[x, s, t])^2, {t, 0, n}] 
limit = Sqrt[Normal[Series[ (int/n)   , {n, Infinity, 0}]]]
(*(17905500000000 \[Pi])/(\[Sqrt](50625000000000000000000 - 
 1198243037250151359750000 \[Pi]^2 + 
 7854551311289380861908169 \[Pi]^4 + 1993491409755024 \[Pi]^6))*)

Numerical value of this result is the same which @Cesareo gave in his answer!

Answer 2

Try this

R1 = 1;
R1 = 100;
R5 = 45;
L1 = 346*10^(-3);
L2 = 7169*10^(-9);
c = 360*10^(-5);
Vi = LaplaceTransform[230*Sqrt[2]*Sin[100*Pi*t], t, s];
R2 = s*L1;
R3 = 1/(s*c);
R4 = s*L2;
x = (R2 R3 R5 Vi)/(R1 R3 (R4 + R5) + R2 R3 (R4 + R5) + R1 R2 (R3 + R4 + R5));
xt = Chop[N[ComplexExpand[InverseLaplaceTransform[x, s, t]]]];
intn = (1/n)*(Integrate[xt^2, {t, 0, n}]);
Chop[Limit[Sqrt[intn], n -> Infinity]]