3
$\begingroup$

Four identical unfair dice are tossed once. Find the probability of events in which the sum of numbers (facing up) is 18. Given the probability of face 6 is $1/2$ and that of each other face is $1/10$.

My attempt

ClearAll[data,prob]
data = DeleteCases[Tuples@Table[Range[1, 6], 4], x__ /; Total@x != 18];
prob = (# /. {p_ /; p != 6 -> 1/10, 6 -> 1/2}) & /@ data;
Times @@@ prob // Total

with output $12/125$.

$\endgroup$
5
$\begingroup$
pd = EmpiricalDistribution[({1, 1, 1, 1, 1, 5}/10) -> Range[6]];
Probability[Total[Array[x, 4]] == 18, Thread[Array[x, 4] \[Distributed] pd]]
(* result 12/125 *)
| improve this answer | |
$\endgroup$
3
$\begingroup$

Without filtering:

Total[Times @@@ Map[If[# == 6, 1/2, 1/10] &,
                    Flatten[Permutations /@
                            IntegerPartitions[18, {4}, Range[6]], 1], {2}]]
   12/125
| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.