4
$\begingroup$

I have three vectors:

v1={1,0,0}       v1={0,1,0}     v1=1/2{1,1,1}

I wish to show the volume constructed by these vectors.

I know the amount of this volume is calculated by

1/2  Dot[Cross[{1, 0, 0}, {0, 1, 0}], {1, 1, 1}]

But I do not know how to draw this volume!!!

$\endgroup$
6
$\begingroup$

To include the vectors in the drawing:

v = {{1, 0, 0}, {0, 1, 0}, 1/2 {1, 1, 1}};

ℛ = Parallelepiped[{0, 0, 0}, v];

Graphics3D[{
  {Opacity[0.7], ℛ},
  {Red, Arrowheads[0.05],
   Arrow[Tube[{{0, 0, 0}, #}, 0.01]] & /@ v}},
 Axes -> True,
 BoxRatios -> {1, 1, 1}]

enter image description here

The volume can be calculated multiple ways

{Volume[ℛ], RegionMeasure[ℛ], Integrate[1, {x, y, z} ∈ ℛ]}

(* {1/2, 1/2, 1/2} *)

SameQ @@ %

(* True *)
$\endgroup$
7
$\begingroup$

Use Parallelepiped:

v1 = {1, 0, 0};
v2 = {0, 1, 0};
v3 = 1/2 {1, 1, 1};
Graphics3D[Parallelepiped[{0, 0, 0}, {v1, v2, v3}]]

Plot of parallelepiped

$\endgroup$
2
  • $\begingroup$ Thank you so much. But How to show this volume in a cubic with sides equal to 1 $\endgroup$ – Inzo Babaria Oct 6 '20 at 16:14
  • 1
    $\begingroup$ Assuming you mean the aspect ratio, Show[Graphics3D[Parallelepiped[{0, 0, 0}, {v1, v2, v3}]], BoxRatios -> 1]. $\endgroup$ – yawnoc Oct 6 '20 at 16:18

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.