Nonlinear model fit for a complex function of two variables?

Question

I am trying to fit the real and imaginary part of the Lorentzian, using MultiNonlinearModelfit function, I am having two independent variables in the problem (x and w, please see the code below), I am not sure how to go about the two independent variables, Here is my data Data

Data = Import["E:\\Shelender\\codes\\Mathematica\\Aelastic \
relaxation\\try.csv"];
real = Data[[All, {1, 2}]];
imag = Data[[All, {1, 3}]];
w = Data[[All, {4}]];
Model = (A*E^(d/x)*tw)/(-I + E^(d/x)*tw);
fit = ResourceFunction["MultiNonlinearModelFit"][
Rationalize[{real, imag}, 0], ComplexExpand[ReIm@Model], 
Rationalize[{{A, 1.0*10^-4}, {t, 1.0*10^-12}, {d, 10}}, 0], {x}, 
PrecisionGoal -> 5, AccuracyGoal -> 10];
fit["ParameterConfidenceIntervalTable"]

Answer 1

I think you want something like this?

real = Data[[All, {1, 4, 2}]];
imag = Data[[All, {1, 4, 3}]];
Model = (A*E^(d/x)*t*w)/(-I + E^(d/x)*t*w);
fit = ResourceFunction["MultiNonlinearModelFit"][
  Rationalize[{real, imag}, 0],
  ComplexExpand[ReIm @ Model],
  Rationalize[{{A, 1.0*10^-4}, {t, 1.0*10^-12}, {d, 10}}, 0],
  {x, w},
  WorkingPrecision -> 30,
  MaxIterations -> 1000
]

The w variable doesn't change a whole lot, so it doesn't seem to impact the fit all that much.

Edit

You can plot the fit for example like this:

Manipulate[
 Show[
  ListPlot[{real[[All, {1, 3}]], imag[[All, {1, 3}]]}],
  Quiet @ Plot[
    {fit[1, x, w], fit[2, x, w]}, {x, 0, 1.5597}, 
    PlotRange -> All
  ]
 ],
 {w, 1.255 10^8, 1.256*10^8}
]

As you can see, the value of w really doesn't influence the fit much.