Exporting to PDB seems to lose aromaticity

Question

I have a molecule with the following SMILES:

ClearAll[sml];
sml = "O=C(NCC1=CC(NC(C2=CN=C3C=CC=CN23)=O)=C(C)C=C1)NC4=CC=CC(F)=C4";

The plot looks as follows:

sml // RightComposition[
    Molecule[#, IncludeHydrogens -> True] &,
    MoleculePlot[#, ImageSize -> Large] &
]

In particular, please note the presence of aromatic bonds.

Now, following the export example at the bottom of the page for PDB files in the help manual, I attempt to export the molecule to a PDB file:

ClearAll[coords, atoms];
{coords, atoms} = sml // RightComposition[
    Molecule[#, IncludeHydrogens -> True] &,
    {MoleculeValue[#, "AtomCoordinates"] &, AtomList /* Map[First]}, Through
];

Export[
    FileNameJoin[{NotebookDirectory[], "mol.pdb"}],
    {{QuantityMagnitude[UnitConvert[coords, "Picometers"]]}, {atoms}},
    {{"AdditionalCoordinates", "AdditionalAtoms"}}
];

The export happens correctly (or at least so it appears), and I get a PDB file.

But when I load the PDB file, I find that the molecule has lost its aromatic bonds:

"mol.pdb" // RightComposition[
    Import[FileNameJoin[{NotebookDirectory[], #}], {"PDB", "Molecule"}] &,
    MoleculePlot[#, ImageSize -> Large] &
]

In addition, the oxygen atoms appear to have lost their double bonds as well.

What am I doing incorrectly?

Thanks in advance for your help.

Answer 1

• PDB files often contain no bond information at all, and when they do they don't contain bond types
• Perceiving bond types from 3D geometry is a relatively expensive operation, which is fine for small molecules (<100 atoms) but really time-consuming for large proteins
• The PDB importer for the "Molecule" import element does not do bond-order perception by default, and there isn't a documented option to turn it on.
• The XYZ importer has a documented option "InferBondTypes" which should be added to the PDB importer, perhaps with an Automatic setting that switches behavior based on the atom count.
• There is an undocumented option though to turn on the bond order perception for the PDB importer, which can be used in version 12.1

sml = "O=C(NCC1=CC(NC(C2=CN=C3C=CC=CN23)=O)=C(C)C=C1)NC4=CC=CC(F)=C4";
element = {"PDB", "Molecule"};
sml // Molecule // 
    ExportString[#, element]& // 
    ImportString[#, element, "UseOpenBabel" -> True]& //
    MoleculePlot