How to plot the solution region of system of inequalities with slack variables?

Question

There are already related questions to this one, but I could not transfer these solutions to my problem.

I have the system

$\sqrt{t_1^2+u_1^2}+\sqrt{t_2^2+u_2^2}\leq 1$,

$x=2t_1-u_1+2t_2+u_2$,

$y=2u_1+t_1+2u_2-t_2$,

where all variables are real valued. In Mathematica notation this is:

equ = Sqrt[t1^2 + u1^2] + Sqrt[t2^2 + u2^2] <= 1 && 
      x == 2 t1 - u1 + 2 t2 + u2 && 
      y == 2 u1 + t1 + 2 u2 - t2 && 
      Element[{t1, u1, t2, u2}, Reals];

I would like to plot all points $(x,y)\in\mathbb{R}^2$ where there exist $t_1,u_1,t_2,u_2\in\mathbb{R}$ such that the system has a solution.

Any ideas?

Answer 1

Clear["`*"];
equ = Sqrt[t1^2 + u1^2] + Sqrt[t2^2 + u2^2] <= 1 && 
  x == 2 t1 - u1 + 2 t2 + u2 && y == 2 u1 + t1 + 2 u2 - t2 && 
  Element[{t1, u1, t2, u2}, Reals]
reg = ImplicitRegion[equ, {x, y, t1, u1, t2, u2}]
Resolve[Exists[{t1, u1, t2, u2}, {x, y, t1, u1, t2, u2} ∈ 
   reg], Reals]

The result is

(y == -Sqrt[5] && 
   x == -Sqrt[5 - y^2]) || (-Sqrt[5] < y < Sqrt[
    5] && -Sqrt[5 - y^2] <= x <= Sqrt[5 - y^2]) || (y == Sqrt[5] && 
   x == -Sqrt[5 - y^2])

So you can plot it by RegionPlot or ContourPlot

for example

RegionPlot[(-Sqrt[5] < y < Sqrt[5] && -Sqrt[5 - y^2] <= x <= Sqrt[
    5 - y^2]), {x, -5, 5}, {y, -5, 5}]