How to export and import these data

Question

I want to export my_data and then import them back again in exactly the same data structure as the one they had when they were initially generated.

mydata = Table[{σ, RandomVariate[NormalDistribution[0, σ]]}, {σ, 1, 2}, {100}]

I say exactly, because no matter what I have tried based on the online documentation, when I import the exported data, the structure is not valid for plotting them using:

Show[
 Histogram3D[
  mydata,
  PlotRange -> {{0, 10}, {-20, 20}, {0, All}},
  AxesLabel -> (Text[Style[#, Italic, 14]] & /@ {"a", "b", "c"})]
 ]

(plotting works with the initially generated data)

Could you provide here with the correct export and import commands?

Answer 1

You can use Put (>>) and Get (<<).

mydata>>filename
mydataImported = <<filename

Answer 2

Alternatively, exporting and importing as a spreadsheet

Clear["Global`*"]

SeedRandom[1234]

Generating and exporting the data

Export["/Users/roberthanlon/Downloads/mydata.xls",
  mydata = Table[{σ, 
     RandomVariate[NormalDistribution[0, σ]]}, {σ, 1, 2}, {100}]];

The imported data is

mydata2 = Import["/Users/roberthanlon/Downloads/mydata.xls"];

The data is equivalent

mydata == mydata2

(* True *)

Although not identical

mydata === mydata2

(* False *)

Generating the histograms

{hg1, hg2} = 
 Show[Histogram3D[#, PlotRange -> {{0, 10}, {-20, 20}, {0, All}}, 
     AxesLabel -> (Text[Style[#, Italic, 14]] & /@ {"a", "b", 
         "c"})]] & /@ {mydata, mydata2}

The histograms are identical

SameQ @@ {hg1, hg2}

(* True *)