0
$\begingroup$

I am completely new to mathematica. I am not sure how to calculate the expression 2F1. Is it possible to a closed form solution in terms of z of the hypergeometric series 2F1(-a, N/2-a, N/2; z) and 2F1(1-a, N/2-a, 1+N/2; z) when N>2a and N is any positive natural number.

$\endgroup$
  • $\begingroup$ Try Hypergeometric2F1 $\endgroup$ – wuyudi Sep 29 at 12:40
1
$\begingroup$
Clear["Global`*"]

nmax = 7;

Table[{n, Assuming[n/2 > a, 
      Hypergeometric2F1[-a, n/2 - a, n/2, z] // FunctionExpand // 
       FullSimplify]}, {n, 1, nmax}] // 
   Prepend[#, {"n", Hypergeometric2F1[-a, n/2 - a, n/2, z]}] & // 
  Grid[#, Frame -> All] & // TraditionalForm

enter image description here

Table[{n, Assuming[n/2 > a, 
      Hypergeometric2F1[1 - a, n/2 - a, 1 + n/2, z] // FunctionExpand // 
       FullSimplify]}, {n, 1, nmax}] // 
   Prepend[#, {"n", Hypergeometric2F1[1 - a, n/2 - a, 1 + n/2, z]}] & // 
  Grid[#, Frame -> All] & // TraditionalForm

enter image description here

Consequently, even for specific values of n these hypergeometric functions do not generally reduce to simpler functions.

| improve this answer | |
$\endgroup$
1
$\begingroup$

For general $n$ and $a$ no, but for many values it can simplify. For instance:

a = 3/2;

Table[Hypergeometric2F1[-a, n/2 - a, n/2, z] // FunctionExpand // FullSimplify, {n, 1, 5}]

{
3 z + 1, 
(8 (z - 1) EllipticK[z] + 2 (z + 7) EllipticE[z])/(3 π), 
1, 
(4 (z - 1) (z + 3) EllipticK[z] + 4 ((7 - 2 z) z + 3) EllipticE[z])/(15 π z),
(Sqrt[z] ((8 - 3 z) z + 3) + 3 (z - 1)^3 ArcTanh[Sqrt[z]])/(16 z^(3/2))
}

Capital $N$ is a builtin function in Mathematica, so don't use it as a variable.

| improve this answer | |
$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.