2
$\begingroup$

I have the following expression $$2^{1-2 n^2} \left(3-\sqrt{5}\right)^{-n-1} \left(\sqrt{5}-1\right)^{n (n+1)} \left(\sqrt{5}+1\right)^{n^2}$$

This can be simplified to $$\left(\frac{1}{2} \left(\sqrt{5}+1\right)\right)^{n+2}$$

But

 FullSimplify[2^(1 - 2*n^2)*(3 - Sqrt[5])^(-1 - n)*(-1 + Sqrt[5])^(n*(1 + n))*(1 + Sqrt[5])^n^2, n > 0]

returns unevaluated

Interestingly, the ratio of these two expressions is simplified:

FullSimplify[2^(1 - 2*n^2)*(3 - Sqrt[5])^(-1 - n)*(-1 + Sqrt[5])^(n*(1 + n))*((1 + Sqrt[5])^n^2 / ((1 + Sqrt[5])/2)^(n + 2)), n > 0]
(* 1 *)
$\endgroup$
3
  • $\begingroup$ FindSequenceFunction[Table[2^(1-2 n^2) (3-√5)^(-1-n) (-1+√5)^(n (1+n)) (1+√5)^n^2,{n,10}],n]//FullSimplify gives 2^(-1-n) (1+√5)^n (3+√5). $\endgroup$
    – chyanog
    Sep 18 '20 at 10:23
  • $\begingroup$ Also FullSimplify[ExpToTrig[2^(1 - 2 n^2) (3 - Sqrt[5])^(-1 - n) (-1 + Sqrt[5])^(n (1 + n)) (1 + Sqrt[5])^n^2]] gives the same result, but such a result is only partial, not the best simplification. $\endgroup$ Sep 18 '20 at 12:12
  • $\begingroup$ @chyanog - You can get closer by putting the simplification within the Table. That is, FindSequenceFunction[Table[(2^(1 - 2*n^2)*(3 - Sqrt[5])^(-1 - n)*(-1 + Sqrt[5])^(n*(1 + n))*(1 + Sqrt[5])^n^2) // Simplify, {n, 1, 10}], n] evaluates to (2/(1 + Sqrt[5]))^(1 - n)* (2 + Sqrt[5]) Or you get the same result with FindSequenceFunction[Table[(2^(1 - 2*n^2)*(3 - Sqrt[5])^(-1 - n)*(-1 + Sqrt[5])^(n*(1 + n))*(1 + Sqrt[5])^n^2), {n, 1, 10}] // Simplify, n] As a general rule you want to provide FindSequenceFunction with the simplest form to work with. $\endgroup$
    – Bob Hanlon
    Sep 18 '20 at 15:50
1
$\begingroup$

That's where I can bring it:

expr1 = 2^(1 - 2*n^2)*(3 - Sqrt[5])^(-1 - n)*(-1 + 
      Sqrt[5])^(n*(1 + n))*(1 + Sqrt[5])^n^2;
expr2 = expr1 /. (-1 + Sqrt[5])^(n (1 + n)) -> a*(-1 + Sqrt[5])^n^2 //
    Simplify;
expr3 = expr2 /. a -> (-1 + Sqrt[5])^n;
expr4 = expr3 /. (3 - Sqrt[5])^(-1 - n) -> a*(3 - Sqrt[5])^-n // 
   Simplify[#, n > 0] &;
expr5 = expr4 /. a -> (3 - Sqrt[5])^-1;
expr6 = Simplify[expr5/(3 + Sqrt[5]), n > 0]*(3 + Sqrt[5])

 (*   2^(-1 - n) (1 + Sqrt[5])^n (3 + Sqrt[5])   *)

Have fun!

$\endgroup$
2
  • $\begingroup$ OK, but this is only a partial success. See the two comments above, with the same result. I'd like to see an expression ((1 + Sqrt[5])/2)^(n+2) or GoldenRatio^(n+2). $\endgroup$ Sep 18 '20 at 15:57
  • $\begingroup$ So far, the most elegant result (* GoldenRatio^n (1 + GoldenRatio) *) is obtained by using substitution 2^(-1 - n) (1 + Sqrt[5])^n (3 + Sqrt[5]) /. Sqrt[5] -> 2 GoldenRatio - 1 // FullSimplify. Does anyone get GoldenRatio^(n+2) from this? $\endgroup$ Sep 18 '20 at 16:09
0
$\begingroup$

The following code solves my problem:

Simplify[FullSimplify[ExpToTrig[
2^(1 - 2*n^2)*(3 - Sqrt[5])^(-1 - n)*(-1 + 
Sqrt[5])^(n*(1 + n))*(1 + Sqrt[5])^n^2]] /. {1 + Sqrt[5] -> 
2 GoldenRatio, 3 + Sqrt[5] -> 2*GoldenRatio^2}]

 (* GoldenRatio^(2 + n) *)

However in general, Mathematica is not very successful in simplifying expressions containing GoldenRatio. I had to supplement the knowledge base with substitutions.

Thank you all for your effort!

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.