3
$\begingroup$

Given (assuming $0 \leq t \leq \pi/2$)

x == (1 + a Sin[2 t]) Sin[t],

and

y == 1 - (1 + a Sin[2 t]) Cos[t]

How can I get $y(x)$ without the $t$ variable appearing?

Solving for, and eliminating, $t$ directly proved very awkward and this didn't work:

Assuming[0 < t < \[Pi]/2,
 Eliminate[{x == (1 + a Sin[2 t]) Sin[t],
   y == 1 - (1 + a  Sin[2 t]) Cos[t] }, t]]
$\endgroup$
7
$\begingroup$

The usual procedure for obtaining a Cartesian equation from parametric equations like yours is to use GroebnerBasis[] for eliminating variables:

First[GroebnerBasis[Append[TrigExpand[{x == (1 + a Sin[2 t]) Sin[t],
                                       y == 1 - (1 + a Sin[2 t]) Cos[t]}], 
                           Cos[t]^2 + Sin[t]^2 == 1],
                    {x, y, a}, {Cos[t], Sin[t]}]]
   -4 a x + x^2 - 4 a^2 x^2 - 4 a x^3 + 2 x^4 + x^6 - 2 y + 12 a x y - 8 x^2 y +
   8 a^2 x^2 y + 4 a x^3 y - 6 x^4 y + 9 y^2 - 12 a x y^2 + 16 x^2 y^2 -
   4 a^2 x^2 y^2 + 3 x^4 y^2 - 16 y^3 + 4 a x y^3 - 12 x^2 y^3 + 14 y^4 +
   3 x^2 y^4 - 6 y^5 + y^6

The result obtained is a degree-$6$ polynomial, so I am not very sanguine about solving for y in this case.

| improve this answer | |
$\endgroup$
  • 1
    $\begingroup$ An excellent first step (+1). $\endgroup$ – David G. Stork Sep 11 at 2:40
  • $\begingroup$ Solve[gb==0, y, Reals] gives you solutions, but you have to pick the right ones. $\endgroup$ – Akku14 Sep 13 at 4:40
  • $\begingroup$ @Akku, since the result contains Root[] objects (as expected), I don't particularly care for solving for y, as it is not more convenient than the starting implicit equation. $\endgroup$ – J. M.'s discontentment Sep 20 at 5:01

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.